CenterMesh keeping original position.

Blitz3D Forums/Blitz3D Programming/CenterMesh keeping original position.

RifRaf

(Posted 2009) [#1]

I hope I can explain this right, what im trying to do is take several meshes and center them.. but I want the resulting mesh to remain in the indentical space as the previous uncentered mesh. I only need to center the x\z, Y should be unchanged.
What im going to do, hopefully is use this
http://www.blitzbasic.com/codearcs/codearcs.php?code=1343
on the main map, so that each segment can be culled, currently though they are nearly always seen by the camera because their center is 0,0,0 even if they actual geometry is 1000 units away from that.

Any ideas on the best(and quickest) way to go about this?
below is a pic issustrating this. The pics texts says somthing about scale, thats not important as I use scalemesh when scaling anyway.

dynaman

(Posted 2009) [#2]

Save the Y position in a variable.
Execute the centermesh command
reset the Y coordinate.

Save this as the default position. (been ages since I played with B3D so I'm not sure of th exact commands to use)

RifRaf

(Posted 2009) [#3]

Thanks for the reply, but that doesnt seem to address the issue. Probably because of my poor description.

I cannot re position the mesh. it has to remain (as far as geometry goes) in the exact same place after the centermesh.
what it should boil down to is some sort of calculation before centermesh, then the centermesh, then a positionentity based off the initial calculation to get it back where it should be. But for the life of me I cant get it right.

Stevie G

(Posted 2009) [#4]

Interesting, I'm using a variation of the clusterise function to split up my visible landscapes but I never thought that it was the center point that is used in culling. I'll need to check.

**EDIT**
Blitz automatically generates a bounding box for meshes which must be based on the min,max vertex values. It only uses the center point of the entity for non-mesh entities. I think what you have should already work, test it using the EntityInView command. If it didn't then the 'clusterise mesh' function would be useless.
**EDIT**

You've got 2 options, the second being easiest

1.

* Use the clustersised mesh function
* For each cluster/chunk, iterate through all vertices and find the mid point.
* Center the mesh
* Positionentity the centered mesh at the mid point you found earlier.

2.

* Use the clusterised mesh function
* For each cluster / chunk, reset the entitycullbox ( not sure the name of this function ) to coincide with the actual geometry.

Stevie

RifRaf

(Posted 2009) [#5]

**EDIT**
Blitz automatically generates a bounding box for meshes which must be based on the min,max vertex values. It only uses the center point of the entity for non-mesh entities. I think what you have should already work, test it using the EntityInView command. If it didn't then the 'clusterise mesh' function would be useless

perhaps entityinview does a linepick type thing, wich uses the geometry not the bounding box. Try entityautofade and test again :)

2.

* Use the clusterised mesh function
* For each cluster / chunk, reset the entitycullbox ( not sure the name of this function ) to coincide with the actual geometry.

I never knew such a command existed, ill have to look through the docs and try to find it.

Stevie G

(Posted 2009) [#6]

Entityinview does not do a linepick, entityvisible does though. I remember because it's slower than a week in the jail. I assume that entityinview simply returns a 'was rendered during the last renderworld' flag.

It's likely that entityauto fade uses the center coords of the entity rather than the center of the geometry. Why not use fog and let the rendering cull what is out of view automatically?

RifRaf

(Posted 2009) [#7]

what is interesting then is that I can do a trisrendered() and this shows most chunks being drawn even if they are far behind the camera.

Stevie G

(Posted 2009) [#8]

A quick check tells me that my entities are not all in view ( entityinview ) as expected ( clevels are clustered into 3 x 3 chunks ) but I've yet to check the trisrendered. I'll check tomorrow.

Ross C

(Posted 2009) [#9]

I know exactly what you mean rifraf. I had this exactly same problem with my cannon game. I needed to break the model up and find the centre points, so i could rotate them around it.

What i did was this:

1. loop through every vertex in the mesh, finding the furthest -x +x -y +y -z +z. Then find the exact centre point using this information.

2. Store the x y and z distances to the world centre (0,0,0)

3. Use the positionmesh command to position the mesh around teh world centre, using the co-ords from point 2

4. Finally use the moveentity command to move the entity back to where it was. This time though, the meshes centre will be correct.

I have a fix mesh centre function for this purpose on my computer at home. I can post it (when i get home) if you want? Just be wary of scaling/moving/rotating the entity first before you centre it.

jfk EO-11110

(Posted 2009) [#10]

This info about not culling a mesh when its center pivot is in view (but not a single triangle) now really confuses me. I am using a culsterisation too and so far I thought it's culling things correctly. I clearly see variations in TrisRendered, compared to the unclusterized map.

Maybe EntityAutofade works diffrent? It would make sense, I don't think ENtityAutofade is going to check for a bounding box, rather only the distance between camera and entity.

Zethrax

(Posted 2009) [#11]

Here you go.

EDIT: Edited to return the total vertex count, so that it may be used to check for an empty mesh.

; These globals are used to return x, y, and z float values from functions.
; They must be accessed immediately after any function that uses them is called
; as they will be modified by other functions which use them.
Global G_return_x#, G_return_y#, G_return_z#


Function CenterMesh( mesh )
; Centers the vertex data of the specified mesh to be at the world center.

; RETURNS:-
; The function returns the total number of vertices found in the mesh.
; If a zero is returned, then no vertices were found and the globals G_return_x#, G_return_y#, G_return_z#
; do not contain valid data, and should not be used for any purpose.

; The original offset position of the mesh in the globals G_return_x#, G_return_y#, G_return_z#.

; NOTES:-
; Requires the G_return_x#, G_return_y#, G_return_z# globals.

Local max_surface, max_vertex, surface, vertex, vx#, vy#, vz#, vertex_count
Local px#, py#, pz#, nx#, ny#, nz#

; Count the number of surfaces.
max_surface = CountSurfaces ( mesh )

If max_surface ; If the mesh has surface data...

	; Loop through all the surface indexes.
	For surface_index = 1 To max_surface
	
		; Get the surface for the current surface index.
		surface = GetSurface ( mesh, surface_index )
		
		; Count the number of vertices.
		max_vertex = CountVertices ( surface )
		
		; Increment the count of all vertices found, so that it can be returned by the function.
		vertex_count = vertex_count + max_vertex
		
		If max_vertex ; If the surface has vertex data...
		
			; Vertex indexes start at zero, so adjust max_vertex to suit.
			max_vertex = max_vertex - 1	
		
			; Seed min/max vertex variables.
			px# = VertexX# ( surface, 0 ) : nx# = px#
			py# = VertexY# ( surface, 0 ) : ny# = py#
			pz# = VertexZ# ( surface, 0 ) : nz# = pz#
		
			; Loop through all the vertex indexes.
			For vertex_index = 0 To max_vertex
			
				; Get the x, y, z position of the vertex.
				vx# = VertexX# ( surface, vertex_index )
				vy# = VertexY# ( surface, vertex_index )
				vz# = VertexZ# ( surface, vertex_index )
				
				; Find the highest x, y, z vertex position values.
				If vx# > px# Then px# = vx#
				If vy# > py# Then py# = vy#
				If vz# > pz# Then pz# = vz#
				
				; Find the lowest x, y, z vertex position values.
				If vx# < nx# Then nx# = vx#
				If vy# < ny# Then ny# = vy#
				If vz# < nz# Then nz# = vz#
			
			Next
			
		EndIf
	
	Next
	
	; Find the mid-point between the highest and lowest x, y, z vertex position values.
	G_return_x# = ( px# + nx# ) / 2.0
	G_return_y# = ( py# + ny# ) / 2.0
	G_return_z# = ( pz# + nz# ) / 2.0
	
	; Position the mesh data back to the world center.
	PositionMesh mesh, -G_return_x#, -G_return_y#, -G_return_z#
	
EndIf

; Return the total number of vertices found. If a zero is returned,
; then no vertices were found and the globals G_return_x#, G_return_y#, G_return_z#
; do not contain valid data, and should not be used for any purpose.
Return vertex_count

End Function


; *** EXAMPLE ***


Graphics3D 800, 600, 0, 2
SetBuffer BackBuffer()

TurnEntity CreateLight(), 45.0, 0.0, 0.0

Global G_cam = CreateCamera()
CameraZoom G_cam, 1.6
MoveEntity G_cam, 0.0, 0.0, -20.0

; Create a box to mark the world center.
Global G_world_center_marker = CreateCube()
ScaleEntity G_world_center_marker, 0.25, 0.25, 0.25
EntityColor G_world_center_marker, 255, 0, 0

Global G_test_mesh = CreateCube()
EntityAlpha G_test_mesh, 0.5
PositionMesh G_test_mesh, 10.0, 10.0, 10.0

; Create a box to mark the center of the test mesh.
Global G_testmesh_center_marker = CreateCube()
PositionEntity G_testmesh_center_marker, 10.0, 10.0, 10.0
ScaleEntity G_testmesh_center_marker, 0.25, 0.25, 0.25
EntityColor G_testmesh_center_marker, 0, 255, 0


UpdateWorld : RenderWorld : Flip

Print "Press any key to center the mesh."

WaitKey

If CenterMesh( G_test_mesh ) = 0 Then Print "ERROR: No vertex data found." : WaitKey : End

UpdateWorld : RenderWorld : Flip

Print "Press any key to move the mesh back to its original position."

WaitKey

; Position the G_test_mesh entity back where it was.
PositionEntity G_test_mesh, G_return_x#, G_return_y#, G_return_z#

UpdateWorld : RenderWorld : Flip

Print "Press any key to continue."

WaitKey

While Not KeyDown( 1 )

If KeyDown( 205 )=True Then TurnEntity G_cam,0,-1,0
If KeyDown( 203 )=True Then TurnEntity G_cam,0,1,0
If KeyDown( 208 )=True Then MoveEntity G_cam,0,0,-0.05
If KeyDown( 200 )=True Then MoveEntity G_cam,0,0,0.05

; Use camera project to get 2D coordinates from 3D coordinates of cube
CameraProject(G_cam,EntityX(G_test_mesh),EntityY(G_test_mesh),EntityZ(G_test_mesh))

RenderWorld

; If cube is in view then draw text, if not then draw nothing otherwise text will be drawn at 0,0
If EntityInView(G_test_mesh,G_cam)=True

; Use ProjectedX() and ProjectedY() to get 2D coordinates from when CameraProject was used.
; Use these coordinates to draw text at a 2D position, on top of a 3D scene.
Text ProjectedX#(),ProjectedY#(),"Test Mesh"

EndIf

Text 0,0,"Use cursor keys to move about"
Text 0,20,"ProjectedX: "+ProjectedX#()
Text 0,40,"ProjectedY: "+ProjectedY#()
Text 0,60,"ProjectedZ: "+ProjectedZ#()
Text 0,80,"EntityInView: "+EntityInView(G_test_mesh,G_cam)
Text 0,100,"Tris Rendered: "+TrisRendered()

Flip

Wend

End

D4NM4N

(Posted 2009) [#12]

Not sure if it is what you are after, but i wrote some code ages ago to fit all my animated models (all at different sizes) into a certain size eg. 1x1x1 blitz 3d unit.

http://www.blitzbasic.co.nz/codearcs/codearcs.php?code=1430

While it may not be exactly what you are looking for, there is some mesh measurement stuff in there so may give you the 'idea' you need :)

RifRaf

(Posted 2009) [#13]

Thanks Bill, ill give that a shot!
edit: it seems to work great, thanks!

RifRaf

(Posted 2009) [#14]

curious, I can cluster a mesh thats over the tri limit (meaning a model that would crash you on renderworld)
but it comes out all weird. Either of you had any luck with very high poly model clustering.

jfk EO-11110

(Posted 2009) [#15]

Whenever I got a model with more than 31k Tris or 64k Vertices then I put them on additional surfaces. I did this some time ago to display a 3D scan with 200kPoints+ Actually one of those Laser Plasma Glass Cube files, that works with Dots, not with triangles. However, in Game design I never got such problems. Currently my map says "10kTris" and I am already worried :)