Help Change Gamma

Blitz3D Forums/Blitz3D Programming/Help Change Gamma

Yue	(Posted 2010) [#1]

Each time I have to learn something new, I think that's what I like to program, and as I read a book on c + +, and the only way to learn is to schedule, studying third code.

Well, as I am a new me on this thank all those who in one way or another help me despite my great my language barrier. Anyway, I need to know how to implement a bar with an indicator to be handled by the mouse pointer change the gamma.

This configuration is to put it in my project options.

A greeting.

jfk EO-11110

(Posted 2010) [#2]

As far as I remember, chanching Gamma on all 16 Million colors is rather slow, eg:

For I=0 To 255
For j=0 To 255
For k=0 To 255
SetGamma i,j,k,255-i,255-j,255-k ; invert
Next
Next
Next
UpdateGamma()

Someone correct me if I get this wrong, but isn't this the way to change Gamma for all Colors? Well the sample takes several seconds and may not be useful for a mouse control bar IMO.

Last edited 2010

_PJ_	(Posted 2010) [#3]

I'm pretty sure that's how it's done, jfk, yeah.

To get around the slowness for a 'slider-bar' type control, it may be best suited to only apply the gamma change once an "Apply" button is clicked, rather than dynamically as the slider moves.

Essentially, the format would be:

(Of course, this is very basic)

Graphics 800,600

; This is our variable to control the change of gamma values. Only one value is used since we update Reg Green & Blue together.
Global GAMMA_DELTA=128

; These are the on-screen dimensions and position of the slider image
Global SLIDER_PIXEL_WIDTH=400
Global SLIDER_PIXEL_HEIGHT=15
Global SLIDER_CONTROL_PIXEL_WIDTH=5
Global SLIDER_CONTROL_PIXEL_HEIGHT=30

Global SLIDER_DRAW_POSITION_X=200
Global SLIDER_DRAW_POSITION_Y=300

; These are for an 'OK' button to apply the gamma change
Global BUTTON_X=300
Global BUTTON_Y=500
Global BUTTON_WIDTH=50
Global BUTTON_HEIGHT=25

; Used for the visual colours
Const COLOUR_SLIDER=4194304
Const COLOUR_SLIDER_MOUSEOVER=33554431

Const COLOUR_BUTTON=4194304
Const COLOUR_BUTTON_MOUSEOVER=33554431
Const COLOUR_BUTTON_TEXT=33554431
Const COLOUR_BUTTON_TEXT_MOUSEOVER=4194304

Global SLIDER_COLOUR=COLOUR_SLIDER
Global BUTTON_COLOUR=COLOUR_BUTTON
Global BUTTON_TEXT_COLOUR=COLOUR_BUTTON_TEXT

While Not KeyDown(1)
	Cls
	UpdateSlider()
	DrawSlider()
	UpdateOKButton()
	DrawOKButton()
	Flip
Wend
End

Function DrawOKButton()
	; Draws the OK Button
	SetColour(BUTTON_COLOUR)
	Rect BUTTON_X,BUTTON_Y,BUTTON_WIDTH,BUTTON_HEIGHT,True
	SetColour(BUTTON_TEXT_COLOUR)
	Text BUTTON_X+(BUTTON_WIDTH * 0.5),BUTTON_Y+(BUTTON_HEIGHT*0.5),"Apply",True,True
End Function

Function DrawSlider()
	SetColour(SLIDER_COLOUR)
	; Draws the slider on screen according to the globals and current state of GAMMA_DELTA
	Rect SLIDER_DRAW_POSITION_X,SLIDER_DRAW_POSITION_Y,SLIDER_PIXEL_WIDTH,SLIDER_PIXEL_HEIGHT,True
	Local PositionX=GetSliderControlPositionX()
	Local PositionY=GetSliderControlPositionY()	
	Rect PositionX,PositionY,SLIDER_CONTROL_PIXEL_WIDTH,SLIDER_CONTROL_PIXEL_HEIGHT,False

	Local Points,Ratio#
	Ratio#=SLIDER_PIXEL_WIDTH/256
	For Points=0 To 256 Step 32
		Text SLIDER_DRAW_POSITION_X+(Ratio*Points),SLIDER_DRAW_POSITION_Y+(SLIDER_PIXEL_HEIGHT*1.5),Str(Points),True,False
	Next
End Function

Function ApplyGammaChange()
	Local Red, Green, Blue
	For Red=0 To 255
	For Green=0 To 255
	For Blue=0 To 255
	SetGamma Red,Green,Blue,GAMMA_DELTA,GAMMA_DELTA,GAMMA_DELTA
	Next
	Next
	Next
	UpdateGamma()
	Cls
	Color 255,255,255
	Text 0,0,"Gamma "+Str(GAMMA_DELTA)+" Applied successfully."
	Flip
	WaitKey()
	End
End Function

Function MouseOverGammaSlider(X,Y)
	; Check to see if mouse is over the slider area
	If ((X>SLIDER_DRAW_POSITION_X) And (X<(SLIDER_DRAW_POSITION_X+SLIDER_PIXEL_WIDTH)))
		If ((Y>(GetSliderControlPositionY())) And (Y<(GetSliderControlPositionY()+SLIDER_CONTROL_PIXEL_HEIGHT)))
			SLIDER_COLOUR=COLOUR_SLIDER_MOUSEOVER
			Return True
		End If
	End If
	SLIDER_COLOUR=COLOUR_SLIDER
	Return False
End Function

Function UpdateSlider()
	Local MX=MouseX()
	Local MY=MouseY()
	;Update the slider on mouseclicks. To ensure the mouse hasn't moved in the meantime, use MX and MY variables
	If (MouseOverGammaSlider(MX,MY) And (MouseDown(1))) 
		Local X=(MX-SLIDER_DRAW_POSITION_X)
		GAMMA_DELTA=X*(SLIDER_PIXEL_WIDTH/256)
	End If
End Function
	
Function UpdateOKButton()
	Local MX=MouseX()
	Local MY=MouseY()
	;Update the slider on mouseclicks. To ensure the mouse hasn't moved in the meantime, use MX and MY variables	If MouseOverOKButton()
	If (MouseOverOKButton(MX,MY) And MouseHit(1))
		ApplyGammaChange()
	EndIf
End Function

Function MouseOverOKButton(X,Y)
	; Check to see if mouse is over the OK Button area
	If (X>BUTTON_X) And (X<(BUTTON_X+BUTTON_WIDTH)) And (Y>BUTTON_Y) And (Y<(BUTTON_Y+BUTTON_HEIGHT))
		BUTTON_COLOUR=COLOUR_BUTTON_MOUSEOVER
		BUTTON_TEXT_COLOUR=COLOUR_BUTTON_TEXT__MOUSEOVER
		Return True
	End If
	BUTTON_COLOUR=COLOUR_BUTTON
	BUTTON_TEXT_COLOUR=COLOUR_BUTTON_TEXT
	Return False
End Function

Function GetSliderControlPositionX()
	; Returns the calculated position of the slider for drawing and mouseover events
	Local Ratio#=(SLIDER_PIXEL_WIDTH/256)*GAMMA_DELTA
	Return SLIDER_DRAW_POSITION_X+(Ratio-(SLIDER_CONTROL_PIXEL_WIDTH*0.5))
End Function

Function GetSliderControlPositionY()
	Return SLIDER_DRAW_POSITION_Y-((SLIDER_CONTROL_PIXEL_HEIGHT-SLIDER_PIXEL_HEIGHT)*0.5)
End Function

Function SetColour(Colour)
	;Effects colour changes
	Color (Colour Shr 16) And 255,(Colour Shr 8) And 255,Colour And 255
End Function

Last edited 2010

Yue	(Posted 2010) [#4]

Thax :) Malice