For Each on BlitzMax?

BlitzMax Forums/BlitzMax Beginners Area/For Each on BlitzMax?

Yue	(Posted 2015) [#1]

Which is equivalent BlitzMax for a "for each" that was used in Blitz3D?

; For Each on B3d
for Obj.Car = Each Car 

   EntityColor Obj.Car\Mesh%, 255,0,0

Next

RustyKristi

(Posted 2015) [#2]

Hey Yue,

You can always check out the examples included or blitzmax online manual here:

http://www.blitzbasic.com/bmdocs/command.php?name=EachIn&ref=goto

Local a[]=[0,5,12,13,20]

for b=eachin a
	print b
next

For T:Obj = EachIn ObjList
...
Next

hope that helps :-)

degac

(Posted 2015) [#3]

Type Car
	Field x:Int,y:Int,z:Int
End Type

Global list_car:TList=New TList

Global cars:Car

For Local n:Int=0 Until 10 'means 0 to 9
		'create a new object 'Car'
		cars=New Car
		'define its parameters
		cars.x=n*10
		cars.y=10
		cars.z=10
		'store in a list - at then end (AddLast, AddFirst=at the top)
		list_car.AddLast cars
Next

'iterate each elements in the list (must be of Car type)
For Local c:Car=EachIn list_car
		Print c.x+" "+c.y+" "+c.z
Next

The main difference between B3D and Bmax is that object and list are not directly related.
An object (Car) can be stored in different list (or map or array, or both!)
A list can store different type of object.
Its a more useful solution.

degac

(Posted 2015) [#4]

Handling different type in the same list

Type Car
	Field x:Int,y:Int,z:Int
End Type

Type missile
	Field x:Int,y:Int,z:Int

End Type

Global list_objects:TList=New TList

For Local n:Int=0 Until 9
			list_objects.addlast New Car
Next

For n:Int=0 Until 9
			list_objects.addlast New Missile
Next
'you need to 'cast' the generic Object to the specific one you want to 
For Local o:Object=EachIn list_objects
	If Car(o) 'it's of type 'car'
				Print "Object: Car"	
	End If
	
	If Missile(o) 'it's of type 'missile'
				Print "Object: Missile"	
	End If
Next