Tokamak Water combined with water ripple

Blitz3D Forums/Blitz3D Programming/Tokamak Water combined with water ripple

Guy Fawkes

(Posted 2011) [#1]

Hi all, I'm having a bit of a problem getting this code to work.

What I have done is combined Tokamak Physics code which is a water physics simulation, with a demo that creates ripples when an object "touches" the water.

the tokamak part is fine, but the PROBLEM is these lines:

Water=fxWater_Create( "floor",  DEMO_WATER_WIDTH, DEMO_WATER_DEPTH, 0.025 )
PositionEntity Water,0,-10,0
EntityTexture Water, tex
FlipMesh Water

for some reason, it's saying that the entity "water", doesn't exist. which it CLEARLY does...

Graphics3D 640,480,0,2

Const Rigid_Bodies=200,Animated_Bodies=7
TOKSIM_SetRigidBodiesCount Rigid_Bodies
TOKSIM_SetAnimatedBodiesCount Animated_Bodies
TOKSIM_SetRigidParticleCount 0
TOKSIM_SetControllersCount 0
TOKSIM_SetGeometriesCount Rigid_bodies+Animated_Bodies ;Assuming each one only has one geometry. Not true with more complex rigid bodies and animated bodies.
TOKSIM_CreateSimulator(0,-1,0)

Global fxWATER_MAX = 5				;max number of active surfaces/effects at one time
Global fxWATER_NUM = 0				;current number of active water effects.

Global FXWATER_MAX_WIDTH = 100		;max sub-division for water meshes
Global FXWATER_MAX_DEPTH = 100		;max sub-division for water meshes

Global FXWATER_MAX_BANKS = fxWATER_MAX * 2
Global FXWATER_NUM_BANKS = 0


Global DEMO_WATER_WIDTH	 = 40 	;--> Adjust these for different plane sizes / mesh resolution
Global DEMO_WATER_DEPTH  = 40

;reserve memory banks for vertice altitudes
Dim fxWaterBank#(FXWATER_MAX_BANKS, FXWATER_MAX_WIDTH, FXWATER_MAX_DEPTH )


Type fxWaterWave

	Field id
	Field name$
	
	Field active		;if not ripples then fx is not actiave
	
	Field parent		;parent entity (if any)
	Field entity		;water mesh
	Field surface		;water surface

	Field bank1			;pointers to array for mem storage
	Field bank2

	Field width			;width of plane / surface
	Field depth			;depth of plane / surface
	Field dampening#	;water dynamics

End Type

;Demo options
Global OPT_WIREFRAME = 0
Global OPT_REFRSH 	 = 0
Global OPT_BALLFREEZE= 0
Global OPT_CEILING	 = 1

;Create Scene
wall1=CreateCube()
ScaleEntity wall1,50,20,1
wall1rb=TOKAB_Create()
TOKAB_AddBox wall1rb,100,40,2
TOKAB_SetPosition wall1rb,0,0,-50
PositionEntity wall1,0,0,-50

wall2=CreateCube()
ScaleEntity wall2,50,20,1
wall2rb=TOKAB_Create()
TOKAB_AddBox wall2rb,100,40,2
TOKAB_SetPosition wall2rb,0,0,50
PositionEntity wall2,0,0,50

wall3=CreateCube()
ScaleEntity wall3,1,20,50
wall3rb=TOKAB_Create()
TOKAB_AddBox wall3rb,2,40,100
TOKAB_SetPosition wall3rb,-50,0,0
PositionEntity wall3,-50,0,0

wall4=CreateCube()
ScaleEntity wall4,1,20,50
wall4rb=TOKAB_Create()
TOKAB_AddBox wall4rb,2,40,100
TOKAB_SetPosition wall4rb,50,0,0
PositionEntity wall4,50,0,0

Flor=CreateCube()
ScaleEntity flor,50,1,50
PositionEntity flor,0,-20,0
Florb=TOKAB_Create()
TOKAB_AddBox Florb,100,2,100
TOKAB_SetPosition florb,0,-20,0

side1=CreateCube()
ScaleEntity side1,Sqr(3)*25/2,1,50    ;35.3552
RotateEntity side1,0,0,30
PositionEntity side1,32,-10,0
Side1b=TOKAB_Create()
TOKAB_AddBox Side1b,Sqr(3)*25,2,100
TOKAB_SetRotation Side1b,0,0,30
TOKAB_SetPosition Side1b,32,-10,0

side2=CreateCube()
ScaleEntity side2,Sqr(3)*25/2,1,50    ;35.3552
RotateEntity side2,0,0,-30
PositionEntity side2,-32,-10,0
Side2b=TOKAB_Create()
TOKAB_AddBox Side2b,Sqr(3)*25,2,100
TOKAB_SetRotation Side2b,0,0,-30
TOKAB_SetPosition Side2b,-32,-10,0

Global tex

tex = create_noise_map()

Global Water

Water=fxWater_Create( "floor",  DEMO_WATER_WIDTH, DEMO_WATER_DEPTH, 0.025 )
PositionEntity Water,0,-10,0
EntityTexture Water, tex
FlipMesh Water

;force refresh
fxWater_dimple( Water, 1,1, 0.001, 0.001)

Global bmaxx# =  DEMO_WATER_WIDTH * 0.5	;half the width of the water plane
Global bmaxy# = 10.0
Global bmaxz# =  DEMO_WATER_DEPTH * 0.5	;half the depth of the water plane

campiv=CreatePivot()
cam=CreateCamera(campiv)
PositionEntity cam,0,50,-50
PointEntity cam,campiv

SeedRnd MilliSecs()

Dim obj(Rigid_Bodies)
Dim rb(Rigid_Bodies)

For i=1 To Rigid_Bodies
rot#=rot#+8.2
x#=Cos(rot)*20
z#=Sin(rot)*20
nr=Rnd(1,2)        
If nr=2 Then
obj(i) = CreateCube()
ScaleEntity obj(i),1,0.5,0.5
rb(i) = TOKRB_Create()
geom = TOKRB_AddBox(rb(i),2.0,1.0,1.0)
TOKGEOM_SetMaterialIndex geom,1
TOKRB_SetPosition rb(i),x#,2+i*0.2,z#
TOKRB_SetLinearDamping rb(i),0.001
TOKRB_SetAngularDamping rb(i),0.002    
TOKRB_SetMass rb(i),2.0
TOKRB_SetBoxInertiaTensor rb(i),2.0,1.0,1.0,2.0
EntityColor obj(i),Rnd(100,230),Rnd(100,230),Rnd(100,230)
ElseIf nr=1
obj(i) = CreateSphere()
rb(i) = TOKRB_Create()
TOKRB_AddSphere rb(i),2
TOKRB_SetPosition rb(i),x#,2+i*0.2,z#
TOKRB_SetAngularDamping rb(i),0.002
TOKRB_SetLinearDamping rb(i),0.001
TOKRB_SetMass rb(i),2.0
TOKRB_SetSphereInertiaTensor rb(i),2,2.0
EntityColor obj(i),Rnd(100,230),Rnd(100,230),Rnd(100,230)
EndIf
Next

l=CreateLight()
RotateEntity l,20,10,0

While Not KeyHit(1)
    TurnEntity campiv,0,.1,0
    TOKSIM_Advance .1,1
    For i=1 To Rigid_Bodies
        PositionEntity obj(i),TOKRB_GetX#(rb(i)),TOKRB_GetY#(rb(i)),TOKRB_GetZ#(rb(i))
        RotateEntity obj(i),TOKRB_GetPitch#(rb(i)),TOKRB_GetYaw#(rb(i)),TOKRB_GetRoll#(rb(i)),False
        If TOKRB_GetY#(rb(i))<-10 Then
            If TOKRB_IsGravityEnabled(rb(i)) Then TOKRB_GravityEnable rb(i),0
            TOKRB_ApplyImpulse rb(i),0,.02,0
            TOKRB_SetAngularDamping rb(i),.01
            TOKRB_SetLinearDamping rb(i),.01
        ElseIf TOKRB_IsGravityEnabled(rb(i))=0 Then
            TOKRB_GravityEnable rb(i),1
            TOKRB_SetAngularDamping rb(i),.002
            TOKRB_SetLinearDamping rb(i),.001
        EndIf        
    Next
    If KeyHit(57) Then
        For i=1 To Rigid_Bodies
        TOKRB_ApplyImpulse rb(i),Rand(-2,2),Rand(5,10),Rand(-2,2)
        Next
    EndIf

	update_player(player)

	;update fxWater
	fxWater_update()

	UpdateWorld
    RenderWorld
    Flip
Wend
TOKSIM_DestroySimulator

Function update_player(ent)

	;check floor bounce
	If EntityY#(ent) < -bmaxy+2 Then
		;reverse vertical direction
		by# = by# * -1.0
		;create dimple
		fxWater_Dimple(Water, EntityX(ent)+bmaxx,EntityZ(ent)+bmaxz, 1.0, 5.0)
		;slightly alter direction
		bx# = bx# + Rnd#(-0.25, 0.25)
		bz# = bz# + Rnd#(-0.25, 0.25)
	EndIf

End Function

Function fxWater_Create( name$="", width=1, depth=1, damp#=0.01, parent=0 )


	;create new Wavy water effect plane
	w.fxWaterWave = New fxWaterWave

	w\id		= 1
	w\name$		= name$
	
	w\active	= True
	
	;create rectangular grid mesh
	w\width		= width
	w\depth		= depth
	w\dampening#= 1 - damp#
	
	w\parent	= parent
	w\entity	= create_mesh_plane( w\width, w\depth, False, parent )
	w\surface	= GetSurface(w\entity,1)
	
	;store handle for quick retrieval during collision
	NameEntity w\entity, Handle(w)
	
	;reserve memory banks to hold vertex energy
	w\bank1		= fxWater_Create_Buffer()
	w\bank2		= fxWater_Create_Buffer()
	
	;return mesh handle
	Return Handle(w)
	
End Function

;--------------------------------------------------------------------------------------------------

Function fxWater_update()

	For w.fxWaterWave = Each fxWaterWave

		;if the surface is perfectly flat then this value remains 0
		dyna# = 0
		
		;process water
	    For x = 1 To w\width-1
	        For z = 1 To w\depth-1
				fxWaterBank#(w\bank2,x,z) = (fxWaterBank#(w\bank1,x-1,z) + fxWaterBank#(w\bank1,x+1,z) + fxWaterBank#(w\bank1,x,z+1) + fxWaterBank#(w\bank1,x,z-1)) / 2.1-fxWaterBank#(w\bank2,x,z) 
				fxWaterBank#(w\bank2,x,z) = fxWaterBank#(w\bank2,x,z) * w\dampening#
				dyna# = dyna# + fxWaterBank#(w\bank2,x,z)
	        Next
	    Next

		;Only deform patch if necesary
		If dyna# <> 0 Then
		    ;PatchTransform
			k=0
			For i = 0 To w\depth
		        For j = 0 To w\width
					VertexCoords(w\surface,k,VertexX(w\surface,k),fxWaterBank#(w\bank2,j,i),VertexZ(w\surface,k))
		            k=k+1
		        Next
		    Next
		EndIf

		;should be optional - depending on type of texture (slows down seriously!)
		UpdateNormals w\entity
		
	    ;SwapWaterBuffer
		tmp = w\bank1
		w\bank1 = w\bank2
		w\bank2 = tmp

	Next

End Function

;--------------------------------------------------------------------------------------------------

Function fxWater_Dimple( hand, x,z, force#=1.0, range#=1.0)
	
	w.fxWaterWave = Object.fxWaterWave(hand)

	For xg = x - range# * 0.5 To x+range# * 0.5
		For zg = z - range# * 0.5 To z+range# * 0.5
			If xg> 0 And xg < w\width And zg>0 And zg<w\depth Then
				fxWaterBank#(w\bank2, xg,zg) = force#
			EndIf
		Next
	Next

End Function

;--------------------------------------------------------------------------------------------------

Function fxWater_get_surface( hand )

	w.fxWaterWave = Object.fxWaterWave( hand )
	Return w\surface

End Function

;--------------------------------------------------------------------------------------------------

Function fxWater_get_entity( hand )

	w.fxWaterWave = Object.fxWaterWave( hand )
	Return w\entity

End Function

;--------------------------------------------------------------------------------------------------

Function fxWater_Create_Buffer() ; xsize=1, zsize=1 )

	If FXWATER_NUM_BANKS >= FXWATER_MAX_BANKS Then 
		RuntimeError "[fxWater::Create_buffer] Max amount of fxWater memory banks reached!"
	Else
		;create a new memory bank and resize it to fit
		FXWATER_NUM_BANKS = FXWATER_NUM_BANKS + 1
		;NOTE: convert array into memory bank
	EndIf

	Return FXWATER_NUM_BANKS
	
End Function

;--------------------------------------------------------------------------------------------------

Function fxWater_Free_Buffers( )

;| Frees all buffers. Call as a part of when scene/level is removed from memory.


	;NOTE: resize memory banks to 0 (once implemented).

	Return 0
	
End Function

;--------------------------------------------------------------------------------------------------

;Creates a flat grid mesh
Function create_mesh_plane(width=1,depth=1,doublesided=False,parent=0)

	tot = width + (depth*width)
	mix#= (width+depth) * 0.5
	
	mesh=CreateMesh( parent )
	surf=CreateSurface( mesh )
	
	stx#=-.5
	sty#=stx
	stp#=Float(1)/Float(mix#)
	y#=sty#
	
	For a=0 To depth
		x#=stx
		v#=a/Float(depth)
		
		For b=0 To width
			u#=b/Float(width)
			AddVertex(surf,x,0,y,u,v)
			x=x+stp
		Next
		y=y+stp
	Next
	
	For a=0 To depth-1
		For b=0 To width-1
			v0=a*(width+1)+b:v1=v0+1
			v2=(a+1)*(width+1)+b+1:v3=v2-1
			AddTriangle( surf,v0,v2,v1 )
			AddTriangle( surf,v0,v3,v2 )
		Next
	Next
	
	UpdateNormals mesh

	If doublesided=True Then EntityFX mesh,16
	
	FitMesh mesh, -width*0.5, 0, -depth*0.5, width, 1, depth
	
	Return mesh

	
End Function

;--------------------------------------------------------------------------------------------------

Function create_noise_map()

; creates a noise map to be used as a generic reflection map

	sq = 128

	tex = CreateTexture(sq,sq,65,1)
	tbuf = TextureBuffer(tex)
	SetBuffer(tbuf)
	
	For x = 0 To sq-1
		For y = 0 To sq-1
			r = Rnd(100,120)
			g = Rnd(100,130)
			b = Rnd(190,240)
			Color r,g,b
			Rect x,y,1,1
		Next
	Next	
	
	SetBuffer(BackBuffer())
	
	Return tex

End Function


;--------------------------------------------------------------------------------------------------

If you need me to, I can upload a copy of the DECLS and DLLs for Tokamak.

Thanks everyone for all the help! :)

H&K	(Posted 2011) [#2]

You see how there are FOUR lines that referance "Water"?
Well which one is the error on?

Anyway doesnt this need a return type?

Function fxWater_Create( name$="", width=1, depth=1, damp#=0.01, parent=0 )

Guy Fawkes

(Posted 2011) [#3]

anything after water= is the problem apparently.

Floyd

(Posted 2011) [#4]

I searched this site for fxWater_Create and followed the first link other than this thread.

It contains sample code, including

Global w1 = fxWater_Create( "floor",  DEMO_WATER_WIDTH, DEMO_WATER_DEPTH, 0.025 )
water = fxWater_get_entity( w1 )
PositionEntity water, 0, -10, 0

This is what you have, except for the call to fxWater_get_entity. So fxWater_Create must be returning a more complicated object, part of which is the actual water entity.

Edit: Now that I've actually looked at the code it creates something called an fxWaterWave:

Type fxWaterWave

	Field id
	Field name$
	
	Field active		;if not ripples then fx is not actiave
	
	Field parent		;parent entity (if any)
	Field entity		;water mesh
	Field surface		;water surface

	Field bank1			;pointers to array for mem storage
	Field bank2

	Field width			;width of plane / surface
	Field depth			;depth of plane / surface
	Field dampening#	;water dynamics

End Type

Last edited 2011

H&K	(Posted 2011) [#5]

Well reading rez post FXWater_Create has at the end of it

;return mesh handle
	Return Handle(w)
	
End Function

Im not saying you are wrong, as its my opinion that its a return type error as well. But it does look like he has tried to "handle it"
@Rex If the above fix worked, move if to inside the type.

;return mesh handle
	Return fxWater_get_entity(w)
	
End Function

Guy Fawkes

(Posted 2011) [#6]

here's what i have in my globals section.

it's not working still.

same error, same line.

Global tex

tex = create_noise_map()

Global Water1

Water1=fxWater_Create( "floor",  DEMO_WATER_WIDTH, DEMO_WATER_DEPTH, 0.025 )
PositionEntity Water1,0,-10,0
EntityTexture Water1, tex
FlipMesh Water1

Global water

water = fxWater_get_entity( Water1 )

;force refresh
fxWater_dimple( Water, 1,1, 0.001, 0.001)

Global bmaxx# =  DEMO_WATER_WIDTH * 0.5	;half the width of the water plane
Global bmaxy# = 10.0
Global bmaxz# =  DEMO_WATER_DEPTH * 0.5	;half the depth of the water plane

Gabriel

(Posted 2011) [#7]

same error, same line.

Well unless you've posted the wrong code, you still haven't made the change that Floyd told you to make, so it's hardly surprising that you've still got the same error on the same line. You're still calling two different entity commands and one mesh command on an object which patently isn't an entity or a mesh. Only *then* do you get the entity handle, which you then use incorrectly, as the only function you give it to is the one you *didn't* need the entity for. For that, you needed the water object.

It looks to me as though you're trying to run before you can walk. You're using code (presumably) written by someone else that you don't understand. It isn't going to end well. I know that learning the basics is boring, but it avoids all the frustration you're getting now.

Im not saying you are wrong, as its my opinion that its a return type error as well. But it does look like he has tried to "handle it"

Handl'ing it doesn't make it an entity though. It just switches between object and handle. It's not an entity. The entity is a field within that object. I'm also pretty sure that's not Rez's code.

Last edited 2011

H&K	(Posted 2011) [#8]

Handl'ing it doesn't make it an entity though. It just switches between object and handle. It's not an entity. The entity is a field within that object. I'm also pretty sure that's not Rez's code.

I did realise that which is why I also said use fxwater_get_entity. My point was that he at least knew he had to get a handle, which is a step in the right direction.

The thing I dont know, which made me "hedge" my comment was if B3d needed to define a return type or not.

The way I see it, is that even tho I dont know the answer to solve the problem, I could at least point out where the problem was. (I dont have b3d, just the sdk so Im guessing most of the time on syntax). Obviously my comments are only helpful to ppl who have simply overlooked the reason, and not ppl who dont understand the code at all.

I should probably stop replying to REZes posts if this is the case.

Last edited 2011

Guy Fawkes

(Posted 2011) [#9]

hey wo wo WOH.

I did TOO post the fix.

Look

Global water

water = fxWater_get_entity( Water1 )

Guy Fawkes

(Posted 2011) [#10]

Either way, that's ok mates. I'm switching to Newton Physics, you guys can close this thread! :)

Thanks for the help! :)

Gabriel

(Posted 2011) [#11]

I did TOO post the fix.

water = fxWater_get_entity( Water1 )

As I already explained, this is NOT the fix. That line goes after you've already tried to use the object as an entity three times, and it puts the entity in the wrong variable, where you subsequently proceed to use the entity as an object. Instead of fixing things, you've actually broken them even worse.

My point was that he at least knew he had to get a handle, which is a step in the right direction.

He doesn't though. The Handle/Object thing is completely unrelated to entities. If it was an entity, he could use it without handl'ing it.

I should probably stop replying to REZes posts if this is the case.

Well the same could be said for me in that respect. We're both in the same boat in that you don't own B3D and I no longer have it installed, and we're both just trying to help when someone is obviously struggling.

Either way, that's ok mates. I'm switching to Newton Physics

Newton physics will still require you to not mix entities and objects up. It will still require you to learn and practice the basics of programming. All you're going to achieve by switching physics engines is to lose the progress you already made by trying to solve this. You're not far off making this work. It would be a shame to throw it all away.