problem load Mesh

Blitz3D Forums/Blitz3D Programming/problem load Mesh

Yue	(Posted 2012) [#1]

Hi I have a problem loading a mesh, the message returns me is: Entity is not Mesh "

Any suggestions.

Graphics3D 800,600,32,2
SetBuffer BackBuffer()

pxCreateWorld(1,"")

cam = CreateCamera()
PositionEntity cam,0,100,-200
CameraClsColor cam,128,128,128
CreateLight()

plane = CreatePlane()
EntityColor plane, 0,128,128

Yue = LoadAnimMesh("Yue.b3d")
YuePX = LoadAnimMesh("YuePX.b3d")

HideEntity Spetsnaz
HideEntity SpetsnazPX

Repeat 
	If KeyHit(57) Then CreateRagdoll(Yue, YuePX,Rand(-100,100),50,Rand(0,100), Rand(0,360), Rand(0,360), Rand(0,360))
	
	pxRenderPhysic(30,0)
	UpdateRagdolls()
	RenderWorld()
	Flip
Until KeyHit(1)
End

Type Ragdoll
	Field Mesh
	Field Joints[100] 
	Field Bodies[100] 
	Field Bones[100] 
End Type

Function CreateRagdoll(man, px,x#,y#,z#, pitch#,yaw#,roll#)
	man = CopyEntity(man)
	PositionEntity man,x,y,z	
	RotateEntity man,pitch,yaw,roll	
	R.Ragdoll = New Ragdoll
	If EntityClass (man) <> "Mesh" Then	
		R\Mesh = GetChild(man,1)
		EntityParent R\Mesh,0
		FreeEntity man
	Else
		R\Mesh = man
	End If
	CreateHullsForAllChilds(R\Mesh, px, R)
	DeparentAllChilds(R\Mesh)
End Function

Function DeparentAllChilds(mesh)
	Repeat
		If CountChildren(mesh) = 0 Then Exit
		DeparentAllChilds(GetChild(mesh,1))	
	Forever 
	EntityParent mesh,0	
End Function

Function UpdateRagdolls()
	For R.Ragdoll = Each Ragdoll
		For i= 0 To 100
			If R\Bodies[i] = 0 Then Exit
			pxBodySetEntity R\Bones[i], R\Bodies[i]
		Next
	Next
End Function

Function CreateHullsForAllChilds(mesh, pxmesh, R.Ragdoll, batya=0)
	HullMesh = FindChild(pxmesh, EntityName(mesh)+"px")
	If HullMesh Then
		Hull = BodyCreateHull(HullMesh, 10)
		pxBodySetPosition Hull, EntityX(mesh,1), EntityY(mesh,1), EntityZ(mesh,1)
		pxBodySetRotation Hull, EntityPitch(mesh,1), EntityYaw(mesh,1), EntityRoll(mesh,1)
		
		For i=0 To 100
			If R\Bodies[i] = 0 Then 
				R\Bodies[i] = Hull
				R\Bones[i] = mesh
				Exit
			End If
		Next		
		If batya Then
			Joint = pxJointCreateSpherical (batya,Hull,pxBodyGetPositionX(Hull),pxBodyGetPositionY(Hull),pxBodyGetPositionZ(Hull),0,1,0)
			pxJointSphericalSetLimitAngle(Joint, 30,1, 0)
			pxJointSphericalSetLimitTwist(Joint,-10,10,10,1,0)
			pxJointSphericalSetLimitSpring(Joint, 10, 1, 0)
			For i=0 To 100
			If R\Joints[i] = 0 Then 
				R\Joints[i] = Joint
				Exit
			End If
		Next	
		End If
	End If
	For i=1 To CountChildren(mesh)
		CreateHullsForAllChilds(GetChild(mesh,i), pxmesh, R, Hull)
	Next
End Function

Function BodyCreateHull%(mesh%, mass#)

    Local nsurf = CountSurfaces(mesh) ; << ERROR HERE!! :(
    Local nvert = 0
    For ns = 1 To nsurf
        Local surf = GetSurface(mesh,ns)
        nvert = nvert + CountVertices(surf)
    Next
         vbank = CreateBank(nvert*4*3)
    nv = 0
    For ns = 1 To nsurf
        surf = GetSurface(mesh,ns)
        nvv = CountVertices(surf)
        For nvc = 0 To nvv - 1
             PokeFloat vbank,nv*12+0,VertexX(surf,nvc)
             PokeFloat vbank,nv*12+4,VertexY(surf,nvc)
             PokeFloat vbank,nv*12+8,VertexZ(surf,nvc)
            nv = nv+1
        Next
    Next
    Local bbb%= pxBodyCreateHull(vbank, nvert, mass)
    FreeBank vbank
    Return bbb
End Function

Zethrax

(Posted 2012) [#2]

In the lines:-

Yue = LoadAnimMesh("Yue.b3d")
YuePX = LoadAnimMesh("YuePX.b3d")

you're not actually testing to see if the models were loaded correctly. Replace these with:-

Yue = LoadAnimMesh("Yue.b3d")
YuePX = LoadAnimMesh("YuePX.b3d")
If Yue = 0 Then RunTimeError "Yue model failed to load."
If YuePX = 0 Then RunTimeError "YuePX model failed to load."

and that should tell you if the problem lies with the files or filepaths.

What line was highlighted in the Bltz3d debugger when the problem occurred? Once you find that out, put Cls : Print <entity-handle-variable> : Waitkey : End code (where <entity-handle-variable> is the name of the variable that holds the suspect entity handle) before the command where the error occurs to print the value of the entity handle that is causing the crash.

Debugging is largely about doing stop-checks (stop the execution and return information that tells you about what's really going on with the code execution) to zero in on where the execution of the code deviates from what you need or expect to be happening..