Weapon Model sticking into the ground

Blitz3D Forums/Blitz3D Programming/Weapon Model sticking into the ground

A51M15X

(Posted 2009) [#1]

I have a weapon model attached to the player and whenever you look down with the camera it sticks into the ground. This is probably really easy to solve, but i have no idea how to fix this.

GIB3D

(Posted 2009) [#2]

Can you post the code?

A51M15X

(Posted 2009) [#3]

weapon1=LoadMesh("M4.3ds",camera)
ScaleEntity weapon1,.5,.5,.5
RotateEntity weapon1,0,90,0
MoveEntity weapon1,1.8,-.8,-1

GIB3D

(Posted 2009) [#4]

Maybe it has something to do with collision? If you even have it..

Play	(Posted 2009) [#5]

Maybe this can help ?
http://www.blitzbasic.com/codearcs/codearcs.php?code=1271
bless :)

jfk EO-11110

(Posted 2009) [#6]

I guess the wepon is too big. Just scale it smaller, then move it closer to the camera. In extreme cases you have to scale the Z-Axis a lil shorter because of the lense distortion. This method however also prevents the weapon from sticking into the walls.

GIB3D

(Posted 2009) [#7]

Oh I thought you were talking about not being able to get the gun out of the wall because it's stuck.

Guy Fawkes

(Posted 2009) [#8]

this works better:

weapon1=LoadMesh("M4.3ds",camera)
ScaleEntity weapon1,meshwidth(weapon1)/4,meshheight(weapon1)/4,meshdepth(weapon1)/4 ;divide by 2 for possible better results
RotateEntity weapon1,0,90,0
MoveEntity weapon1,1.8,-.8,-1

Zethrax

(Posted 2009) [#9]

Just create a second camera, parent the gun to it, and sync the rotation of the camera to that of your main camera to get correct lighting on the gun.

EXAMPLE: Creating the second camera.

Function CreateHudCamera( order, x#, y#, z# )
; USAGE:
; Creates a camera to be used for a heads-up display.

; PARAMETERS:
; order - This sets the drawing order of the camera. 'order' should be a negative number, so that the HUD camera is drawn on top of the main camera graphics. The highest value negative number will be drawn last (eg. The '-2' camera will be drawn after the '-1' camera.).

; x#, y#, z# - Set the camera's absolute world position. The position should set so that the camera and its associated 3D graphic objects do not interfere with any other cameras.

; RETURNS:
; The new HUD camera's entity handle is returned.


	Local cam = CreateCamera()
	PositionEntity cam, x#, y#, z#, True ; 
	CameraRange cam, 0.2, 5.0
	CameraZoom cam, 1.6
	EntityOrder cam, order
	CameraClsMode cam, False, True ; This prevents the background graphics from being overwritten by the camera's clearscreen color.
	Return cam
End Function

To sync the rotation use the code below, or something similar.

RotateEntity HUD_camera, EntityPitch# ( user_x_pivot_handle, True ), EntityYaw# ( user_handle, True ), 0.0, True

Where HUD_camera is the handle to the second camera; user_x_pivot_handle is the handle to a pivot used for the pitch of the player's head (FPS view); and user_handle is the handle to the main entity used for the player, which is yawed.

Nate the Great

(Posted 2009) [#10]

of you could just say

entityorder gun,-1

??? This always fixes my problems

Stevie G

(Posted 2009) [#11]

An Entityorder <> 0 disables polygon z-ordering. This works fine for quads but for a detailed mesh it looks terrible.

xtremegamr

(Posted 2009) [#12]

Um...That seems a bit complicated. I would just render the gun after everything else. Like this:


Graphics3D 800,600,0,2 ;set your 3d graphics

gunpiv=CreatePivot() ;parent the gun model to this
worldpiv=CreatePivot() ;parent everything BUT the gun model to this

;main loop
While Not KeyHit(1)

SetBuffer BackBuffer()
Cls

;do your main gameplay code here
;Player movement, shooting, etc.

UpdateWorld ;update player collisions, etc.

HideEntity gunpiv ;Show all entities except for the gun
ShowEntity worldpiv

RenderWorld ;render everything but the gun

ShowEntity gunpiv ;Hide all entities except for the gun
HideEntity worldpiv

RenderWorld ;render the gun

Wend ;end of main loop

end

The above code will render the world before the gun, so no matter what, the gun will never stick through the floor (or any world geometry).

Zethrax

(Posted 2009) [#13]

The above code will render the world before the gun, so no matter what, the gun will never stick through the floor (or any world geometry).

You're right. That code wouldn't show the gun sticking through the world geometry. It wouldn't show any world geometry at all, as you haven't set CameraClsMode to disable clearing the background. Also, all that hiding and showing would likely cause problems with interpolation if render tweening was being used for game speed regulation.

Basically, what you're trying to do is equivalent to using a second camera, but with the added overhead of hiding every entity in the world for each render frame.

Here's a practical example of using the second camera approach with a 2 metre long gun. Note that the second camera doesn't introduce any significant additional overhead, as it's just rendering the gun - as would be done if the gun were rendered by the main camera.

Graphics3D 800, 600, 0, 2
SetBuffer BackBuffer ()
HidePointer


; == Declarations ==


; -- World.
;Global gravity# = 9.8
;^^^^^^

; -- Viewport.
Global viewport_center_x = GraphicsWidth () / 2
Global viewport_center_y = GraphicsHeight () / 2
;^^^^^^


; -- Mouselook.
Global mouselook_x_inc# = 0.4 ; This sets both the sensitivity and direction (+/-) of the mouse on the X axis.
Global mouselook_y_inc# = 0.4 ; This sets both the sensitivity and direction (+/-) of the mouse on the Y axis.
Global mouse_left_limit = 250 ; Used to limit the mouse movement to within a certain number of pixels (250 is used here) from the center of the screen. This produces smoother mouse movement than continuously moving the mouse back to the center each loop.
Global mouse_right_limit = GraphicsWidth () - 250 ; As above.
Global mouse_top_limit = 250 ; As above.
Global mouse_bottom_limit = GraphicsHeight () - 250 ; As above.
;^^^^^^

; -- Mouse smoothing que.
Global mouse_x_speed_1#
Global mouse_x_speed_2#
Global mouse_x_speed_3#
Global mouse_x_speed_4#
Global mouse_x_speed_5#
Global mouse_y_speed_1#
Global mouse_y_speed_2#
Global mouse_y_speed_3#
Global mouse_y_speed_4#
Global mouse_y_speed_5#
;^^^^^^

; -- User.
Global user_movement_speed# = 4.0 ; The user's movement speed. This produces a movement speed of 4 metres per second.
Global user_camera_pitch#
Const USER_CENTERPOINT_HEIGHT# = 0.94
Const USER_CAMERA_HEIGHT# = USER_CENTERPOINT_HEIGHT# * 2.0 - 0.1
;^^^^^^


; -- Timing.
Global milli_secs ; Holds the value of the Millisecs() timer. Set at the start of the main loop.
Global old_time ; This must be set to the current 'MilliSecs()' time at the start of a new game and when returning from a pause.
Global game_time ; This holds a relative game time value which is used with timeouts so that they can be paused.
Global Delta_Time# ; Use this as a multiplier for all continuous game world events, to regulate game speed.
;^^^^^^

; -- Collision.
Const COLLTYPE_geometry = 1
Const COLLTYPE_user = 2
;^^^^^^


; == Setup ==


; -- Create a light;
RotateEntity CreateLight (), 45.0, 45.0, 0.0, True
;^^^^^^

; -- Create user entity.
Global user = CreatePivot()
PositionEntity user, 0.0, USER_CENTERPOINT_HEIGHT#, 0.0, True
EntityRadius user, USER_CENTERPOINT_HEIGHT#
EntityType user, COLLTYPE_user
;^^^^^^

; -- Create user's camera.
Global user_camera = CreateCamera( user )
CameraRange user_camera, 0.5, 500.0
CameraClsColor user_camera, 0.0, 106.0, 213.0
CameraZoom user_camera, 1.6 ; Set the camera focus to the correct value for the human eye.
PositionEntity user_camera, 0.0, USER_CAMERA_HEIGHT#, 0.0, True
;^^^^^^

; Create HUD camera.
Global hudcam = CreateHudCamera( -1, 0, -1000.0, 0 )

; -- Create user's gun.
Global gun = CreateCube()
ScaleMesh gun, 0.05, 0.05, 1.0
PositionMesh gun, 0.0, 0.0, 1.0
UpdateNormals gun
EntityParent gun, hudcam
PositionEntity gun, 0.3, -0.3, 0.3
;^^^^^^

; -- Create some meshes to use as a movement reference.
Global sphere = CreateSphere ()
UpdateNormals sphere
PositionEntity sphere, 15.0, 1.0, 0.0, True
EntityType sphere, COLLTYPE_geometry
Global cone = CreateCone ()
UpdateNormals cone
PositionEntity cone, -15.0, 1.0, 0.0, True
EntityType cone, COLLTYPE_geometry
Global cube = CreateCube ()
UpdateNormals cube
PositionEntity cube, 0.0, 1.0, 15.0, True
EntityType cube, COLLTYPE_geometry
Global cylinder = CreateCylinder ()
UpdateNormals cylinder
PositionEntity cylinder, 0.0, 1.0, -15.0, True
EntityType cylinder, COLLTYPE_geometry
	; -- Create grid texture.
	Global grid_2d_tex = CreateTexture ( 256, 256, 11 )
	SetBuffer TextureBuffer ( grid_2d_tex )
	For i = 0 To 4
		Rect i, i, 256 - i - i, 256 - i - i, False
	Next
	For y = 5 To 250
		For x = 5 To 250
			WritePixel x, y, 0
		Next
	Next
	SetBuffer BackBuffer ()
	;^^^^^^
	; -- Create 2D grid.
	Global grid_2D = CreatePlane ()
	EntityType grid_2D, COLLTYPE_geometry
	EntityTexture grid_2D, grid_2d_tex
	EntityFX grid_2D, 9
	;^^^^^^
;^^^^^^

InitializeNewMap()

; == Main Code ==


; -- Initialize the loop.
old_time = MilliSecs ()
Collisions COLLTYPE_user, COLLTYPE_geometry, 2, 2
;^^^^^^

; -- Main loop.
While Not KeyHit ( 1 ) ; Exit the main loop if the escape key is pressed.
	CalculateDeltatimeAndGametime()
	MouseLook()
	MoveUser()
	UpdateWorld
	RenderWorld

	; -- Frames Per Second counter.
	; Place into the main program loop where it will be executed each frame. The variables used here do not need to be declared globlly as this will occur automatically if the routine is placed in the main program. The value of 'milli_secs' should be set from the 'MilliSecs()' Blitz function at the start of the main program loop.
	FPS_framecounter = FPS_framecounter + 1
	If milli_secs >= FPS_timeout
		FPS_timeout = milli_secs + 1000
		FPS_framecount = FPS_framecounter
		FPS_framecounter = 0
	EndIf
	Text 10, 10, "FPS"
	Text 40, 10, FPS_framecount
	;^^^^^^

	Text 10, 30, "Use W, A, S, D, F, C to move and ESCAPE to exit."

	VWait ; Use this along with 'Flip False' so that the user can't disable the wait for vertical blank.
	Flip False

	Delay ( 1 ) ; Lets Windows do whatever housekeeping it needs to. Useful if the user is downloading something at the same time as playing a game, etc. Not sure if it's required for a windowed game.

Wend
;^^^^^^

End ; End the program.


; == Functions ==


Function MouseLook()

	; -- Update the smoothing que to smooth the movement of the mouse.
	mouse_x_speed_5# = mouse_x_speed_4#
	mouse_x_speed_4# = mouse_x_speed_3#
	mouse_x_speed_3# = mouse_x_speed_2#
	mouse_x_speed_2# = mouse_x_speed_1#
	mouse_x_speed_1# = MouseXSpeed ( )
	mouse_y_speed_5# = mouse_y_speed_4#
	mouse_y_speed_4# = mouse_y_speed_3#
	mouse_y_speed_3# = mouse_y_speed_2#
	mouse_y_speed_2# = mouse_y_speed_1#
	mouse_y_speed_1# = MouseYSpeed ( )
	the_yaw# = ( ( mouse_x_speed_1# + mouse_x_speed_2# + mouse_x_speed_3# + mouse_x_speed_4# + mouse_x_speed_5# ) / 5.0 ) * mouselook_x_inc#
	the_pitch# = ( ( mouse_y_speed_1# + mouse_y_speed_2# + mouse_y_speed_3# + mouse_y_speed_4# + mouse_y_speed_5# ) / 5.0 ) * mouselook_y_inc#
	;^^^^^^

	TurnEntity user, 0.0, -the_yaw#, 0.0 ; Turn the user on the Y (yaw) axis.
	user_camera_pitch# = user_camera_pitch# + the_pitch#
	; -- Limit the user's camera to within 180 degrees of pitch rotation. 'EntityPitch()' returns useless values so we need to use a variable to keep track of the camera pitch.
	If user_camera_pitch# > 90.0 Then user_camera_pitch# = 90.0
	If user_camera_pitch# < -90.0 Then user_camera_pitch# = -90.0
	;^^^^^^
	RotateEntity user_camera, user_camera_pitch#, 0.0, 0.0 ; Pitch the user's camera up and down.
	
	RotateEntity hudcam, EntityPitch# ( user_camera, True ), EntityYaw# ( user, True ), 0.0, True
	
	; -- Limit the mouse's movement. Using this method produces smoother mouselook movement than centering the mouse each loop.
	If ( MouseX() > mouse_right_limit ) Or ( MouseX() < mouse_left_limit ) Or ( MouseY() > mouse_bottom_limit ) Or ( MouseY() < mouse_top_limit )
		MoveMouse viewport_center_x, viewport_center_y
	EndIf
	;^^^^^^

End Function


Function MoveUser()

	If KeyDown( 32 ) Or KeyDown( 205 ) ; Right. The 'D' and 'CURSOR RIGHT' keys.
		x#=1.0
	Else If KeyDown( 30 ) Or KeyDown( 203 ) ; Left. The 'A' and 'CURSOR LEFT' keys.
		x#=-1.0
	EndIf

	If KeyDown( 33 ) Or KeyDown( 54 ) ; Up. The 'F' and 'RIGHT SHIFT' keys.
		y#=1.0
	Else If KeyDown( 46 ) Or KeyDown( 157 ) ; Down. The 'C' and 'RIGHT CONTROL' keys.
		y#=-1.0
	EndIf

	If KeyDown( 17 ) Or KeyDown( 200 ) ; Forward. The 'W' and 'CURSOR UP' keys.
		z#=1.0
	Else If KeyDown( 31 ) Or KeyDown( 208 ) ; Backward. The 'S' and 'CURSOR DOWN' keys.
		z#=-1.0
	EndIf

	MoveEntity user, x# * user_movement_speed# * Delta_Time#, y# * user_movement_speed# * Delta_Time#, z# * user_movement_speed# * Delta_Time# ; Move the user.

End Function


Function CalculateDeltatimeAndGametime()
; NOTES:
; The variable 'old_time' must be set to the current millisecs time at the start of a new game and when returning from a pause.

	milli_secs = MilliSecs () ; Store the 'MilliSecs ()' time in the 'milli_secs' variable so that you can use the stored time value without calling 'MilliSecs ()' again in this loop.

	the_time_taken = milli_secs - old_time ; Calculate the time the last loop took to execute.
	If the_time_taken > 100 Then the_time_taken = 100 ; This stops disk accesses and the like from causing jumps in position.
	game_time = game_time + the_time_taken ; Calculate the value for the 'game_time' variable used with timeouts, etc.
	Delta_Time# = the_time_taken / 1000.0 ; Calculate the value for the 'Delta_Time#' variable used to regulate game speed.
	old_time = milli_secs ; Update the 'old_time' variable with the current time.

End Function


Function InitializeNewMap()
; NOTES:
 ; This function should only need to be run when a new map is first loaded. It should normally be executed by the map file loader routine.

	; -- Precache the game's 3D graphics media. This forces the media to be uploaded to the video card. This should be done before any of the media is hidden or has its alpha set to zero to turn off rendering. Note that the camera will end up pointing back to where it started, so there is no need to reset its orientation.
	For i = 1 To 4
		TurnEntity user_camera, 0.0, 90.0, 0.0, True
		RenderWorld
	Next
	;^^^^^^
End Function


Function CreateHudCamera( order, x#, y#, z# )
; USAGE:
; Creates a camera to be used for a heads-up display.

; PARAMETERS:
; order - This sets the drawing order of the camera. 'order' should be a negative number, so that the HUD camera is drawn on top of the main camera graphics. The highest value negative number will be drawn last (eg. The '-2' camera will be drawn after the '-1' camera.).

; x#, y#, z# - Set the camera's absolute world position. The position should set so that the camera and its associated 3D graphic objects do not interfere with any other cameras.

; RETURNS:
; The new HUD camera's entity handle is returned.


	Local cam = CreateCamera()
	PositionEntity cam, x#, y#, z#, True ; 
	CameraRange cam, 0.2, 5.0
	CameraZoom cam, 1.6
	EntityOrder cam, order
	CameraClsMode cam, False, True ; This prevents the background graphics from being overwritten by the camera's clearscreen color.
	Return cam
End Function