fps & different CPUs

Blitz3D Forums/Blitz3D Programming/fps & different CPUs

jtassinari

(Posted 2010) [#1]

Hi everyone,

as i have tried a little exe on differnt cpus i have seen it's running at different FPS.

So i thought that if i could set a specific FTP, according to the HW chances, i could see my little app running quite fine...

but still, how can i do it?

any suggestion would be really welcome...

thanks

jTassinari
-[ www.absolute-line.net ]-

Kryzon

(Posted 2010) [#2]

The native Timer commands are supposed to provide a simple way to make your application run on different systems with the same speed.

There are other manual ways, of course, like Tweening or Delta Timing. It all comes down to what result each method has, and if that result is what you seek.

Further reading: http://www.blitzbasic.com/Community/posts.php?topic=85383

Charrua

(Posted 2010) [#3]

hi

when i tried to understand frame tweening i made an adition to the sample code, just a bargraph showing how Frames per second and game uptades per second vary depending on the complexity of the 3d world or quantities of objects to render etc.

; ID: 9
; Author: BlitzSupport
; Date: 2001-09-17 23:31:53
; Title: Commented 3D game framework
; Description: The basic framework of a frame-limited/frame-tweening Blitz 3D game

; ------------------------------------------------------------------
; 	GameCore -- support@...
; ------------------------------------------------------------------
; The basics of a frame-limited Blitz 3D game, ready to rock
; ------------------------------------------------------------------
;             Adapted from Mark Sibly's code
; ------------------------------------------------------------------



; ------------------------------------------------------------------
;	Game's frames-per-second setting
; ------------------------------------------------------------------

Global gameFPS = 50

; ------------------------------------------------------------------
;	Open 3D display mode
; ------------------------------------------------------------------

Graphics3D 1024, 768

; ------------------------------------------------------------------
; Single camera setup
; ------------------------------------------------------------------

Global cam = CreateCamera ()
CameraViewport cam, 0, 0, GraphicsWidth (), GraphicsHeight ()
light = CreateLight()


; ------------------------------------------------------------------
; General setup
; ------------------------------------------------------------------

; Load and arrange objects, textures, etc here...

														;<<<< added <<<<<<<<<<<<
	Global nBoxes = 3000
	Dim boxes(nBoxes)
	For i = 1 To nBoxes
		box = CreateCube ()
		boxes(i)=box
		EntityColor box,Rnd(50,255),Rnd(50,255),Rnd(50,250)
		EntityAlpha box,Rand(0.4,1)
		RotateEntity box,Rand(-90,90),Rand(-90,90),Rand(-90,90)
		MoveEntity box, Rnd(-50,50), Rnd(-50,50), 50+Rnd(1,50)
	Next
														;<<<< added <<<<<<<<<<<<


; ------------------------------------------------------------------
;	Frame limiting code setup
; ------------------------------------------------------------------

framePeriod = 1000 / gameFPS
frameTime = MilliSecs () - framePeriod	;simulamos que el tiempo del cuadro anterior fue del
										;período que quermos

														;<<<< added <<<<<<<<<<<<

;used to calculate the time spent in UpdateGame and RenderWorld and to
;calculate the ammount of renders per second and Game updates per second
Global fps_=0, fps=0	;number of RenderWorld's per second
Global ups_=0, ups=0	;number of update games per second
Global tug_=0, tug=0	;accumulated time of update games in 1 second
Global trw_=0, trw=0	;accumulated time of render world in 1 second
Global tuw_=0, tuw=0	;accumulated time of update world in 1 second
Global NextSecond = MilliSecs()
Global TrisGranularity = 100
Local  tTemp
														;<<<< added <<<<<<<<<<<<


Repeat

	; --------------------------------------------------------------
	; Frame limiting
	; --------------------------------------------------------------

	Repeat
		frameElapsed = MilliSecs () - frameTime
	Until frameElapsed
	;este bucle espera a que pase el tiempo de un cuadro. Respecto al anterior
	;si es que ya no pasó.

	frameTicks = frameElapsed / framePeriod
	;es entero y vale 1 o más
	
	frameTween# = Float (frameElapsed Mod framePeriod) / Float (framePeriod)
	;es real e indica la parte fraccionaria respecto al período deseado: 0..1 0..framePeriod

	; --------------------------------------------------------------
	; Update game and world state
	; --------------------------------------------------------------
	;
	
	For frameLimit = 1 To frameTicks
	
		If frameLimit = frameTicks Then CaptureWorld
		frameTime = frameTime + framePeriod
		
		tTemp = MilliSecs()						;<<<< added <<<<<<<<<<<<
		UpdateGame ()
		tug_ = tug_ + MilliSecs() - tTemp		;<<<< added <<<<<<<<<<<<
		
		ups_ = ups_ + 1							;<<<< added <<<<<<<<<<<<

		tTemp = MilliSecs()						;<<<< added <<<<<<<<<<<<
		UpdateWorld
		tuw_ = tuw_ + MilliSecs() - tTemp		;<<<< added <<<<<<<<<<<<

			
	Next

	; --------------------------------------------------------------
	; **** Wireframe for DEBUG only -- remove before release! ****
	; --------------------------------------------------------------
		
	If KeyHit (17): w = 1 - w: WireFrame w: EndIf ; Press 'W'
	
	; --------------------------------------------------------------
	; Draw 3D world
	; --------------------------------------------------------------

	tTemp = MilliSecs()							;<<<< added <<<<<<<<<<<<
	RenderWorld frameTween
	trw_ = trw_ + MilliSecs() - tTemp			;<<<< added <<<<<<<<<<<<
	fps_=fps_+1									;<<<< added <<<<<<<<<<<<

	; --------------------------------------------------------------
	; Show result
	; --------------------------------------------------------------
	
	BarGraph()									;<<<< added <<<<<<<<<<<<

	Flip	; True

Until KeyHit (1)

End

; ------------------------------------------------------------------
; Game update routine, called from frame limiting code
; ------------------------------------------------------------------

Function UpdateGame ()

	;<<<< added <<<<<<<<<<<<

	; trun the camera with Left Right cursor keys
	
	If KeyDown (203) TurnEntity cam, 0, 0.5, 0
	If KeyDown (205) TurnEntity cam, 0, -0.5, 0
	
	;move randomly the boxes
	For i=1 To nBoxes
		TurnEntity Boxes(i),Rand(0.1,0.4),Rand(0.1,0.4),Rand(0.1,0.4)
		MoveEntity Boxes(i),0,.1,0
	Next 
	
End Function

Function BarGraph()

	;shows a graph with 
	;	FPS in red from 0 To 60
	;	game updates in white from 0 to 60
	;	ammount of RenderWorld in green plus game updates in blue plus update world in yelow
	;	concatenated and calculated as a percent of 1 second
	;
	;the graph has as a background a rectangle in black that covers just 5/6
	;signaling 100% for UpdateGame+UpdateWorld+RenderWorld
	;the vertical lines signal 5, 10, 15 and so on for fps and 10, 20, 30, etc
	;for percentages.
	;least: TrisRendered() from 0 to TrisGranularity*100 in grey
	;each vertical line signal for TrisRendered the ammount defined previously by TrisGranularity
	
	
	If MilliSecs()>NextSecond Then
		fps = fps_
		fps_ = 0
		ups = ups_
		ups_ = 0
		tug = tug_
		tug_ = 0
		trw = trw_
		trw_ = 0
		tuw = tuw_
		tuw_ = 0
		NextSecond=MilliSecs()+1000
	End If

	Color 0,0,0
	Rect 10,8,100,42
	For i=1 To 12		;from 0 to 60 whatever per second or 0 to 100%
		If i Mod 2 Then
			Color 0,128,128
		Else
			Color 0,192,192
		End If
		Line 10+i*10,8,10+i*10,50
	Next
	Color 255,0,0		;en rojo world renders 
	Rect 10,10,fps*2,6
	Color 255,255,255	;en blanco game updates
	Rect 10,20,ups*2,6
	Color 0,255,0		;como porcentaje en verde Trender
	Rect 10,30,100*trw/1000,6
	Color 0,0,255		;en azul T update game
	Rect 10+100*trw/1000,30,100*tug/1000,6
	Color 255,255,0		;en amarillo T update world
	Rect 10+100*trw/1000+100*tug/1000,30,100*tuw/1000,6
	Color 192,192,192
	Rect 10,40,TrisRendered()/TrisGranularity ,6	;en gris TrisRendered()

End Function

try this code, change the ammount of cubes to show, use the left/right arrows to rotate the camera and see how the white bar (game updates) remains constant and the red one (renders per second) change as the invers of the ammount of cubes in front of the camera.
the graph also shows the acumulative of UpdateWorld, RenderWold and Update game.

Juan

jtassinari

(Posted 2010) [#4]

thansk Kryzon,

your suggestion sounds perfect to me, i wonder how's this is gonig to load the CPU, BTW there is a great way to learn... Testing :D

cheers,

jTassinari
-[ www.absolute-line.net ]-

jtassinari

(Posted 2010) [#5]

Kryzon,
i tried the CreateTimer function but it takes the (one of the two) cpu at full usage!

browsing around in the programming area, i got this post (http://www.blitzbasic.com/Community/posts.php?topic=23175#238864) that is offering a great solution to fix the framrate and free the CPU charge.

doing this i still can have the change to send and recive datas on the net od to a db to store info.

While Charrua, your scritp is really nice, and really well explained, thansk indeed =)

cheers,

jTassinari
-[ www.absolute-line.net ]-

*	(Posted 2010) [#6]

I would recommend Delta timing over the blitz build timing functions, not only do the inbuilt functions suck away CPU time but with Delta time you can have the system do things inbetween frames.

Kryzon

(Posted 2010) [#7]

The timer commands do not waste CPU resources with blank loops. They free it just like if you used Delay.

[...] not only do the inbuilt functions suck away CPU time [...]

Where did you read that?

Run this:

timer = CreateTimer(1)

While Not KeyHit(1)
   
   If KeyDown(57) Then WaitTimer(timer)

   Print n
   n = n + 1

Wend

End

Hold space to see the effect of WaitTimer. Make sure you got the TaskManager minimized so you can see the CPU usage in the tray.

The real danger are manual methods that rely on blank loops to wait for time to pass, even if that time is nothing more than 1 or 2 milliseconds. Logically, waste is waste, no matter the amount.

*	(Posted 2010) [#8]

years ago when I used the inbuilt commands I used CreateTimer/WaitTimer and the game didnt run as fast as when I used Delta Timing. This was years ago so they might be better now :)

jtassinari

(Posted 2010) [#9]

Hi there,

i did some more testing, and had closer cpu usage in both case.
I tested a simple script with a lot of Sin and Cos and entitydistance, in both cases, a simulation of soral system, with hi color texture, on intel 2 core and intel 2 quad core.
In both cases the cpu worked fine, on the compiled script, and the cpu usage was around 7% on dual core (one cpu working) and 4% on intel2 quad (always one CPU working).

Now it's just as scipting is working better according to the understaing of it...

cheers,

jTassinari
-[ www.absolute-line.net ]-

_33	(Posted 2010) [#10]

Blitz3D will always just use ONE cpu core, as the language is single threaded. So it is normal that you get twice the cpu usage on a dual core than on a quad core. But I am not sure what your question is from the base of this thread. It's obvious that everyone that will run your program will have various CPUs (INTEL or AMD) at various speeds. You on the other hand need to level it out with the right methods (like what Kryzon proposed for example).

_PJ_	(Posted 2010) [#11]

Full CPU load will be assigned to a B3D app regardless of the frame limiting methods, the thread ha the CPU availabilitiy even if the workload is much less than the processor's capability.
To free up the CPU, just add in a small (i.e 1 - 10 maybe?) Delay in the loop. This will halt execution briefly when the CPU can continue with other priority tasks.

* for a single core only of course.