FastExt Glow

Blitz3D Forums/Blitz3D Userlibs/FastExt Glow

GIB3D

(Posted 2010) [#1]

Let's say I have a Lightsaber in a 3D scene that I want to have a glow effect on in a scene with other bright objects that I don't want to have a glow effect on. How would I do that using FastExt?

1. RenderGroup normal_objects
2. RenderGroup glow_objects
3. RenderPostprocess(FE_Glow)

Won't work because it would make everything glow

1. RenderGroup glow_objects
2. RenderPostprocess(FE_Glow)
3. RenderGroup normal_objects

Won't work because the objects in the normal_objects group will overlap the glow effect.

Yasha

(Posted 2010) [#2]

Render to two separate buffers. The FE_PostProcess effects work across the entire contents of a buffer, so either use render-to-texture or copyrect to move either the lightsabre or the normal scene to a separate buffer, then glow the one with the lightsabre (on a black background). Afterwards you should be able to use an additive blend to combine the lightsabre with the rest of the scene again (not sure how you would do this for other objects, but additive should be fine for an object made of light).

GIB3D

(Posted 2010) [#3]

On another game I made, I had to use a blur effect on fire to make it look more like fire and less like a sphere with a texture on it. I put the rendered-post-processed objects onto a texture to be used as an Overlay. The only problem with that is that they now are shown behind objects too which is not what I want.

MikhailV

(Posted 2010) [#4]

@GIB3D: Your problem has very difficult decision with postprocess fx :(

I can explain as it to make, but it required two RenderWorld for whole scene (and in the first RenderWorld - all objects should be absolute black, except glowed objects). It will reduce FPS!

There is the simple and best decision for your task! You need to use technology with which help create lasers in 3D scenes. Technology essence — to use 2-4 crossed quads with a glowed texture and with BrushFX=1 and BrushBlend=3.

It is heavy to me to explain in more details, I badly know English language. I hope, some people from community has understood me and can explain you all details of technology!

GIB3D

(Posted 2010) [#5]

Thanks for the answer, I'll try that later ;)

GIB3D

(Posted 2010) [#6]

I've got it working FINALLY!

Include "FastExt.bb"

Const RG_Normal = 1
Const RG_Glow = 2

Global Camera
Global GlowStick

Global GlowOverlay


InitMedia
Main

Function Main()
	While Not KeyDown(1)
		
		pxRenderPhysic 30,0
		
		TurnEntity GlowStick,0,1,0,1
		
		UpdateWorld
		
		;1. Render Glow Objects with Black Objects
		;2. Put into overlay texture
		;3. Cls
		;4. Render normal objects
		;5. Place glow overlay
		
		ColorFilter 0,0,0
		RenderGroup RG_Normal,Camera,1
		ColorFilter
		RenderGroup RG_Glow,Camera,0
		SpecialRender
		
		CopyRectStretch 0,0,GraphicsWidth(),GraphicsHeight(),0,0,TextureWidth(GlowOverlay),TextureHeight(GlowOverlay),BackBuffer(),TextureBuffer(GlowOverlay)
		
		RenderGroup RG_Normal,Camera,1
		CustomPostprocessOverlay(1,1,255,255,255,GlowOverlay)
		RenderPostprocess(FE_Overlay)
		
		;CopyRectStretch 0,0,TextureWidth(GlowOverlay),TextureHeight(GlowOverlay),0,0,256,256,TextureBuffer(GlowOverlay),BackBuffer()
		
		Flip
	Wend
End Function

Function InitMedia()
	Graphics3D 800,600,0,2
	InitExt()
	SetBuffer BackBuffer()
	
	Local Light = CreateLight()
	GroupAttach RG_Normal,Light
	GroupAttach RG_Glow,Light
	
	Camera = CreateCamera()
	PositionEntity Camera,0,5,-10
	RotateEntity Camera,30,0,0
	
	GlowStick = CreateCylinder()
	PositionMesh GlowStick,0,1,0
	PositionEntity GlowStick,2,-1,4
	ScaleEntity GlowStick,.125,2,.125
	RotateEntity GlowStick,30,0,0
	EntityFX GlowStick,1
	GroupAttach RG_Glow,GlowStick
	
	Local Sphere = CreateSphere(8)
	PositionEntity Sphere,2,1,-2
	EntityColor Sphere,255,80,0
	EntityFX Sphere,4
	GroupAttach RG_Glow,Sphere
	
	Local Ground = CreatePlane()
	EntityTexture Ground,GTexture(100,50,20)
	GroupAttach RG_Normal,Ground
	
	Local Obstruction = CreateCube()
	ScaleMesh Obstruction,1,4,1
	EntityColor Obstruction,150,50,10
	EntityFX Obstruction,1
	GroupAttach RG_Normal,Obstruction
	
	GlowOverlay = CreateTexture(1024,1024,1+16+32)
End Function

Function GTexture(r,g,b) ; Green Checkered Texture
	Local T = CreateTexture(64,64)
	
	SetBuffer TextureBuffer(T)
		Color r,g,b
		Rect 0,0,64,64
		
		Color r*1.14,g*1.14,b*1.14
		Rect 32,0,32,32
		Rect 0,32,32,32
	SetBuffer BackBuffer()
	ScaleTexture T,4,4
	PositionTexture T,.25,.25
	
	Return T
End Function

Function SpecialRender()
	CustomPostprocessGlow(1,0,4)
	CustomPostprocessGlowEx(2,2)
	RenderPostprocess(FE_Glow)
End Function

Oiduts Studios

(Posted 2010) [#7]

Wow, that looks great GIB, this could be used for many applications.