Using sine to convey a swaying motion?

Blitz3D Forums/Blitz3D Programming/Using sine to convey a swaying motion?

Cubed Inc.

(Posted 2012) [#1]

How do you convey a swaying, or pendulum like motion using Sin()?

Matty

(Posted 2012) [#2]

Set the position, x,y or z based on a calculation such as:

position = offset + length * Sin(angle)

and simply change the angle each frame slightly...

Kryzon

(Posted 2012) [#3]

You can also use it to modulate an 'angle offset' that you apply to the pivot of the pendulum.

[bbcode]
Const ROT_ANGLE# = 30.0

[...]

RotateEntity pendulumPivot, 0, 0, (Sin(angle) * ROT_ANGLE)

;Pendulum will swing from -30 to 30.
[/bbcode]

Cubed Inc.

(Posted 2012) [#4]

What do you mean by changing the angle by each frame slightly? You want me to set up a flag where the angle of the pendulum changes from 30 to -30 after a certain amount of time, or am I misunderstanding the whole thing?

Adam Novagen

(Posted 2012) [#5]

You're only half-misunderstanding. Open this example, it's in the B3D docs for Sin() and Cos():

; Sin / Cos / Tan example. 

; Left/Right arrow keys change angle. Escape quits. 

Const width = 640, height = 480 
Const radius# = .2 * height 
Const KEY_ESC = 1, KEY_LEFT = 203, KEY_RIGHT = 205 

Graphics width, height 
SetBuffer BackBuffer( ) 
Origin width / 3, height / 2 

angle# = 0.0 

While Not KeyDown( KEY_ESC ) 

; NOTE: It is usually best to avoid very large angles. 
; The 'If angle...' lines show one way to do this. 
; Mod is another possibility. 

If KeyDown( KEY_LEFT ) Then angle = angle - 2.5 
; If angle < 0.0 Then angle = angle + 360 

If KeyDown( KEY_RIGHT ) Then angle = angle + 2.5 
; If angle >= 360.0 Then angle = angle - 360 

Cls 

Color 80, 80, 0 ; pale yellow circle 
Oval -radius, -radius, 2 * radius, 2 * radius, False 

For a# = 0.0 To Abs( angle Mod 360 ) Step .5 

x# = radius * Cos( a ) ; (x,y) is a point on the circle 
y# = radius * Sin( a ) ; corresponding to angle a. 

If ( angle Mod 360 < 0 ) Then y = -y ; reverse for negative angle 
WritePixel x, y, $ffff00 ; bright yellow 

Next 

Color 255, 255, 0 ; yellow 
Line 0, 0, radius * Cos( angle ), radius * Sin( angle ) 

Color 0, 255, 0 ; green 
Line 0, 0, radius * Cos( angle ), 0 
Text radius * 1.5, 10, "Cos( angle ) = " + Cos( angle ) 

Color 255, 0, 0 ; red 
Line radius * Cos( angle ), 0, radius * Cos( angle ), radius * Sin( angle ) 
Text radius * 1.5, -10, "Sin( angle ) = " + Sin( angle ) 

Color 255, 255, 255 
Text radius * 1.5, -30, " angle = " + angle 
Text radius * 1.5, 30, "Tan( angle ) = " + Tan( angle ) 

Flip 

Wend 

End

Hold down one of the arrow keys and watch the green (cos) line. You'll notice that although angle# increases (or decreases, depending on which button you press) at a steady, ongoing rate, the green line will "swing" side to side in a perfect pendulum motion. I can't quite put it into clear words, but if you look closely at this example and what happens to the Sin() and Cos() lines you should be able to figure it out: sine and cosine "undulate" while a circular angle increases or decreases.

Last edited 2012