2D snow Need help

Blitz3D Forums/Blitz3D Programming/2D snow Need help

WERDNA

(Posted 2009) [#1]

Hey,

I'm making a 2D game right, where the character is able to dig
through snow.

What I've done so far, is created a Type called Snow, then
made several thousand 1 pixel by 1 pixel pieces of snow to cover
the ground.
Then I simply run a function, that erases one anytime the player
collides with it.

The problem is, my game can only handle about 5000 of these
before crashing and I need them to fill the entire screen.
(Meaning around 480,000 of them).

I created them, by making a 1,1 image using createimage, and
then using Plot to slap down a white pixel.

Then a For loop like so.
For Snows = 1 to 5000
Snow.Snow = New Snow
Snow\image = SnowImage; < The image previously created
Snow\x = x
Snow\y = y
next

Is there a better way to do this?
to create several thousand 1 pixel snow flakes that cover the
screen?

Thanks,

WERDNA

BLaBZ

(Posted 2009) [#2]

Haha, Thats crazy 480,000 images

Well couldn't you just void creating the image all together? Just plot on the back buffer?

Mahan

(Posted 2009) [#3]

If the char image is not very big you could loop through every pixel of it and where the char-image-pixels are not transparent compare against the pixels of a snow-image on the proper x, y offset, and simply "remove" the snow by writing pixels of a different color ...

Example: (keys w, a, s, d and ESC to end)




Function removeSnowUnderChar(charImg, snowImg, charX, charY)

	Local charBuf=ImageBuffer(charImg)
	Local snowBuf=ImageBuffer(snowImg)
	
	LockBuffer(charBuf)
	LockBuffer(snowBuf)

	Local x, y
	Local w = ImageWidth(charImg)
	Local h = ImageHeight(charImg)
	For x = 0 To (w-1)
		For y = 0 To (h-1)
			If (ReadPixelFast(x, y, charBuf) <> $ff000000) Then ; if this is a non-transparent pixel of the char (black)
				If (ReadPixelFast(x+charX, y+charY, snowBuf) = $ffffffff) Then ; and if it hits a "snow pixel"
					WritePixelFast(x+charX, y+charY, $ff000000, snowBuf) ; remove the snow
				EndIf
			EndIf
		Next
	Next

	UnlockBuffer(snowBuf)
	UnlockBuffer(charBuf)
End Function




Function main()

	Graphics 640, 480, 0, 2
	
	
	;create snow
	Local snowImage=CreateImage(640, 480) ; big as the screen
	SetBuffer(ImageBuffer(snowImage))
	Color 255, 255, 255
	Rect(0, 280, 640, 200) ; "paint" the snow onm the lower part of the screen
	
	;Create "char"
	Local char=CreateImage(32, 32)
	SetBuffer(ImageBuffer(char))
	Color 0,0,255 ; blue
	Oval 16, 16, 10, 10
	
	Local charX, charY
	
	
	SetBuffer(BackBuffer())
	While Not KeyDown(1)
		Cls()
	
		If KeyDown(17) And charY > 0 ; "w"
			charY = charY - 1
		EndIf
		If KeyDown(30) And charX > 0 ; "a"
			charX = charX - 1
		EndIf
		If KeyDown(31) And charY < (480-32) ; "s"
			charY = charY + 1
		EndIf
		If KeyDown(32) And charX < (640 - 32) ; "d"
			charX = charX + 1
		EndIf


		removeSnowUnderChar(char, snowImage, charX, charY)

		DrawImage(char, charX, charY)
		DrawImage(snowImage, 0, 0) ; always draw the "snow" over the whole screen
		Text 10, 10, "x=" + charX + " y=" + charY
		Flip()
	Wend

	EndGraphics()



End Function


main()

WERDNA

(Posted 2009) [#4]

Oh, lol!

I should have thought of that.

Thanks for the example Mahan!

Thanks to this, in a few days I'll be able to upload my newest mini game. Plow Dog!

WERDNA