Pausing scrolling text

BlitzMax Forums/BlitzMax Beginners Area/Pausing scrolling text

Drex	(Posted 2013) [#1]

I have a continous starfield scrolling in the background,but I want to be able to scroll text from the side of the screen to the middle,then pause for a few seconds,and then scroll it off the screen.

what the easiest way to do this ?

matibee

(Posted 2013) [#2]

Obviously you've got to keep track of the position over time. 'Easiest way' depends on your viewpoint, but I like little animators for doing stuff like this...

SuperStrict

Type lerpStage
	Field startTime:Float
	Field endTime:Float
	Field startPos:Float
	Field endPos:Float
	
	Function Create:lerpStage( st:Float , et:Float , sp:Float , ep:Float )
		Local ls:lerpStage = New lerpStage
		ls.startTime = st
		ls.endTime = et
		ls.startPos = sp
		ls.endPos = ep
		Return ls
	End Function
	
	Method Position:Float( time:Float )
		Local t:Float = time - startTime
		t :/ endTime - startTime
		Return startPos + t * ( endPos - startPos )
	End Method 
	
End Type 
	
Type LerpAnimator
	Field stages:TList
	Field time:Float
	Field lastMS:Float
	
	Function Create:LerpAnimator( stage:lerpStage )
		Local la:LerpAnimator = New LerpAnimator
		la.stages = New tlist
		la.stages.addlast( stage )
		Return la
	End Function
	
	Method addStage( stage:lerpStage )
		stages.Addlast( stage )
	End Method
	
	Method Update()
		time :+ 0.001 * Float(MilliSecs() - lastMS)
		lastMS = MilliSecs()
	End Method
	
	Method Position:Float()
		For Local ls:lerpStage = EachIn stages
			If ( ls.startTime <= time And ls.endTime >= time )
				Return ls.Position( time )
			End If
		Next
		Return lerpStage( stages.Last() ).endPos
	End Method
	
	Method Start()
		lastMS = MilliSecs()
		time = 0
	End method
End Type 
		
		
Graphics 800 , 600

Local animator:LerpAnimator = LerpAnimator.Create( lerpStage.Create( 0 , 1 , 800 , 300 ) )
animator.addStage( lerpStage.Create( 1, 6 , 300 , 300 ) )
animator.addStage( lerpStage.Create( 6 , 7 , 300 , - 200 ) )
animator.Start()

While Not AppTerminate()
	
	Cls
	
		DrawRect animator.Position() , 200 , 200 , 200
		DrawText animator.Position(), 0, 0
		
	Flip 1
	
	animator.Update()
	
Wend

I've done many types of flexible animator in the past. Here they are in fact, written in Monkey;

http://www.matibee.co.uk/temp/monkey/animators/

Drex	(Posted 2013) [#3]

I've sussed it,thank you for your help.