Adjusting a triangles normal?

Blitz3D Forums/Blitz3D Programming/Adjusting a triangles normal?

JA2	(Posted 2009) [#1]

Hi :)

I need some help with automatically adjusting normals on a mesh. If you look at the picture below, you can see where I've moved a section of the mesh down. It's the corners that are the problem, I'd like each corner to be the same, either a sharp corner or angled but not both like in the picture.

Here's the code to make the mesh and move sections of it up and down.

Can anyone help?

Graphics3D 640,480,0,2

Global Cam = CreateCamera()
MoveEntity Cam,0,6,-6
TurnEntity Cam,55,0,0

Global Lit = CreateLight()
TurnEntity Lit,45,45,0

Global Terrain = CreateFlatTerrain (10,10,20,20)
MoveEntity Terrain,0,-2,0
EntityPickMode Terrain,2

Global BrushHeight#=-1,BrushSize=3

Local Tex = CreateTexture (64,64)
SetBuffer TextureBuffer (Tex)
Color 150,150,250
Rect 0,0,64,64
Color 50,50,100
Rect 0,0,32,32
Rect 32,32,32,32
SetBuffer BackBuffer()

ScaleTexture Tex,0.05,0.05
EntityTexture Terrain,Tex

While Not KeyDown (1)

	Local I,S,MDL,MDR

	MDL = MouseDown (1)
	MDR = MouseDown (2)

	If KeyHit (2) Then BrushHeight = -1
	If KeyHit (3) Then BrushHeight = -0.25
	If KeyHit (4) Then BrushHeight = 0
	If KeyHit (5) Then BrushHeight = +0.25
	If KeyHit (6) Then BrushHeight = +1

	If MDL
		CameraPick Cam,MouseX(),MouseY()
		If PickedEntity() = Terrain
			Local Surfaces = CountSurfaces (Terrain)
			For S = 1 To Surfaces
				Local Surface = GetSurface (Terrain,S)
				Local Vertices = CountVertices (Surface)
				For I = 0 To Vertices-1
					Local PX0 = PickedX()
					Local PX1 = PX0-BrushSize/2
					Local PX2 = PX0+BrushSize/2
					Local PZ0 = PickedZ()
					Local PZ1 = PZ0-BrushSize/2
					Local PZ2 = PZ0+BrushSize/2
					Local VX# = VertexX (Surface,I)
					Local VZ# = VertexZ (Surface,I)
					If VX > PX1 And VX < PX2 And VZ > PZ1 And VZ < PZ2
						VertexCoords Surface,I,VertexX(Surface,I),BrushHeight,VertexZ(Surface,I)
					EndIf
				Next
			Next
		EndIf
	EndIf

	If KeyDown (57) Then WireFrame True Else WireFrame False

	UpdateWorld
	RenderWorld

	Flip
	
Wend
End

Function CreateFlatTerrain (W#,D#,SegX,SegZ)

	Local Mesh = CreateMesh()
	Local Surface = CreateSurface (Mesh)
	Local HW# = W/2.0
	Local HD# = D/2.0
	Local ScaleV# = SegZ / Float (SegX)
	Local DX#,DZ#,X,Z,A

	For X = 0 To SegX
		DX = X / Float (SegX)
		For Z = 0 To SegZ
			DZ = Z / Float (SegZ)
			Local V = AddVertex (Surface,DX*W-HW,0,DZ*D-HD,DX,DZ*ScaleV)
			VertexNormal (Surface,V,0,1,0)
		Next
	Next
	For X = 0 To SegX-1
		For Z = 0 To SegZ-1
			Local V0 = X*(SegZ+1)+Z			
			Local V1 = X*(SegZ+1)+Z+1		
			Local V2 = (X+1)*(SegZ+1)+Z+1	
			Local V3 = (X+1)*(SegZ+1)+Z		 
			AddTriangle (Surface,V0,V1,V2)
			AddTriangle (Surface,V0,V2,V3)
		Next
	Next

	Return Mesh

End Function

Ross C

(Posted 2009) [#2]

I believe you need to call updatenormals() after you reposition your vertices. sswift has a good updatenormals function in the archives too.

Warner

(Posted 2009) [#3]

This probem has not much to do with normals. The way the base mesh is created, it will allways create two different type of corners for the lowered areas. Maybe you can replace the way the triangles are connected in the 'upperleft' and 'lowerright' corner of the lowered area?

JA2	(Posted 2009) [#4]

Thanks for the replies :)

Any idea how to select only the upper left and lower right triangles of the altered sections and turn them?

Warner

(Posted 2009) [#5]

I believe that is not possible. The triangles are allready defined, and I don't know any way to change that. Also, if you change the vertices, the surrounding triangles are affected as well.
As far as I can see it, there are two options:
1) rebuild the mesh every time it is changed
2) use a different design for the terrain
I think that with the first approach, the terrain would require less triangles.

JA2	(Posted 2009) [#6]

I think it's possible to remove the corner triangles/quads and rebuild them with the centre line facing the other way. It's a bit beyond me to this to be honest. I'm kinda hoping someone will be able to help me with this.

I'm doing this to make quick simple terrains for a small game I'm working on. I've got it setup to texture each area based on slope and height so far, just need to fix this issue with the corner areas and I can move on.

Warner

(Posted 2009) [#7]

No, it is not possible to remove any triangles. Do do that, you need to clear the surface, and then rebuild it.
1. store all vertices/triangles in type
2. use ClearSurface
3. rebuild surface using AddVertex/AddTriangle

In your case, you need to UnWeld the terrain mesh, then turn the triangle, then Weld it again.
To turn the triangle, use the above method but redefine that specific triangle when your at step 3-rebuilding the surface.

Stevie G

(Posted 2009) [#8]

^^ 1. Just take a copy of the mesh and use this as a reference to re-build the mesh, deleting the copy once you're done. No need to store anything in types.

JA2	(Posted 2009) [#9]

I tried this for a few hours yesterday and a few more this morning. I thought I had it working but when the mesh is rebuilt with those triangles/quads facing the other direction, they get turned back to normal when the mesh is rebuilt on the next loop.

Anyway, I decided to change the way the mesh is built to begin with. Took me awhile to get it working but now the mesh is built out of hexagons instead, always giving an angled corner. Still low poly enough and looks quite good IMO.

Warner

(Posted 2009) [#10]

Great work. It looks good indeed.

big10p

(Posted 2009) [#11]

For some reason I cant see your images, JA2.

Anyway, one possible solution that occured to me is to create each mesh quad from 4 tris, instead of just 2, like so:

|--------|
|\      /|
| \    / |
|  \  /  |
|   \/   |
|   /\   |
|  /  \  |
| /    \ |
|/      \|
|--------|

This would let you deform the corners correctly without having to rebuild the mesh and turn triangles. You would also be able to choose sharp or rounded corners, as such a quad can be used to represent either, when deformed correctly.