[MaxGui] Textfield for password input?

BlitzMax Forums/BlitzMax Beginners Area/[MaxGui] Textfield for password input?

Grisu

(Posted 2015) [#1]

Hello all,

Has anyone a small example code that turns user inputs for a textfield invisible (i.e. replacing each char with an asterik "*")?

I'm quite sure there was something for this on the code archives. But I can't find it anymore. :(

Grisu

Henri

(Posted 2015) [#2]

Hi Grisu,

use 'TEXTFIELD_PASSWORD'-style in CreateTextField().

-Henri

Grisu

(Posted 2015) [#3]

Thanks, worked! :)

Grisu

(Posted 2015) [#4]

Sorry to come back to this:

But is there a way to unflag (i.e. remove the passwort flag) from the textfield afterwards? I want to give the user an option to show / hide the password input as he prefers.

SetGadgetText doesn't come with a flag parameter. I tried to remove and recreate the textfield (bad coding), but it still shows the "****"?

| Edit |

Got a workaround, you have to...

1. Hide the current Textfield.
2. Create a new Textfield and set the Password again.
3. Show the new Textfield.

RedrawGadget() has no effect!

	     		Case EVENT_GADGETACTION'BUTTON_ACTION
				HideGadget(Proxy_PasswordTextField:TGadget)	
  	            If ButtonState(Proxy_ShowPassword) = 0 Then 'Default = Hidden PW
					Proxy_PasswordTextField:TGadget	= CreateTextField(3, 25+PNL_HEIGHT+2,MAINWINDOW_W-3-SLIDER_WIDTH-46-16, PNL_HEIGHT, ProxyPanel, TEXTFIELD_PASSWORD)
					'Print "HIDDEN"
                Else ' Show PW
					Proxy_PasswordTextField:TGadget	= CreateTextField(3, 25+PNL_HEIGHT+2,MAINWINDOW_W-3-SLIDER_WIDTH-46-16, PNL_HEIGHT, ProxyPanel)
					'Print "VISIBLE"					
               EndIf
			   SetGadgetText (Proxy_PasswordTextField, ini_Proxypassword)
               ShowGadget(Proxy_PasswordTextField:TGadget)

There has to be an easier way.

degac

(Posted 2015) [#5]

Hi

just create 2 different textfield txt_hidden and txt_showed. Then just show/hide one of them as required.

Import MaxGui.Drivers

Strict 

Local window:TGadget
Local textfield:TGadget
Local button:TGadget

window=CreateWindow("My Window",30,20,320,200)


Global btn:Tgadget[3],txt:tgadget[2]


btn[0]=CreateButton("Hide",10,40,100,25,window)
btn[1]=CreateButton("Show",10,70,100,25,window)

txt[0]=CreateTextField(10,4,200,25,window)
txt[1]=CreateTextField(10,4,200,25,window,TEXTFIELD_PASSWORD)

Local show_it:Int=0

SetGadgetText txt[0],"Normal"
SetGadgetText txt[1],"Password"



SetShowWhat(show_it)

While WaitEvent()
	Select EventID()
	Case EVENT_WINDOWCLOSE
		End
		
	Case event_gadgetaction
		Select EventSource()
			Case btn[0]		SetShowWhat(0)
			Case btn[1]		SetShowWhat(1)	
		End Select
	End Select
Wend


Function SetShowWhat:Int(f:Int)
		
		Select f
			Case 0		
						HideGadget txt[0]
						ShowGadget txt[1]
						ActivateGadget txt[1]
						SetGadgetText txt[1],GadgetText(txt[0])
						Print "TXT:0 ("+GadgetText(txt[0])+")"
			Case 1
						HideGadget txt[1]
						ShowGadget txt[0]
						ActivateGadget txt[0]
						SetGadgetText txt[0],GadgetText(txt[1])
						Print "TXT:1 ("+GadgetText(txt[1])+")"
		End Select


End Function

Grisu

(Posted 2015) [#6]

Yeah, at least I can get around recreating the textfield every time. Thanks!

I hoped to use just one though. Just changing the flag of the textfield itself somehow.

Henri

(Posted 2015) [#7]

Hi,

use this function to change the mask in textfield (or remove it):

Function SetPasswordMask(textField:TGadget, mask:String="")	'If mask is empty then mask is removed
	
	If Not textField Then Return
	
	Local char:Int
	If mask Then char = Asc(mask)
	
	SendMessageW(QueryGadget(textField, QUERY_HWND), EM_SETPASSWORDCHAR, char, 0 )
	RedrawGadget(textField)
	
EndFunction

-Henri

Grisu

(Posted 2015) [#8]

Perfect. Best solution. :)

Thanks!

Btw: BMX uses the "●" as default char.

degac

(Posted 2015) [#9]

@Henry

Nice solution, but I suppose it's Windows only...