abstraction

BlitzMax Forums/BlitzMax Beginners Area/abstraction

Yue	(Posted 2015) [#1]

That offers the advantages Abstraction, my structural form of "program", that of declaring an abstract method to use then do not see much benefit.

Any ideas?

TomToad

(Posted 2015) [#2]

Abstract helps when you have several different types derived from a single type. You can call the extended types Methods through the base type. Say if you had a list of enemies. You could put trolls, dragons, skeletons, etc... in the same list, but use an abstract Update method to iterate through all the enemies without the need to test what type it is first.

SuperStrict

Type TShape
	Field x:Float, y:Float, Color:Int
	
	Method Draw() Abstract
End Type

'Define a square whose upper right is x,y and extends to Width,Height
Type TSquare Extends TShape
	Field Width:Float, Height:Float
	
	Method Draw() Final
		SetColor (color Shr 16) & $FF, (Color Shr 8) & $FF, Color & $ff
		DrawRect x,y,Width,Height
	End Method
End Type

'Define a circle whose center point is x,y and has a radius of Radius
Type TCircle Extends TShape
	Field Radius:Float
	
	Method Draw() Final
		SetColor (color Shr 16) & $FF, (Color Shr 8) & $FF, Color & $ff
		DrawOval x-Radius, y-Radius, 2*Radius, 2*radius
	End Method
End Type 

'Define an equalateral triangle whose base is parallel to the x axis.  Top point is x,y and height is distance from top point to base
Type TTriangle Extends TShape
	Field Height:Float

	Method Draw() Final
		Local t:Float[6]
		Local c:Float = Height/(2*Sin(60))
		t[0] = x
		t[1] = y
		t[2] = x+c
		t[3] = y+Height
		t[4] = x-c
		t[5] = y+Height
		SetColor (color Shr 16) & $FF, (Color Shr 8) & $FF, Color & $ff
		
		DrawPoly t
	End Method
End Type

Graphics 800,600

Local List:TList = CreateList()

For Local i:Int = 1 To 20
	Local t:Int = Rand(0,2)
	Select t
		Case 0 'Square
			Local s:TSquare = New TSquare
			s.x = Rand(0,800)
			s.y = Rand(0,600)
			s.Width = Rand(10,50)
			s.Height = Rand(10,50)
			s.Color = Rand(0,1)*$FF0000 + Rand(0,1) * $FF00 + Rand(0,1) * $FF
			List.AddLast(s)
		Case 1 'Circle
			Local c:TCircle = New TCircle
			c.x = Rand(0,800)
			c.y = Rand(0,600)
			c.Radius = Rand(10,50)
			C.Color = Rand(0,1)*$FF0000 + Rand(0,1) * $FF00 + Rand(0,1) * $FF
			List.AddLast(c)
		Case 2 'Triangle
			Local e:TTriangle = New TTriangle
			e.x = Rand(0,800)
			e.y = Rand(0,600)
			e.Height = Rand(10,50)
			e.Color = Rand(0,1)*$FF0000 + Rand(0,1) * $FF00 + Rand(0,1) * $FF
			List.AddLast(e)
	End Select
Next

While Not KeyHit(KEY_ESCAPE) And Not AppTerminate()
	Cls
	For Local Shape:TShape = EachIn List
		Shape.Draw
	Next
	Flip
Wend

Yue	(Posted 2015) [#3]

@TomToad
Thanks You. :)

markcw

(Posted 2015) [#4]

Like TomToad says, use Abstract when you want to enforce a behaviour/function on an extended type.

I've never actually found much use for Abstract and in one case I had to actually remove it as it interfered with a function I added that created a new instance of the type, and you can't do that in an abstracted type.

The only uses it has is either when designing code to be extendible by another programmer or as a reminder you need to implement a standardized method/function - as in TomToad's example.

SidAntic

(Posted 2015) [#5]

nice, I never used "abstract", but for my Tile-Map-Editor and for other future things, I will use it.

Thanks.
:---)

Yasha

(Posted 2015) [#6]

it interfered with a function I added that created a new instance of the type, and you can't do that in an abstracted type.

You can deal with that by doing something like this:

Type Foo Abstract
    Function Make:Foo(a:Int, b:Int)
        Return _Foo.Make(a, b)
    End Function
    Field a:Int, b:Int
End Type

Private
Type _Foo Extends Foo
    Function Make:Foo(a:Int, b:Int)
        Local f:_Foo = New Self
        f.a = a ; f.b = b
        Return f
    End Function
End Type

Abstract is actually exactly what you want when a type has constructor functions, because that's the situation when preventing the user from calling New directly is important!

markcw

(Posted 2015) [#7]

Ok I get it. Thanks!