still having OO knightmares

BlitzMax Forums/BlitzMax Beginners Area/still having OO knightmares

Pete Carter

(Posted 2009) [#1]

I have a type i call "soldier" and i have 20 or so instances of that type on screen. my game requires the player to be able to click the mouse on a soldier and then be able to control that one soldier, then be able to click on another to deselect the first.

hope thats clear.

What the best way of doing this?

thanks Pete

EOF	(Posted 2009) [#2]

I would do it like this:

Type Soldier
  Field x,y,blah ..
End Type

Global ucSoldier:Soldier    '   current "user-controlled" Soldier

...

' update all soldiers
For s:Soldier=Eachin SoliderList
    If UserClickedSolder(s) Then ucSoldier=s
    ' Update soldiers
    If s<>ucSoldier
        CPU_ControlsThisSoldier
    Else
        USER_ControlsThisSoldier
    EndIf
Next

Essentially, a pointer which indicates which soldier the player is currently controlling

InvisibleKid

(Posted 2009) [#3]

Jim posted when i was coding but its done and figured i'd post anyway.

very crude and basic example but i hope it helps


Strict
Graphics 800,600

Global selectedSoldier = 0

Global SoldierList:TList = CreateList()

For Local s = 1 To 6
	TSoldier.CreateSoldier(s,Rand(20,780),Rand(20,580))
Next


While Not KeyDown(key_Escape) And Not AppTerminate()
Cls

	TSoldier.Update()
	
	DrawText "Left click on soldier to select",10,10
	DrawText "Right click to move selected soldier",10,20
Flip
Wend
End

Type TSoldier
	Field id
	Field x,y		'current position
	Field tx,ty		'target position
	Field ismoving
	
	Function CreateSoldier:TSoldier(id,x,y)
		Local s:TSoldier = New TSoldier
		
		s.id = id
		s.x = x
		s.y = y
		
		SoldierList.AddLast s
	EndFunction
	
	Method CheckMouseCollision()
		If MouseX() > Self.x-4 And MouseX() < Self.x+4 And ..
		 MouseY() > Self.y-4 And MouseY() < Self.y+4
			
			selectedSoldier = Self.id
		EndIf
	EndMethod
	
	Method SetMoveTarget()		
		Self.tx = MouseX()
		Self.ty = MouseY()
		Self.ismoving = 1
	EndMethod
	
	Method Move()
		If Self.x > Self.tx Then Self.x:-1
		If Self.x < Self.tx Then Self.x:+1
		If Self.y > Self.ty Then Self.y:-1
		If Self.y < Self.ty Then Self.y:+1
		
		If Self.x = Self.tx And Self.y = Self.ty Then Self.ismoving = 0
	EndMethod
	
	Method Draw()
		'draw selected circle
		If Self.id = selectedSoldier
			SetColor 255,0,0
			DrawOval Self.x-8,Self.y-8,16,16
			SetColor 232,230,0
		Else
			SetColor 0,255,0
		EndIf
		
		'draw soldier		
		DrawOval Self.x-4,Self.y-4,8,8
		
		SetColor 255,255,255
	EndMethod
	
	Function Update()
		For Local s:TSoldier = EachIn SoldierList
			s.Draw()
			
			If s.ismoving = 1 Then s.Move()
			
			If MouseDown(1) Then s.CheckMouseCollision()
			
			If MouseDown(2) And selectedSoldier = s.id Then s.SetMoveTarget()
		Next
	EndFunction
EndType

Pete Carter

(Posted 2009) [#4]

Thankyou both. Your detailed posts are very helpful.

very crude and basic example

but it answers my question very well

InvisibleKid

(Posted 2009) [#5]

your welcome

a side note:
after rereading my posted code

Method CheckMouseCollision(id)

should be

Method CheckMouseCollision()

and

If MouseDown(1) Then s.CheckMouseCollision(s.id)

should be

If MouseDown(1) Then s.CheckMouseCollision()

i was gonna do more with it, but at the last second i decided not to over complicate what should just be a basic example and forgot to change the method/method call (fixed now). all though as is it doesn't affect anything, but its just not needed.

anyway glad it helped 8-)

Pete Carter

(Posted 2009) [#6]

Thanks again