LoadTexture <> LodBrush

Blitz3D Forums/Blitz3D Programming/LoadTexture <> LodBrush

Yue	(Posted 2012) [#1]

what is the difference between these two commands?, sorry for my ignorance.

RemiD

(Posted 2012) [#2]

Apparently you have taken the time to search :
http://blitzbasic.com/b3ddocs/command.php?name=CreateTexture
http://blitzbasic.com/b3ddocs/command.php?name=CreateBrush

A brush is a collection of properties such as Colour, Alpha, Shininess, Texture etc that are all stored as part of the brush. Then, all these properties can be applied to an entity, mesh or surface at once just by using PaintEntity, PaintMesh or PaintSurface.

Bobysait

(Posted 2012) [#3]

+ Textures are independants pixel-arrays with some stuff around to manipulate it (let's talk about Low-Level)

+ Brushes are container for materials (they enable to manipulate colors, blend, fx AND textures, they are High-level aspect for mesh)

All the stuff you do, both with textures and brushes, affects the internal brush of the mesh (EntityColor/EntityTexture/EntityFx ...etc), so EntityTexture(entity,texture) will not add a "texture" to an entity, it adds the texture to the "Entity-Brush" of the entity

Then to answer your question :
+ "LoadTexture" loads a single texture.

+ "LoadBrush" loads a single texture then creates a brush to handle it and finally returns the brush (not the texture)

Now, let's go a bit deeper :
each blitz3d "mesh" has one brush (you can access it using EntityBrush(entity), it will return a copy of the brush, so modifying the returned brush will not affect the entity, you have to "repaint" the entity using PaintEntity to overwrite the internal brush)

each surface of the mesh has (or not) a brush
(if not, then it uses the default entitybrush)

each brush may (or not) contains up to 8 textures

So, when you do "TextureEntity", you just add the texture to the EntityBrush (it is made internaly)

Some warning(s) :
/! you can't add a texture to a layer (the layer is the "slot" you specify in EntityTexture Entity,texture,Frame,Layer) that the mesh brush already uses (there won't be any error, but the texture won't be drawn)
So, just remember you can't override the default texture material, you can just "Add"
For exemple : a mesh with EntityColor 255,0,0 will be drawn "red-scaled", whatever the brushes affected to any additional surfaces (surface brush colors and pixels will scale between 0 and 255 red channel)

Here is an exemple on how to use multiple brushes on the same mesh

Graphics3D 800,600,0,2
SetBuffer BackBuffer()

Local cam = CreateCamera()
MoveEntity cam,0,0,-2
CameraClsColor cam,200,200,200

; Texture with Horizontal red lines
Local TexHo = CreateTexture(64,64)
	SetBuffer TextureBuffer(TexHo)
		Color 255,255,255 : Rect 0,0,64,64,1
		Color 255,000,000 : Rect 0,0,64,8,1 : Rect 0,16,64,8,1 : Rect 0,32,64,8,1 : Rect 0,48,64,8,1
	SetBuffer BackBuffer()
	
; Texture with Horizontal green lines (green lines fill the whyte areas of the previous texture)
Local TexHoG = CreateTexture(64,64)
	SetBuffer TextureBuffer(TexHoG)
		Color 255,255,255 : Rect 0,0,64,64,1
		Color 000,255,000 : Rect 0,8,64,8,1 : Rect 0,24,64,8,1 : Rect 0,40,64,8,1 : Rect 0,56,64,8,1
	SetBuffer BackBuffer()
	
; Texture with vertical blue lines
Local TexVe = CreateTexture(64,64)
	SetBuffer TextureBuffer(TexVe)
		Color 255,255,255 : Rect 0,0,64,64,1
		Color 000,000,255 : Rect 0,0,8,64,1 : Rect 16,0,8,64,1 : Rect 32,0,8,64,1 : Rect 48,0,8,64,1
	SetBuffer BackBuffer()

; create a mesh to render
Local mesh = CreateMesh()
	
	; a simple surface affected with the default mesh brush
	Local surf1 = CreateSurface(mesh)
		AddVertex(surf1,-2.0,+1,0, 0,0)
		AddVertex(surf1,-0.1,+1,0, 1,0)
		AddVertex(surf1,-0.1,-1,0, 1,1)
		AddVertex(surf1,-2.0,-1,0, 0,1)
		AddTriangle(surf1,0,1,2)
		AddTriangle(surf1,0,2,3)
		
	; a surface that will be paint with a separate brush
	Local surf2 = CreateSurface(mesh)
		AddVertex(surf2,+0.1,+1,0, 0,0)
		AddVertex(surf2,+2.0,+1,0, 1,0)
		AddVertex(surf2,+2.0,-1,0, 1,1)
		AddVertex(surf2,+0.1,-1,0, 0,1)
		AddTriangle(surf2,0,1,2)
		AddTriangle(surf2,0,2,3)


Color 255,255,255

; use the horizontal red texture on the entity (on layer "0")
; it will use add the texture to the default mesh brush
	EntityTexture mesh, TexHo,0,0

	RenderWorld
		Color 000,000,000:Rect 0,0,GraphicsWidth(),40,1
		Color 255,255,000:Text 10,10, "Hit any key to Paint the surface 2 with blue Vertical Lines"
	Flip:WaitKey

; use the vertical texture on the brush for surface 2 only (on layer "1")
	; create a brush for surface2
	Local brush = CreateBrush() : BrushFX brush,1
	; use the vertical tex on the material
	BrushTexture brush, TexVe, 0,1
	; paint the surface 2
	PaintSurface surf2, brush

	RenderWorld
		Color 000,000,000:Rect 0,0,GraphicsWidth(),40,1
		Color 255,255,000:Text 10,10, "Hit any key to Paint the Entity with additional Green Horizontal Lines"
	Flip:WaitKey

; now get the entitybrush and repaint with a green texture (on layer "2")
	Local brushg = GetEntityBrush(mesh)
	BrushTexture brushg,TexHoG,0,2
	PaintEntity mesh, brushg
	
	RenderWorld
		Color 000,000,000:Rect 0,0,GraphicsWidth(),40,1
		Color 255,255,000:Text 10,10, "Hit any key to Quit"
	Flip:WaitKey

End

if you want, add a EntityColor Mesh, 255,000,000 above (or below) EntityTexture Mesh,texHo,0,0 and you'll see what I meant.

Have fun

Last edited 2012