Help Please with Menu Shadow

Blitz3D Forums/Blitz3D Programming/Help Please with Menu Shadow

Yue	(Posted 2010) [#1]

;-----------------------------------
; Efectos de Sombras
;-----------------------------------
Include "Includes3\ShadowsSimple.bb"
CreateShadow Tipo_Sombra
Global Textura_Sombra = ShadowTexture()

;---------------------------
; Includes Generales
;---------------------------
Include "Includes\Funciones.bb"
Include "Includes\Recursos2.bb"

;---------------------------
; Entidades Menu Principal
;---------------------------
Local Camara_Menu = CreateCamera()
PositionEntity Camara_Menu,0,1,-3

Local Terreno_Menu = CreatePlane()

Local Sol = CreateLight()
RotateEntity Sol,90,0,0

;---------------------------
; Entidades Temporales
;---------------------------
Local Cubo = CreateCube()
EntityColor Cubo,255,0,0
ScaleEntity Cubo,.5,.5,.5
PositionEntity Cubo,0,1,0
CreateShadowCaster Cubo

Local Fuente_Luz = CreatePivot()
RotateEntity Fuente_Luz,90,0,0
ShadowLight Fuente_Luz,3,120
PositionEntity Fuente_Luz, 0,3,0

AttachShadowReceiver Plano,0,1
EntityTexture Terreno_Menu,Textura_Sombra,0,0

;----------------------------
; Bucle Principal Menu
;----------------------------
Repeat 
	
	TurnEntity Cubo,0,.1,0
	
	UpdateShadows(Camara_Menu,1.0)
	RenderWorld 
	Opciones_Video()
	
	
	Text_ (0,0,FPS(100) + " Tipo_Sombra : " +" " + Tipo_Sombra ,0,0,0)
	
	
	Flip 
	If KeyDown(200) End 
		
Forever

Hi, I need help please, the case is that I have a menu of options in 3D, where you change game options in this case the real-time shadows which perceives the change is due immediately.

I have four choices for shade, and I'm using Fastext, the case is a function that specifies the quality of the shadow CreateShadow (Quality Shadow) and I'm going crazy trying to show the change in real time, I regret not being able to explain better and I use a translator because my English is very bad.

The fact is that the function is outside the Repeat CreateShadow and not to update the value of the variable for this to work properly.

I appreciate the help you can give me possible.

Help!!! Plese i am now :(

Last edited 2010

_PJ_	(Posted 2010) [#2]

It seems to me that you will need to make use of a Global variable to hold the "Quality Shadow" and this is what needs to be changed with the menu options.

In the code provided, you have the line

UpdateShadows(Camara_Menu,1.0)

Within this function, I suspect that you may need to ensure the Shadow system knows to use the variable for Quality Shadow.

OR if this can't work, then you would need to remove the existing shadow and repeat the CreateShadow() with the updated variable.

I hope this helps, I would provide an example, but I don't use FastExt or have those functions.
Maybe you could post those?

Yue	(Posted 2010) [#3]

Hi, I appreciate your help, the code of the function that updates the shadows is this.

Function UpdateShadows% (camera%, tween#=1.0)
	Local j%, c.ShadowCaster, fog%, blend%, t#, r.ShadowReceiver, oldBuffer%, attachedCount%
	Local Shadow.Shadow = ShadowDefault
	Local renderFlag% = 0

	If ShadowInitFlag<>0 And Shadow\enabled<>0 And Shadow\castersCount>0 Then
		;
		; shadow-camera A.I.
		;
		If Shadow\lightType=0
			PositionEntity ShadowCameraDefault, EntityX(camera,1), EntityY(camera,1), EntityZ(camera,1), 1
			RotateEntity ShadowCameraDefault, EntityPitch(Shadow\light,1), EntityYaw(Shadow\light,1), EntityRoll(Shadow\light,1), 1
			MoveEntity ShadowCameraDefault, 0, 0,  -Shadow\range / Tan ( Shadow\cameraFov / 2.0 )
			t =  Tan ( Shadow\cameraFov / 2.0 )
		Else
			PositionEntity ShadowCameraDefault, EntityX(Shadow\light,1), EntityY(Shadow\light,1), EntityZ(Shadow\light,1), 1
			RotateEntity ShadowCameraDefault, EntityPitch(Shadow\light,1), EntityYaw(Shadow\light,1), EntityRoll(Shadow\light,1), 1
			t =  Tan ( Shadow\lightFov / 2.0 )
		EndIf
		CameraRange ShadowCameraDefault, 0.1 / t, 1000.0 / t
		CameraZoom ShadowCameraDefault, 1.0 / t
					
		fog = FogMode(1)
		TextureBlend Shadow\texture, Shadow\texBlend And $FFFF
		
		If Shadow\mode<>0 Then
			oldBuffer = SetBuffer (TextureBuffer(Shadow\texture))
		Else
			oldBuffer = SetBuffer (BackBuffer())
		EndIf
		
		ShadowsOverwriteFX0 = GetOverwriteFX(0) : ShadowsOverwriteFX1 = GetOverwriteFX(1)	; save fx
		OverwriteFX 0, $FFFFFFF7
		ClsColor 255, 255, 255 : Cls 1, 1

		If Shadow\receiversCount>0 Then
			;
			; render receivers (fill zbuffer)
			;
			attachedCount = 0
			For r = Each ShadowReceiver
				r\attached = 0
				If r\enabled<>0 Then
					If EntityInView( r\entity, ShadowCameraDefault )<>0 Or r\showAlways<>0 Then
						If r\showAuto<>0 Then ShowEntity r\entity
						r\autofade = EntityAutoFadeMode (r\entity, -1)
						EntityAutoFadeMode r\entity, 0
						r\attached = 1
						attachedCount = attachedCount + 1
					EndIf
				EndIf
			Next

			If attachedCount>0 Then
				CameraFogColor ShadowCameraDefault, 255, 255, 255
				RenderGroup Shadow\receiversGroupID, ShadowCameraDefault, 0, tween
				For r = Each ShadowReceiver
					If r\attached<>0 Then
						If r\showAuto<>0 Then HideEntity r\entity
						EntityAutoFadeMode r\entity, r\autofade
					EndIf
					r\attached = 0
				Next
			EndIf
		EndIf

		;
		; render casters
		;
		attachedCount = 0
		For c = Each ShadowCaster
			c\attached = 0
			If c\enabled<>0 Then
				If EntityInView( c\entity, ShadowCameraDefault )<>0 Or c\showAlways<>0  Then
					If c\showAuto<>0 Then ShowEntity c\entity
					c\autofade = EntityAutoFadeMode (c\entity, -1)
					EntityAutoFadeMode c\entity, 0
					c\attached = 1
					attachedCount = attachedCount + 1
				EndIf
			EndIf
		Next

		If attachedCount>0 Then
			CameraFogColor ShadowCameraDefault, Shadow\powerR * Shadow\power, Shadow\powerG * Shadow\power, Shadow\powerB * Shadow\power
			RenderGroup Shadow\castersGroupID, ShadowCameraDefault, 0, tween
			For c = Each ShadowCaster
				If c\attached<>0 Then
					If c\showAuto<>0 Then HideEntity c\entity
					EntityAutoFadeMode c\entity, c\autofade
				EndIf
				c\attached = 0
			Next
			
			SetViewMatrixCurrent 0
			CopyProjMatrix ShadowMatrix
				ShadowMatrix\m41 = ShadowMatrix\m41 + Shadow\offsetX
				ShadowMatrix\m42 = ShadowMatrix\m42 + Shadow\offsetY
				ShadowMatrix\m43 = ShadowMatrix\m43 + Shadow\offsetZ
			SetProjMatrix 0, ShadowMatrix
			
			If Shadow\blurAlpha>0 Then
				CustomPostprocessBlur Shadow\blurAlpha, Shadow\blurPasses, Shadow\blurRadius, Shadow\blurQuality
				RenderPostprocess FE_Blur			
			EndIf

			Color 255, 255, 255
			Rect 0, 0, Shadow\texSize, Shadow\texSize, 0
			If Shadow\fadeTexture<>0
				CustomPostprocessOverlay 1, 0, 255, 255, 255, Shadow\fadeTexture
				RenderPostprocess FE_Overlay
			EndIf
		EndIf

		OverwriteFX ShadowsOverwriteFX0, ShadowsOverwriteFX1						; restore fog mode
		FogMode fog

		; rect for debug
		;	Color 0,0,0
		;	Rect Shadow\texSize/4,Shadow\texSize/4,Shadow\texSize/2,Shadow\texSize/2,0
		;	Rect 1,1,Shadow\texSize-2,Shadow\texSize-2,0
	
		If Shadow\mode=0 Then  CopyRect 0, 0,  Shadow\texSize, Shadow\texSize,  0, 0,  BackBuffer(), TextureBuffer(Shadow\texture)
		SetBuffer oldBuffer
		TextureBlend Shadow\texture, Shadow\texBlend
	Else
		If Shadow\texture<>0 Then
			oldBuffer = SetBuffer (TextureBuffer(Shadow\texture))
			Color 255, 255, 255
			Rect 0, 0, Shadow\texSize, Shadow\texSize, 1
			SetBuffer oldBuffer
		EndIf
	EndIf
End Function

And the function that creates the shadow and the quality is this:

Function CreateShadow (quality%=1, mode%=1)
	Local t#, w%, Shadow.Shadow, i%
	If ShadowInitFlag = 0 Then
		ShadowInitFlag = 1
	
		If ShadowLightDefault=0 Then
			ShadowLightDefault = CreatePivot()
			RotateEntity ShadowLightDefault, 90, 0, 0
		EndIf
		
		Shadow = ShadowDefault
		Shadow\castersGroupID = ShadowGroupID
		Shadow\receiversGroupID = ShadowGroupID + 1
		Shadow\castersCount = 0
		Shadow\receiversCount = 0
		Shadow\enabled = 1
		Shadow\light = 0
		Shadow\lightFov = 90
		Shadow\offsetX = 0
		Shadow\offsetY = 0
		Shadow\offsetZ = 0
		Shadow\fadeTexture = 0
		Shadow\cameraFov = 5
		ShadowColor 255, 255, 255
		ShadowPower 0.5
		ShadowRange 50
		Shadow\mode = mode
		Shadow\blurAlpha = 0
		Shadow\blurPasses = 4
		Shadow\blurRadius = 0.1
		Shadow\blurQuality = 0
		
		Select quality
			Case 0
				Shadow\texSize = 512
				Shadow\quality = 0
			Case 1
				Shadow\texSize = 1024
				Shadow\quality = 1
			Case 2
				Shadow\texSize = 2048
				Shadow\quality = 2
			Default
				Shadow\texSize = 512
				Shadow\quality = 0
		End Select
		
		If Shadow\mode=0 Then
			w = GraphicsHeight()
			If GraphicsHeight()>GraphicsWidth() Then w = GraphicsWidth()
			While Shadow\texSize>w : Shadow\texSize = Shadow\texSize Shr 1 : Wend
			Shadow\texture = CreateTexture(Shadow\texSize, Shadow\texSize, 1+16+32+256 )	
		Else
			If Shadow\texSize>GfxDriverCapsEx\TextureMaxWidth Then Shadow\texSize = GfxDriverCapsEx\TextureMaxWidth
			If Shadow\texSize>GfxDriverCapsEx\TextureMaxHeight Then Shadow\texSize = GfxDriverCapsEx\TextureMaxHeight
			Shadow\texture = CreateTexture(Shadow\texSize, Shadow\texSize, 1+16+32+256+FE_RENDER+FE_ZRENDER )
		EndIf

		If ShadowCameraDefault=0 Then
			ShadowCameraDefault = CreateCamera() 
			t =  Tan ( Shadow\cameraFov / 2.0 )
			CameraRange ShadowCameraDefault, 0.1 / t, 1000.0 / t
			CameraZoom ShadowCameraDefault, 1.0 / t
			CameraFogMode ShadowCameraDefault, 1
			CameraFogRange ShadowCameraDefault, 0, 0.01
			CameraFogColor ShadowCameraDefault, Shadow\powerColor, Shadow\powerColor, Shadow\powerColor
			CameraClsColor ShadowCameraDefault, 255, 255, 255
			CameraClsMode ShadowCameraDefault, 0, 0
			CameraViewport ShadowCameraDefault, 0, 0, Shadow\texSize, Shadow\texSize
			CameraProjMode ShadowCameraDefault, 0
		EndIf
	
		SetBuffer TextureBuffer(Shadow\texture)
			Color 255, 255, 255
			Rect 0, 0, Shadow\texSize, Shadow\texSize,1
		SetBuffer BackBuffer()
		ScaleTexture Shadow\texture, 1.0, 1.0
		Shadow\texBlend = FETOP_PROJECT3D1 Or (D3DTOP_MODULATE Shl 8) Or D3DTOP_MODULATE
		TextureBlend Shadow\texture, Shadow\texBlend
		
		TextureIndex Shadow\texture, 0
		ShadowLight ShadowLightDefault
	EndIf	
End Function

I mention that I tried to use Goto and Gosub to update the value of variable quality, but I have not always worked continuously with the first variable is zero for the quality of the shadow of lower quality (512 * 512)

A greeting and thanks again for helping me.

Yue	(Posted 2010) [#4]

Tutorial Englis :(


* PROJECTIVE SHADOWS:

Shade in library are presented two included files ShadowsSimple.bb and ShadowsMultiple.bb

ShadowsSimple.bb - this is a most simple system of the shadows, having one shadow map (texture),
which possible place on receivers - any meshes, on which will fall shadows. This system more compact
and more simple for understanding, than second, but allows to do only simple shadowing.
Examples of use: all ShadowsSimple_*.bb files.

ShadowsMultiple.bb - it's more advanced system, in which possible create any amount of the shadow systems.
Each shadow system has its shadow map and set of the casters - any meshes. Maximum amount of the casters
to one shadow system is defined by constant ShadowCastersMax = 2048, if this little, that can assign
greater number, having changed value of the constant in source file ShadowsMultiple.bb Any caster
can belong to one of the shadow systems or immediately several, that enables to create the more
interesting effects and create pseudo self-shadowing.
Examples of use: all ShadowsMultiple_*.bb files.
	other examples from ShadowSimple framework you can easily adapt for ShadowMultiple framework.

The functional set in both systems alike, but for ShadowsMultiple.bb nearly in all function is used
additional parameter - a pointer to shadow system, see more details in functions description.


Features:

	- This shadows possible use in real projects (games), created on Blitz3D due to their speed.
	  All other variants of the shadows can not give acceptable FPS in real projects, IMHO.

	- Maximum speed of the work, it is used additional rendering only for casters.
	  Projection of the shadow map occurs through DirectX7, without any additional calculation
	  for each vertex in the meshes.

	- The caster and receiver can be absolutely any mesh (software created mesh, animated mesh, terrain, etc.)

	- System correct displays shadows from casters, containing transparent or masked textures
	  (glass, grass, branches of the tree, fence from iron net and etc.)

	- There is possibility of the increase perfomance of the system. You can use low-poly copy of the original
	  meshes as casters.


Restrictions:

	- Impossible to create real self-shadowing.

	- Projection of the shadow spreads on whole receiver (front and back faces),
	  see pictures from path .\images\shadow0.gif and .\images\shadow1.gif

	- Wrong to place part of the caster (or whole caster) inside receiver. Such situation it is necessary to avoid,
	  see pictures from path .\images\shadow2.gif and see example ShadowsSimple_ReceiversUse.bb - it will help you
	  to solve a problem (not completely, only partially)

	- Shadow system support directional an spot lights only. If you want to have less problems with indoor scenes, 
	  see pictures from path .\images\shadow3.gif


Recommendations:

	- Use classical lightmaps for all static objects
	- Use dynamic shadows for dynamic objects only
	- System of the shadows - not instrument for decision of all problems, use it neatly!


Functions:	


CreateShadow (quality%=1, mode%=1)
	This function create shadow system (single for ShadowsSimple.bb or new copy for ShadowsMultiple.bb).
	Parameter quality% can have possible values:
		0 - size of the shadow map (texture) will be 512x512 pixels (1 MB in video memory)
		1 - size 1024x1024 pixels (4 MB) 
		2 - size 2048x2048 pixels (16 MB)
		Size is automatically limited under maximum size of the texture, supported in video card.

	Parameter mode% can have possible values:
		0 - shadow system use render-to-texture method (to shadow map).
		1 - use render to BackBuffer and CopyRect to shadow map. Maximum stability on very old videocards,
		    but it more slow and size of the shadow map limited by current graphics resolution.
		    (as example - if graphic resolution 1024x768, then size of the shadow map will be 512x512)
		
	Function return:
		- nothing for ShadowsSimple.bb or
		- shadow system object with 'Shadow' type for ShadowsMultiple.bb for the subsequent use


UpdateShadows% (camera%, tween#=1.0)
	Main function, update all shadow system and render casters to shadow map.
	Use this function before RenderWorld (and after UpdateWorld).
	Parameter:

		camera% - main camera in your scene (from which the spectator sees). It is possible
			to set any other entity if it is required, but it is necessary to remember
			that the shadow map will be will extend concerning this entity.
		tween# - use for tweening, analogue tween param from RenderWorld

	It is possible to cause function less often, than each frame, if objects move slightly or not move.


ShadowLight% (light_entity%=-1)   - for ShadowsSimple.bb
ShadowLight% (ShadowIn.Shadow, light_entity%=-1)   - for ShadowsMultiple.bb
	Function sets a light source through parametre light_entity % from which shadows will be projected.
	Any entity can be a light source. The object direction in space is used only, the system supports
	only the directional light sources.
	If the parametre light_entity% is not set or equal -1 function will return flowing source light,
	currently used in system.


ShadowOffset (x#=0, y#=0, z#=0)   - for ShadowsSimple.bb
ShadowOffset (ShadowIn.Shadow, x#=0, y#=0, z#=0)   - for ShadowsMultiple.bb
	Function set offset for shadows
	Function sets shadow offset (displacement) in space if the shade lays down roughly on a receiver.
	This function can be demanded in certain cases, all depends on the form and a mesh (receiver) grid.


ShadowFade% (fadeTexture%=-1)   - for ShadowsSimple.bb
ShadowFade% (ShadowIn.Shadow, fadeTexture%=-1)    - for ShadowsMultiple.bb
	By means of this function it is possible to set a texture of smooth display of shadows (fade out)
	on border of a shadow range. Set your texture through parametre fadeTexture%.
	If the parametre is not set or equal -1, that function will return a current texture or a zero
	if the texturee has not been set earlier. By default such texturee is not set also shades vanish
	and appear sharply on border.
	See examples: ShadowsSimple_FadeOut.bb, ShadowsMultiple_FadeOut.bb 


ShadowColor# (r#=255, g#=255, b#=255)   - for ShadowsSimple.bb
ShadowColor# (ShadowIn.Shadow, r#=255, g#=255, b#=255)    - for ShadowsMultiple.bb
	Function sets color tone for a shadow. I recommend to set "cold" tone of a shadow
	if illumination on a scene in "warm" tones, it is more realistic looks, as in the nature the same law operates.
	By default colour tone of a shadow neutral (255,255,255).


ShadowPower# (power#=-1)   - for ShadowsSimple.bb
ShadowPower# (ShadowIn.Shadow, power#=-1)    - for ShadowsMultiple.bb
	Function sets opacity (power) of a shadow by means of parametre power#.
	If the parametre power# is not set or equal -1 function will return current value of power of a shade.
	By default the transparency is equal 50 % (power#=0.5)


ShadowRange# (range#=-1)   - for ShadowsSimple.bb
ShadowRange# (ShadowIn.Shadow, range#=-1)    - for ShadowsMultiple.bb
	Function sets a range of action of a shadow in space by means of parametre range#.
	Behind borders of this range of a shadow from casters will not be displayed.
	It is necessary to consider - the more a range, the the big area of a scene will be covered with a shadow,
	but there will be more low a quality of a shadows (more pixelate).
	If the parametre range# is not set or equal -1 function will return a current range of the shadow system.
	By default range# is equal 50.


ShadowTexture% ()   - for ShadowsSimple.bb
ShadowTexture% (ShadowIn.Shadow)    - for ShadowsMultiple.bb
	Function returns a shadow map (texture) which it is necessary to place on all receivers
	(on uppermost not used layer of mesh).


ShowShadow% ()    - for ShadowsSimple.bb
ShowShadow% (ShadowIn.Shadow)    - for ShadowsMultiple.bb
	Function enable show and an update of shadow system (if it has been hidden earlier).


HideShadow% ()    - for ShadowsSimple.bb
HideShadow% (ShadowIn.Shadow)    - for ShadowsMultiple.bb
	Function hides display and an update of shadow system (if it has been showed earlier).


DebugShadow% (x%=0, y%=0, width%=256, height%=256)   - for ShadowsSimple.bb
DebugShadow% (ShadowIn.Shadow, x%=0, y%=0, width%=256, height%=256)    - for ShadowsMultiple.bb
	Function is used for debugging and allows to see on the screen a shadow map (texture).
	You can set position and size with params.


ShadowBlur% (alpha#=1.0, blurPass%=4, blurRadius#=0.1, quality%=0)
ShadowBlur% (ShadowIn.Shadow, alpha#=1.0, passes%=4, radius#=0.1, quality%=0)
	This function can enable or disable blur FX for shadow map.
	alpha# - alpha value for blur FX ( alpha>0 - enable blur FX, alpha=0 - disable blur FX)
	blurPass% - quantity of blur passes
	blurRadius$ - blur radius
	quality% - quality for blur FX
		0 and 1 - fast method (0 - low quality, 1 - high quality), with small artifacts on some videocards
		2 and 3 - normal method without artifacts (2 - normal quality, 3 - very high quality)
	Example of use: ShadowsSimple_PostBlur.bb


ShadowUpdate% (ShadowIn.Shadow, enable%=-1)
	Only for ShadowsMultiple.bb. Function allows enable/disable an update (shadowmap) for single shadow in multiple-shadow system.
		enable% = -1 - return current update-flag for shadow (default value = 1)
		enable% = 0 - disable update for shadow
		enable% = 1 - enable update for shadow
	Example of use: ShadowsMultiple_Demo.bb


FreeShadows% ()
	If the shadow system is not necessary any more it is possible to remove it by means this function,
	it should be used before such functions as ClearWorld and DeInitExt.
	Attention! If your program deletes shadow system, but continues to work, it is necessary to remember - 
	what is the textures will not be removed (and will occupy video memory) until you do not remove them
	from all receivers or remove receivers (meshes).



* FUNCTIONS FOR SHADOW CASTERS:

CreateShadowCaster% (caster_entity%, showAuto%=0, showAlways%=0)   - for ShadowsSimple.bb
CreateShadowCaster% (ShadowIn.Shadow, caster_entity%, showAuto%=0, showAlways%=0)    - for ShadowsMultiple.bb
	Create shadow caster from entity (caster_entity%).
	showAuto% - if you use LOD entity as caster (hidden in 3d world). Automatically show entity before updating shadow map, and hide after.
	showAlways% - use for entities not having culling box (planes, sprites and etc.) This caster will be always drawn,
	even if it is outside of a shadow map.
	Some AnimMeshes can cause problem (from them will not fall shadow). In such events we recommend
	to create Pivot and set it as parent for AnimMesh, afterwards - set Pivot as shadow caster.
	Function returns nothing.


HideShadowCaster% (caster_entity%)   - for ShadowsSimple.bb
HideShadowCaster% (ShadowIn.Shadow, caster_entity%)    - for ShadowsMultiple.bb
	Disable shadow casting from the caster (caster_entity%).
	The caster does not deleted from system. It is faster that delete from shadow system and create it after.


ShowShadowCaster% (caster_entity%)   - for ShadowsSimple.bb
ShowShadowCaster% (ShadowIn.Shadow, caster_entity%)    - for ShadowsMultiple.bb
	Enable shadow casting from the caster (caster_entity%).


FreeShadowCaster% (caster_entity%)   - for ShadowsSimple.bb
FreeShadowCaster% (ShadowIn.Shadow, caster_entity%)    - for ShadowsMultiple.bb
	Delete shadow caster (caster_entity%) from shadow system.


FindShadowCaster% (caster_entity%)   - for ShadowsSimple.bb
FindShadowCaster% (ShadowIn.Shadow, caster_entity%)    - for ShadowsMultiple.bb
	By means of function it is possible to learn, whether there is a given entity (caster_entity%) at shadow system.
	If function return -1, the entity is absent in system (is not connected).



* FUNCTIONS FOR SHADOW RECEIVERS:

AttachShadowReceiver% (receiver_entity%, showAuto%=0, showAlways%=0)   - for ShadowsSimple.bb
AttachShadowReceiver% (ShadowIn.Shadow, receiver_entity%, showAuto%=0, showAlways%=0)   - for ShadowsMultiple.bb
	Attach receiver_entity% to shadow system.
	If caster is located inwardly receivers or is intersected with receivers
	then use this function for dispose of false shadows.
	showAuto% - if you use LOD entity as receiver (hidden in 3d world). Automatically show entity before updating shadow map, and hide after.
	showAlways% - use for entities not having culling box (planes, sprites and etc.) This receiver will be always drawn,
	even if it is outside of a shadow map.
	Function returns nothing.
	Example of use: ShadowsSimple_ReceiversUse.bb 


ShowShadowReceiver% (receiver_entity%)   - for ShadowsSimple.bb
ShowShadowReceiver% (ShadowIn.Shadow, receiver_entity%)   - for ShadowsMultiple.bb
	Enable receiver_entity% in shadow system.
	

HideShadowReceiver% (receiver_entity%)   - for ShadowsSimple.bb
HideShadowReceiver% (ShadowIn.Shadow, receiver_entity%)   - for ShadowsMultiple.bb
	Disbale receiver_entity% in shadow system.
	The receiver does not deleted from system. It is faster that delete from shadow system and create it after.


FreeShadowReceiver% (receiver_entity%)   - for ShadowsSimple.bb
FreeShadowReceiver% (ShadowIn.Shadow, receiver_entity%)   - for ShadowsMultiple.bb
	Delete receiver_entity% from shadow system.


FindShadowReceiver% (receiver_entity%)   - for ShadowsSimple.bb
FindShadowReceiver% (ShadowIn.Shadow, receiver_entity%)   - for ShadowsMultiple.bb
	By means of function it is possible to learn, whether there is a given entity (receiver_entity%) at shadow system.
	If function return -1, the entity is absent in system (is not connected).

Yue	(Posted 2010) [#5]


;---------------------------
; Includes Generales
;---------------------------
Include "Includes\Funciones.bb"
Include "Includes\Recursos2.bb"

;-----------------------------------
; Efectos de Sombras
;-----------------------------------
Include "Includes3\ShadowsSimple.bb"

.SAlto

CreateShadow Tipo_Sombra+Tipo_Sombra
	
	If Seleccion  = True  
		Seleccion  = False 
		Goto Salto2	

	End If 


;---------------------------
; Entidades Menu Principal
;---------------------------
Local Camara_Menu = CreateCamera()
PositionEntity Camara_Menu,0,1,-3

Local Terreno_Menu = CreatePlane()

Local Sol = CreateLight()
RotateEntity Sol,90,0,0





;---------------------------
; Entidades Temporales
;---------------------------
Local Cubo = CreateCube()
EntityColor Cubo,255,0,0
ScaleEntity Cubo,.5,.5,.5
PositionEntity Cubo,0,1,0


Local Fuente_Luz = CreatePivot()
RotateEntity Fuente_Luz,90,0,0

PositionEntity Fuente_Luz, 0,3,0


;-------------------------
; Aplicando Efecto Sombra
;-------------------------










.Salto2
;----------------------------
; Bucle Principal Menu
;----------------------------
Repeat 
	
	TurnEntity Cubo,1,0,0
	
	
	If Tipo_Sombra = 0
		CreateShadow Tipo_Sombra
		Textura_Sombra = ShadowTexture()
		CreateShadowCaster Cubo
		ShadowLight Fuente_Luz,3,120
		AttachShadowReceiver Plano,0,1
		EntityTexture Terreno_Menu,Textura_Sombra,0,0
		UpdateShadows(Camara_Menu,1.0) 
	End If 
	
	If Tipo_Sombra = 1
		CreateShadow Tipo_Sombra
		Textura_Sombra = ShadowTexture()
		
		CreateShadowCaster Cubo
		ShadowLight Fuente_Luz,3,120
		AttachShadowReceiver Plano,0,1
		EntityTexture Terreno_Menu,Textura_Sombra,0,0
		UpdateShadows(Camara_Menu,1.0)
		
	End If 
	
	
	If Tipo_Sombra = 2
		CreateShadow Tipo_Sombra
		Textura_Sombra = ShadowTexture()
		CreateShadowCaster Cubo
		ShadowLight Fuente_Luz,3,120
		AttachShadowReceiver Plano,0,1
		EntityTexture Terreno_Menu,Textura_Sombra,0,0
		UpdateShadows(Camara_Menu,1.0) 
	End If 
	
	
	RenderWorld 
	
	Opciones_Video()
	Text_ (0,0,FPS(100) + " Tipo_Sombra : " +" " + Tipo_Sombra ,0,0,0)
	
	Flip 
	
	If KeyDown(200) 
		Tipo_Sombra = 2
		Seleccion = True 
		Goto SAlto
	End If 
	
Forever
;  :S

I can not change the variable rate real-time shadows, at least I do but this does not affect the shadow changes, then I wonder if this can be done?, The support of the library or speak good English, nor I speak English, the language is Russian and Spanish I, therefore I am that my head off.

Last edited 2010

puki	(Posted 2010) [#6]

When you want to change the shadow resolution, you will need to rebuild the shadow texture with CreateShadow - I don't see you doing that in the above code.

So, I think you will need to first free the current shadows (as they are the wrong resolution); failing to do so will leave the old shadows on the texture:

FreeShadows

Rebuild the the shadows to the required resolution:

CreateShadow X (X = new resolution)

Apply the new shadows to the old ShadowTexture:

ShadowTexture = ShadowTexture()

This, as far as I know, would be the basic steps to take to rebuild the shadows to a different resolution/quality.

puki	(Posted 2010) [#7]

Look for the demo called 'ShadowsSimple_TweenOther.bb'

Add into the main loop:

	If KeyHit(2)
		FreeShadows
		CreateShadow 3
		ShadowTexture = ShadowTexture()
		CreateGame()
	EndIf

Then press the '1' key to see the resolution change in real-time.

This is just a quick way of doing it (to demonstrate) - you will probably need to delete entities and recreate them prior to doing it this way.

Yue	(Posted 2010) [#8]

Puki Hi, I greatly appreciate the help you gave me, and it is complicated I use a translator when the word in English Brush, I translated into Spanish in the brush, and brush my tongue is something to fix her hair or cleaned teeth ... In order to comment you have given me a light on this, but I have a problem is that calling the new shadow re-creates the world, and therefore the use ClearWorld tells me that since the respective texture for the shadow is not exists. But I hope to fix it and just drink coffee ;)

A greeting.

Yue	(Posted 2010) [#9]

This is impossible, unfortunately I have tried what is in my power, the idea was to create a real-time menu where you notice the change of the shadows, so we will retake this course, or do not deliver what sufientes in Blitz or just the author the libs can not take 5 minutes to do a simple example.

Yue	(Posted 2010) [#10]

I've done gentlemen
:) One of my greatest limitations is the language and the only way to learn is trial and error.

A greeting.

=)

;---------------------------
; Includes Generales
;---------------------------
Include "Includes\Funciones.bb"
Include "Includes\Recursos2.bb"

;-----------------------------------
; Efectos de Sombras
;-----------------------------------
Include "Includes3\ShadowsSimple.bb"
.Inicio
CreateShadow 0
Global Textura_Sombra = ShadowTexture()




Local Camara_Menu = CreateCamera()
PositionEntity (Camara_Menu,0,1,-4)

Local Sol =  CreateLight()
RotateEntity (Sol,90,0,0)



Local Fuente_Luz = CreatePivot()
RotateEntity Fuente_Luz,90,0,0
PositionEntity Fuente_Luz,0,8,0
ShadowLight( Fuente_Luz,3,120)

Local Cubo = CreateCube()
ScaleEntity (Cubo,.5,.5,.5)
EntityColor (Cubo,255,0,0)
CreateShadowCaster Cubo,0,1

Local Terreno_Menu = CreatePlane()
PositionEntity (Terreno_Menu,0,-1,0)
AttachShadowReceiver (Terreno_Menu,0,1)
EntityTexture (Terreno_Menu,Textura_Sombra,0,0)




Repeat 
	
	TurnEntity Cubo,0,1,0
	UpdateShadows(Camara_Menu,1.0)
	RenderWorld 
	Text 0,0, FPS(100)
	Flip
	
	
	
	
	
	
	If KeyHit(200) 
		HideEntity Cubo
		HideEntity Terreno_Menu
		FreeEntity Fuente_Luz
		FreeEntity Cubo
		FreeEntity Sol
		FreeEntity Terreno_Menu
		FreeEntity Camara_Menu
		FreeShadowCaster (Cubo)
		HideShadowReceiver(Terreno_Menu)
		FreeShadowReceiver(Terreno_Menu)
		
		Goto SinSombras 
		
		
	End If 
Forever 


.SinSombras 


FreeShadows()









CreateShadow 2
Global Textura_Sombra2 = ShadowTexture()


Camara_Menu2 = CreateCamera()
PositionEntity (Camara_Menu2,0,1,-4)

Sol2 =  CreateLight()
RotateEntity (Sol2,90,0,0)



Fuente_Luz2 = CreatePivot()
RotateEntity Fuente_Luz2,90,0,0
PositionEntity Fuente_Luz2,0,8,0
ShadowLight( Fuente_Luz2,3,120)

Cubo2 = CreateCube()
ScaleEntity (Cubo2,.5,.5,.5)
EntityColor (Cubo2,255,0,0)
CreateShadowCaster Cubo2,0,1

Terreno_Menu2 = CreatePlane()
PositionEntity (Terreno_Menu2,0,-1,0)
AttachShadowReceiver (Terreno_Menu2,0,1)
EntityTexture (Terreno_Menu2,Textura_Sombra2,0,2)



Repeat 
	
	TurnEntity Cubo2,0,1,0
	UpdateShadows(Camara_Menu,1.0)
	RenderWorld 
	Text 0,0, FPS(100)
	Flip
	If KeyDown(1) End 
	If KeyHit(200) 
		HideEntity Cubo2
		HideEntity Terreno_Menu2
		FreeEntity Fuente_Luz3
		FreeEntity Cubo2
		FreeEntity Sol2
		FreeEntity Terreno_Menu2
		FreeEntity Camara_Menu2
		FreeShadowCaster (Cubo2)
		HideShadowReceiver(Terreno_Menu2)
		FreeShadowReceiver(Terreno_Menu2)
		
		Goto Salto
		
		
	End If 
Forever 
.Salto
FreeShadows()

Goto Inicio