Need a test with this...

BlitzMax Forums/BlitzMax Beginners Area/Need a test with this...

hub	(Posted 2006) [#1]

[EDIT]
I've modified the code to use the Dreamora/ GeoffTheGyratingGiraffe DrawImageArea function
to correct the bug on old machine, so
so could you test this :
http://www.bayre.com/zigwigwis/test_griffe_2.exe

Many thanks

[/EDIT]

Hi !
i need to know if it works fine for you.
you should have this. ie nothing inside the red square !

Here the link :
http://www.bayre.com/zigwigwis/test_griffe.exe

Many thanks for you help !!! Please post also you config.

if someone could also test this with an old pc configuration (geforce 2) it should be interesting for me to know it there is a bug or not !

Diablo

(Posted 2006) [#2]

works fine here.

SebHoll

(Posted 2006) [#3]

Tried it on an old Windows 2000 laptop (750Mhz, 256MB RAM, 11MB Onboard Graphics) and the red square is visible but there is no image behind it at all. Was it included in the EXE? I.e. IncBin

WendellM

(Posted 2006) [#4]

Looks like screenshot above on my AMD XP 3000+ with Win XP Pro SP2 and Radeon 9600 Pro. Animated "blue blades" extend and retract while image inside red square remains unchanged.

Booticus

(Posted 2006) [#5]

Same as Wendell, works fine here. Animation and everything. Good stuff!

hub	(Posted 2006) [#6]

Thanks for the tests !

@seb : its confirms that this code using classic bmax viewport to simulate the blitzbasic drawimagerect doesn't work on old machines. Yes graphics images are include into the exe. i suppose that this function doesn't work too on your old pc :

Function DrawImageRectClip(image:TImage, x#, y#, rx#, ry#, rw#, rh#, frame=0)
	Local vx, vy, vw, vh, hx#, hy#
	
	hx# = image.handle_x
	hy# = image.handle_y
	SetImageHandle image, 0, 0
	GetViewport(vx, vy, vw, vh)
	SetViewport x#, y#, rx# + rw#, ry# + rh#
	
	DrawImage image, x# - rx#, y# - ry#, frame
	
	SetViewport vx, vy, vw, vh
	SetImageHandle image, hx#, hy#
End Function

undomiel

(Posted 2006) [#7]

Didn't work here, the up-down spikies would go into the red box while the side-side spikies would be clipped by the red box. So that definitely confirms your bug!

P3 933 XP SP2 768 MB RAM GeForce 2 GTS w/ 32 MB

Dreamora

(Posted 2006) [#8]

There are enough functions in the code archives that use the correct way to draw image rects like old Blitz did (by using UV coords that are reset to the right values before the function is left)

Using viewport is a strange and unlogical hack ...

TartanTangerine (was Indiepath)

(Posted 2006) [#9]

BMAX viewports are just clipping rects, they will do the job but it's not the most elegant and does involve overhead you could do without.

Yan	(Posted 2006) [#10]

He was already offered a UV routine but wanted a solution that *only* used the standard Max2D commands!

[edit]
Edited to satisfy Dreamora's pedantic side. ;oP
[/edit]

Dreamora

(Posted 2006) [#11]

ok

Although UV only uses Max2D commands as well, but only OOP commands and not procedural commands.
You don't need to modify the module to get the desired results.

hub	(Posted 2006) [#12]

Many thanks for your tests. it's true that i prefer use standard max2d commands ;-) GeoffTheGyratingGiraffe
have posted a link to dreamora code ( http://www.blitzbasic.com/codearcs/codearcs.php?code=1422 ) in another topic. Is Dreamora code works with mac, windows and linux ? i don't understand too how to use it with my project (you know... i don't use framework !)

Blitzer101

(Posted 2006) [#13]

>Didn't work here, the up-down spikies would go into >the red box while the side-side spikies would be >clipped by the red box. So that definitely confirms your >bug!

Does exactly the same here, but I also found the I could not close the window after trying it and had to resort to Ctrl+alt+del and force it to it as a task.

Comp Spec...

Win98se, 800mhz AMD Athlon, 256mb ram, GeForce gfx, Soundblaster snd card. HTH.

Dreamora

(Posted 2006) [#14]

I updated the code with a little commented description on what the parameters mean.

You only need to put the code into a bmx and include it or even just put it into one of your existing BMX files.

hub	(Posted 2006) [#15]

@dreamora : i paste your code into my bmx file. and i've an error : "identifier 'TDX7ImageFrame not found"

Dreamora

(Posted 2006) [#16]

I updated the code. Some BM stuff changed.

Added the possibility to specify the drawing size of the image part as well.

Hope the description is understandable.

hub	(Posted 2006) [#17]

Thanks Dreamora. You should also translate this into english :

Assert l < image.width Else "l muss kleiner als die Bildbreite sein"
Assert t < image.height Else "t muss kleiner als die Bildhöhe sein"

i'll test your code tomorrow.

Dreamora

(Posted 2006) [#18]

good input

undomiel

(Posted 2006) [#19]

Assert l < image.width Else "l must be less than the image's width"
Assert t < image.height Else "t must be less than the image's height"

Unless my german is too rusty.

Dreamora

(Posted 2006) [#20]

yes that would be right. But I removed it so you can now even create repeating structures and mirrored repeating structures.

hub	(Posted 2006) [#21]

Hi !
with Dreamora function... the image auto scale to the drawrect size ? How to not deform the image ?
Thanks
(note i invert some params into the dreamora function declaration)

Strict 

Graphics 800,600

Global hImage:Timage = LoadImage ("griffe.png")
SetImageHandle hImage, 0,0

Rem
	image: handle of the image you want to draw
	x , y: Position at which you want to draw the imagerect
	w,h: width and height of the imagerect you want to draw
	l,t: top left position on the image you want to start drawing (in pixels)
	dw,dh: Drawing height and width of the image part you want do draw.
End Rem

Function drawimagearea (image:TImage, x#, y#, w#, h#, l#, t#,dw#,dh#,  frame:Int=0)
	Local origin_x#,origin_y#
	GetOrigin (origin_x,origin_y)
	Local l1#	= l + w
	Local h1#	= t + h
	Local x0#=-image.handle_x,x1#=x0+w
	Local y0#=-image.handle_y,y1#=y0+h

	If l1 > image.width
		x1 = x0 + w + image.width - l1
		l1 = image.width
	EndIf 
	If h1 > image.height
		y1 = y0 + h + image.height - h1
		h1 = image.height
	EndIf

	If TGLImageFrame (image.frame(frame))
		Local frame:TGLImageFrame 	= TGLImageFrame (image.frame(frame))
								
		frame.u0 = l / image.width
		frame.v0 = t / image.height
		frame.u1 = (l1) / image.width
		frame.v1 = (h1) / image.height
		frame.Draw x0,y0,x0+dw,y0+dh,x+origin_x,y+origin_y
		
		frame.u0	= 0
		frame.v0	= 0
		frame.u1	= 1
		frame.v1	= 1
	Else
		Local frame:TD3D7ImageFrame	= TD3D7ImageFrame(image.frame(frame))
		frame.setUV (l/image.width, t/image.height, (l1) / image.width, (h1) / image.height)
		frame.Draw x0,y0,x0+dw,y0+dh,x+origin_x,y+origin_y
		frame.setUV (0,0,1,1)
	EndIf
	
End Function

Rem
	image: handle of the image you want to draw
	x , y: Position at which you want to draw the imagerect
	w,h: width and height of the imagerect you want to draw
	l,t: top left position on the image you want to start drawing (in pixels)
	dw,dh: Drawing height and width of the image part you want do draw.
End Rem


While Not KeyDown (KEY_ESCAPE)

	Cls
	
	SetColor  255, 255,255
	
	DrawRect 300,100,200,150
	DrawImage hImage, 250,100
	
	DrawRect 300,300,200,150
	DrawImagearea hImage, 300,300,200,150,50,0,200, 250
	Flip

Wend

Yan	(Posted 2006) [#22]

Dreamora's routine doesn't seem to take power of two texture rescaling into account?

I've fixed the scaling thing, pulled out the dx and dy as they seemed a bit pointless to me, renamed the variables and slapped in some compiler directives for good measure...

Strict

Graphics 800,600

Global hImage:Timage = LoadImage ("griffe.png")
SetImageHandle hImage, 0,0

While Not KeyDown (KEY_ESCAPE)
  Cls
  
  SetColor  255, 255,255
  
  DrawRect 300,100,200,150
  DrawImage hImage, 250,100
  
  DrawRect 300,300,200,150
  DrawImageArea hImage, 300,300, 50, 0, 200, 150
  
  Flip
Wend

End


Function DrawImageArea(image:TImage, x#, y#, rx#, ry#, rw#, rh#, frame=0)
  Local origin_x#, origin_y# ; GetOrigin (origin_x, origin_y)
  Local tw = Pow2Size(image.width)
  Local th = Pow2Size(image.height)
  Local rw1#  = rx + rw
  Local rh1#  = ry + rh
  Local x0# = -image.handle_x, x1# = x0 + rw
  Local y0# = -image.handle_y, y1# = y0 + rh
  
  If rw1 > image.width
    x1 = x0 + rw + image.width - rw1
    rw1 = image.width
  EndIf
   
  If rh1 > image.height
    y1 = y0 + rh + image.height - rh1
    rh1 = image.height
  EndIf
?Win32
  If TD3D7ImageFrame(image.frame(frame))
    Local frame:TD3D7ImageFrame = TD3D7ImageFrame(image.frame(frame))
    
    frame.setUV(rx / tw, ry / th, rw1 / tw, rh1 / th)
    frame.Draw x0, y0, x1, y1, x + origin_x, y + origin_y
    frame.setUV(0, 0, image.width / Float(tw), image.height / Float(th))
  Else
?
    Local frame:TGLImageFrame = TGLImageFrame (image.frame(frame))
                
    frame.u0 = rx / tw
    frame.v0 = ry / th
    frame.u1 = rw1 / tw
    frame.v1 = rh1 / th
    
    frame.Draw x0, y0, x1, y1, x + origin_x, y + origin_y
    
    frame.u0 = 0
    frame.v0 = 0
    frame.u1 = image.width / Float(tw)
    frame.v1 = image.height / Float(th)
?Win32
  EndIf
?
  
  Function Pow2Size(n)
    Local ry = 1
    
    While ry < n
      ry :* 2
    Wend
    
    Return ry
  End Function
End Function

Dreamora

(Posted 2006) [#23]

the dw, dh had a reason:

l,t and h,w define the rect on the image you want to draw.

x,y defines the position for the rect
dw,dh define the size of the image when you draw it.

The reason I added those: What if you have a 512x512 image you split up to 128x128 subimages. But for some reason you want to draw them in 80x60 or something similar? Without dw and dh, you can't do that. That's why I added them. If you want to draw it in 1:1 scale, you can still set w,h and dw,dh to the same value.

And the power of two: why should this be of interest? You don't need power of two if you draw subparts of a texture. There is no reason to enforce it. (the image will be as whole within VRAM and thus be power of 2 as it was loaded through BMs routines)

Yan	(Posted 2006) [#24]

Yeah, I can read code thanks...I was probably a bit harsh when I said pointless, just not used that often generally and I was thinking more about compatibility with classic Blitz commands. It'd be easy enough to add them back and setting them to default to rw and rh.

the image will be as whole within VRAM and thus be power of 2 as it was loaded through BMs routines

Precisely! The UV settings have to take that into account, where as Image.width and Image.height do not.

Dreamora

(Posted 2006) [#25]

Why should the UV have to take that into account?
There is no reason for it.
I did not create a DrawImageArea function to be forced to power of 2 subimages once again. That would be totally pointless! If you want that, you could have used loadanimimage which already does work that way and would be faster as image frames are seperate images.

The target of the function is to draw any arbitary subimage of an image to any arbitary area on the screen. For everything else, BM has the needed functionality as part of Max2D

Yan	(Posted 2006) [#26]

Oh dear...Have you even tried your own code?...

Strict

Graphics 800, 600, 32

Local img:TImage = LoadImage("bmlogo.png", 0)' A 257x257 image

SetClsColor 0, 0, 200

Cls

DrawImage img, 0, 12
DrawImageAreaMe img, 260, 12, 0, 0, 128, 128
DrawImageAreaDream img, 520, 12, 128, 128, 0, 0, 128, 128 

DrawText "Full", 12, 0
DrawText "My Quarter", 270, 0
DrawText "Dreamora's Quarter", 520, 0   

Flip

WaitKey()

End


Function DrawImageAreaMe(image:TImage, x#, y#, rx#, ry#, rw#, rh#, frame:Int=0)
	Local origin_x#, origin_y# ; GetOrigin (origin_x, origin_y)
	Local tw = Pow2Size(image.width)
	Local th = Pow2Size(image.height)
	Local rw1#	= rx + rw
	Local rh1#	= ry + rh
	Local x0# = -image.handle_x, x1# = x0 + rw
	Local y0# = -image.handle_y, y1# = y0 + rh
	
	If rw1 > image.width
		x1 = x0 + rw + image.width - rw1
		rw1 = image.width
	EndIf
	 
	If rh1 > image.height
		y1 = y0 + rh + image.height - rh1
		rh1 = image.height
	EndIf
?Win32
	If TD3D7ImageFrame(image.frame(frame))
		Local frame:TD3D7ImageFrame	= TD3D7ImageFrame(image.frame(frame))
		
		frame.setUV(rx / tw, ry / th, rw1 / tw, rh1 / th)
		frame.Draw x0, y0, x1, y1, x + origin_x, y + origin_y
		frame.setUV(0, 0, image.width / Float(tw), image.height / Float(th))
	Else
?
		Local frame:TGLImageFrame = TGLImageFrame (image.frame(frame))
								
		frame.u0 = rx / tw
		frame.v0 = ry / th
		frame.u1 = rw1 / tw
		frame.v1 = rh1 / th
		
		frame.Draw x0, y0, x1, y1, x + origin_x, y + origin_y
		
		frame.u0 = 0
		frame.v0 = 0
		frame.u1 = image.width / Float(tw)
		frame.v1 = image.height / Float(th)
?Win32
	EndIf
?
	
	Function Pow2Size(n)
		Local ry = 1
		
		While ry < n
			ry :* 2
		Wend
		
		Return ry
	End Function
End Function

Function DrawImageAreaDream(image:TImage, x#, y#, dw#, dh#, l#, t#, w#, h#, frame:Int=0)
	Local origin_x#,origin_y#
	GetOrigin (origin_x,origin_y)
	Local l1#	= l + w
	Local h1#	= t + h
	Local x0#=-image.handle_x,x1#=x0+w
	Local y0#=-image.handle_y,y1#=y0+h

	If l1 > image.width
		x1 = x0 + w + image.width - l1
		l1 = image.width
	EndIf 
	If h1 > image.height
		y1 = y0 + h + image.height - h1
		h1 = image.height
	EndIf

	If TGLImageFrame (image.frame(frame))
		Local frame:TGLImageFrame 	= TGLImageFrame (image.frame(frame))
								
		frame.u0 = l / image.width
		frame.v0 = t / image.height
		frame.u1 = (l1) / image.width
		frame.v1 = (h1) / image.height
		frame.Draw x0,y0,x0+dw,y0+dh,x+origin_x,y+origin_y
		
		frame.u0	= 0
		frame.v0	= 0
		frame.u1	= 1
		frame.v1	= 1
	Else
		Local frame:TD3D7ImageFrame	= TD3D7ImageFrame(image.frame(frame))
		frame.setUV (l/image.width, t/image.height, (l1) / image.width, (h1) / image.height)
		frame.Draw x0,y0,x0+dw,y0+dh,x+origin_x,y+origin_y
		frame.setUV (0,0,1,1)
	EndIf
	
End Function

Using this image, I get this.

Dreamora

(Posted 2006) [#27]

ok. in that case its really needed. .width / .height don't work as they should, they don't have the real image width/height saved of the image that is held in VRAM ... thats plain crap but ok.

Thanks for mentioning that. Never realized that BM saves incorrect informations in its internal structure (or if the internal handling changed since BM 1.06 for which this function was written)

I thought you meant powerof2 for the subimagerect you want to draw, not for the width/height of the original image. Thats why I didn't understand its use. sorry.

Is it ok, if I add that to my code?

Yan	(Posted 2006) [#28]

ok. in that case its really needed. .width / .height don't work as they should, they don't have the real image width/height saved of the image that is held in VRAM ... thats plain crap but ok.

Remember, Max2D is trying to act like a 2D system, so it stands to reason that the texture resizing should be hidden from the user. It would be nice if the real texture size was stored somewhere though (Unless it is and I've missed it?).

or if the internal handling changed since BM 1.06 for which this function was written

It's always been that way.

Is it ok, if I add that to my code?

Of course you can.

[edit]
Apologies to hub for the thread hi-jack...
[/edit]

Dreamora

(Posted 2006) [#29]

Never spoted it because I only use PowerOf2 textures (as others have a VRAM overhead).
Updated the code

hub	(Posted 2006) [#30]

I've modified the code to use the Dreamora/ GeoffTheGyratingGiraffe DrawImageArea function
to correct the bug on old machine, so
so could you test this :
http://www.bayre.com/zigwigwis/test_griffe_2.exe

Many thanks !!!!

undomiel

(Posted 2006) [#31]

Yep, works as expected now.