Window Manipulation Project

Blitz3D Forums/Blitz3D Programming/Window Manipulation Project

mk2y10

(Posted 2012) [#1]

Hello everyone, I have been working in the background and decided to let others know about the commands I have been mastering to make Blitz3D more functional. What I have been up to most recently is making desktop widgets for Windows 7 using blitz3d. The reason for this is to help me organize all my information about programming. (I just finished a widget that searches through previously written functions. You type in the name of it, and it lists the results in real time. You just click on one of the results and a weeder copies the function you want out of the code and launches a .bb file that only has the function in it. Clean, Fast, and simple.)

Here I would like to post some functions for Window Manipulation (I will add more as I go) for those who want to have more control over objects in Windows.

Note: You will need the .decls for Windows User32.dll, GDI32.dll, and some others. If I find the link, I will post it around here somewhere.


;This is a compiled list of window manipulation commands, most use the User32.dll and GDI32.dll

;This returns the desktop handle
Function GetDesktop()
Return api_GetDesktopWindow()
End Function

;This returns the applications window handle
Function GetWindow()
Return SystemProperty("AppHWND")
End Function

;This moves the the stated Window to the new destination
Function MoveWindow(Win,LX,LY,SX,SY)
api_SetWindowPos(Win,0,LX,LY,SX,SY,0)
End Function

;This returns true if the pointer is over the specified area of the SCREEN.
Function PointerOver(LX,LY,SX,SY)
MX=PointerX()
MY=PointerY()
If MX>LX-1 And LX+SX>MX
If MY>LY-1 And LY+SY>MY Then Return 1
EndIf
End Function

;This returns the X location of the pointer in relation to the screen.
Function PointerX()
B=CreateBank(8)
api_GetCursorPos(B)
Re=PeekInt(B,0*4)
FreeBank(B)
Return Re
End Function

;This returns the Y location of the pointer in relation to the screen.
Function PointerY()
B=CreateBank(8)
api_GetCursorPos(B)
Re=PeekInt(B,1*4)
FreeBank(B)
Return Re
End Function

;This function changes the window's shape using the mask of an image. (A 0 value is transparent)
;NOTE: This function is in Alpha Stage, the following bugs have been found:
;Bug 1 - If there are too many pixels that are transparent then the function will death freeze!
Function SetWindowShape(Win,Im,LX=0,LY=0)
If Win=0 Then Return 0
If Im=0 Then Return 0
Bf=ImageBuffer(Im)
LockBuffer BF
SX=ImageWidth(Im)
SY=ImageHeight(Im)
Rg=api_CreateRectRgn(LX,LY,SX+LX,SY+LY)
For A=0 To SX-1
For B=0 To SY-1
	X=LX+A
	Y=LY+B
	Px=ReadPixelFast(A,B,Bf)
	If Px<0 Then Px=Px+256^3
	If Px=0
		NRg=api_CreateRectRgn(X,Y,X+1,Y+1)
		C=api_CombineRgn(Rg,NRg,Rg,3)
	EndIf
Next
Next
api_SetWindowRgn(Win,Rg,1)
UnlockBuffer BF
End Function


;This returns the specified window's height (Size Y)
Function WindowHeight(Win)
B=CreateBank(64)
api_GetWindowPlacement(Win,B)
Re=PeekInt(B,10*4)
FreeBank(B)
Return Re
End Function

;This returns the specified window's width (Size X)
Function WindowWidth(Win)
B=CreateBank(64)
api_GetWindowPlacement(Win,B)
Re=PeekInt(B,9*4)
FreeBank(B)
Return Re
End Function

;This returns the X location of the specified window
Function WindowX(Win)
B=CreateBank(64)
api_GetWindowPlacement(Win,B)
Re=PeekInt(B,7*4)
FreeBank(B)
Return Re
End Function

;This returns th Y location of the specified window
Function WindowY(Win)
B=CreateBank(64)
api_GetWindowPlacement(Win,B)
Re=PeekInt(B,8*4)
FreeBank(B)
Return Re
End Function

If you have any comments, or requests, please let me know.

I am currently working on custom shapes for Windows. (Using Images as masks)

EDIT 1/27:
I have a new addition to the set of codes above, it is the SetWindowShape command. It sets the shape of the window using an image as a mask. The parts of the image that are 0,0,0 will be transparent while the other colors will not. Use this for crazy shaped windows. Please note, the coordinates used are from the offset of the window gadget itself, not the buffer on blitz. Use the optional LX and LY parameters to move the location where the region is drawn!

:) - Mike

Last edited 2012

Guy Fawkes

(Posted 2012) [#2]

Thank you for your contribution to the community! This is AWESOME! :)