Doing my swede in

BlitzMax Forums/BlitzMax Beginners Area/Doing my swede in

BlitzMan

(Posted 2016) [#1]

hi guys

Do not no why it is not printing the button i have clicked on.

Strict

Graphics 800,600

SetClsColor 32,32,32 

Global Button_List:TList = CreateList()

Button("0",92,32,0)
Button("1",149,32,1)
Button("2",214,32,2)
Button("3",271,32,3)

' \\ Main

Repeat

Cls 

DrawButton()

Flip

Until KeyHit (KEY_ESCAPE) Or AppTerminate()
End

' \\ End Main

'CREATE BUTTON

Type TButton
	
	Field label:String
	Field x:Int
	Field y:Int
	Field width:Int
	Field height:Int
	Field id:Int
	Field hit:Byte
	
End Type

Function Button(label: String,x:Int,y:Int,id:Int)

     Local Button:TButton = New TButton

     Button.label = label
     Button.x = x
     Button.y = y
     Button.width = TextWidth(Button.label)+17 
     Button.height = 32  
     Button.id = id
     Button.hit = False
	
     ListAddLast(Button_List,Button)
	
End Function

'DRAW BUTTON

Function DrawButton()

For Local Button:TButton = EachIn Button_List

'Mouse Over Button

	If MouseX()>Button.x And MouseX()<Button.x+Button.width And MouseY()>Button.y And MouseY()<Button.y+Button.height Then
	 
		Button.hit = True
	
			SetColor 0,0,0 ' outline
			Rect Button.x,Button.y,Button.width,Button.height , 1
			SetColor 96,96,96 ' middle
			Rect Button.x+1,Button.y+1,Button.width-2,Button.height-2 , 0 
			SetColor 255,255,255 ' text
			DrawText Button.label,Button.x+8,Button.y+9
			SetColor 0,0,0
			
			If MouseHit(MOUSE_LEFT) And Button.hit Then ButtonEvent(Button.id)
			
		Else
		
'Normal Button
		
		Button.hit= False
		
			SetColor 0,0,0 ' outline
			Rect Button.x,Button.y,Button.width,Button.height , 1 
			SetColor 64,64,64 ' middle
			Rect Button.x+1,Button.y+1,Button.width-2,Button.height-2 , 0
			SetColor 255,255,255 ' text
			DrawText Button.label,Button.x+8,Button.y+9
			SetColor 255,255,255

		EndIf
Next

End Function

'BUTTON EVENT

Function ButtonEvent(id)'; Call the Button by its id number

	Select id

		Case 0
			DrawText "Button hit" + id ,200,100
	
		Case 1
			DrawText "Button hit" + id ,200,100
			
		Case 2
			DrawText "Button hit" + id ,200,100
			
		Case 3
			DrawText "Button hit" + id ,200,100		
	
	End Select		

End Function

'-----------------------------------------

'RECT

Function Rect(x:Int, y:Int, w:Int, h:Int,style:Byte=0)
	If style =< 0
		DrawRect x,y,w,h
	Else
		DrawLine(x,y,x+w-1,y)
		DrawLine(x+w-1,y,x+w-1,y+h-1)
		DrawLine(x+w-1,y+h-1,x,y+h-1)
		DrawLine(x,y+h-1,x,y)
	EndIf
End Function

Midimaster

(Posted 2016) [#2]

th text is printed on the screen, but it is black and visible only for a moment. Try this change to see it:

Function ButtonEvent(id)'; Call the Button by its id number
	SetColor 255,255,255
	Print "YES" + id

	Select id
		Case 0
			DrawText "Button hit" + id ,200,100
....

You could optimize your buttons by integrating the functions into the type.

Strict

Graphics 800,600

SetClsColor 32,32,32 


TButton.Add("0",92,32,0)
TButton.Add("1",149,32,1)
TButton.Add("2",214,32,2)
TButton.Add("3",271,32,3)

' \\ Main

Repeat
		Cls 
		TButton.DrawAll()
		Flip
Until KeyHit (KEY_ESCAPE) Or AppTerminate()
End


' \\ End Main

'CREATE BUTTON

Type TButton
	Global List:TList = CreateList()
	
	Field Label:String
	Field X:Int, Y:Int, Width:Int, Height:Int, Id:Int
	Field Hit:Byte
	

	
	Function Add(label: String,x:Int,y:Int,id:Int)
	    Local Button:TButton= New TButton
		Button.Set label, x, y, id
	    ListAddLast List,Button
	End Function



	Method Set(_label: String,_x:Int,_y:Int,_id:Int)
	     Label = _label
	     X = _x
	     Y = _y
	     Width = TextWidth(Label)+17 
	     Height = 32  
	     Id = _id
	     Hit = False
	End Method



	Function DrawAll()
		For Local Button:TButton = EachIn List
			Button.Draw()
		Next
	End Function



	Method Draw()
			SetColor 0,0,0 ' outline
			DrawRect X, Y, Width, Height
			Hit= False
			SetColor 64,64,64 ' middle
			If MouseX()>x And MouseX()<x+width And MouseY()>y And MouseY()<y+height Then
				Hit = True
				SetColor 96,96,96 ' middle
				
				If MouseHit(MOUSE_LEFT)
					Event Id
				EndIf
			EndIf

			DrawRect x+1, y+1, Width-2, Height-2
			SetColor 255,255,255 ' text
			DrawText Label, X+8, Y+9
	End Method
		
End Type


'OUTSIDE: BUTTON EVENT

Function Event(id)'; Call the Button by its id number
	SetColor 255,255,255
	Print "Event:" + id
	DrawText "Button hit" + id ,200,100

	Select id
		Case 0
	
		Case 1
			
		Case 2
			
		Case 3
	
	End Select		

End Function

Encapsulate the code relating the buttons has a lot of advantages:
1. You need not write the header "button." in front of each variable.
2. The function names and variables will never collide with other names in your code.
3. The code keeps closed together like in a class

BlitzMan

(Posted 2016) [#3]

Thanks Midimaster it was the color command.

for the life of me i didnt see it