Sorting lists by fields

BlitzMax Forums/BlitzMax Beginners Area/Sorting lists by fields

fetcher

(Posted 2009) [#1]

The code below takes a list of 3 objects and sorts them by their name field. This was done by giving TPerson an overriding Compare method. The problem now is that I can only sort the list by the one field (name).

Strict

'Person Type
Type TPerson
	Field name:String
	Field age:Int
	Field weight:Int
	Global personList:TList = New TList
	
	Function Create:TPerson(name:String,age:Int,weight:Int)
		Local person:TPerson = New TPerson
		person.name = name
		person.age = age
		person.weight = weight
		personList.addlast(person)
		Return person
	End Function
	
	Method Compare(other:Object)
		If name > TPerson(other).name Then 
                   Return 1 
                Else 
                   Return -1
                End If
	End Method
End Type

'Add some people
TPerson.Create("Joe",35,180)
TPerson.Create("Alice",25,115)
TPerson.Create("Bill",60,170)

'Print the list as is
Print "Unsorted"
For Local person:TPerson = EachIn TPerson.personList
	Print person.name
Next

'Sort the list
TPerson.personList.sort()

'Print the listed sorted by name
Print
Print "Sorted By Name"
For Local person:TPerson = EachIn TPerson.personList
	Print person.name
Next

'Main Loop
While KeyHit(KEY_ESCAPE) = 0

Wend

How would I be able to sort by name, age or weight? Can I send the field I want to sort by to the Compare Method? I was only able to figure out this much by searching through the forums. There are several references to being able to sort by multiple fields, but no code examples or detailed explanations.

N	(Posted 2009) [#2]

Method Sort( ascending:Int = True, compareFunc( o1:Object, o2:Object ) = CompareObjects )

Use the compareFunc argument of TList#Sort. Sorting by more than one field at the same time is another matter, however, and it's entirely up to you to implement that using your own logic.

jsp	(Posted 2009) [#3]

You can use a global variable inside your type to indicate the field you want to sort.
Set that variable whenever you like to change the sortstyle.
Then have a Select Case inside your compare function.

Strict

Const PERSON_NAME:Int=1
Const PERSON_WEIGHT:Int=2
Const PERSON_AGE:Int=3
'Person Type
Type TPerson
	Field name:String
	Field age:Int
	Field weight:Int
	Global personList:TList = New TList
	Global SortStyle:Int = PERSON_NAME
	
	Function create:TPerson(name:String,age:Int,weight:Int)
		Local person:TPerson = New TPerson
		person.name = name
		person.age = age
		person.weight = weight
		personList.addlast(person)
		Return person
	End Function
	
	Method Compare(other:Object)
		Local obj:TPerson	= TPerson(other)
		If obj = Self	Then	Return 0
		Select SortStyle
			Case PERSON_NAME
				If name  > obj.name 
					Return 1
				End If
			Case PERSON_WEIGHT
				If weight > obj.weight
					Return 1
				End If
			Case PERSON_AGE
				If age > obj.age
					Return 1
				End If
		End Select
		
		Return -1
	End Method
End Type

'Add some people
TPerson.create("Joe",35,180)
TPerson.create("Alice",25,115)
TPerson.create("Bill",60,170)

'Print the list as is
Print "Unsorted"
For Local person:TPerson = EachIn TPerson.personList
	Print person.name
Next


'Print the listed sorted by name
Print
Print "Sorted By Name"
TPerson.SortStyle=PERSON_NAME
'Sort the list
TPerson.personList.sort()
For Local person:TPerson = EachIn TPerson.personList
	Print person.name
Next

Print "Sorted By Age"
TPerson.SortStyle=PERSON_AGE
'Sort the list
TPerson.personList.sort()
For Local person:TPerson = EachIn TPerson.personList
	Print person.name
Next
Print "Sorted By Weight"
TPerson.SortStyle=PERSON_WEIGHT
'Sort the list
TPerson.personList.sort()
For Local person:TPerson = EachIn TPerson.personList
	Print person.name
Next

'Main Loop
While KeyHit(KEY_ESCAPE) = 0

Wend

N	(Posted 2009) [#4]

That's really overcomplicating it, I think. Not to mention your line, "If name > obj.name" would be much better handled as simply Return name.Compare(other.name).

fetcher

(Posted 2009) [#5]

Thanks to both of you. CompareFunc was something I had previously had no knowledge of, and seems to be the key in all this.