bouncing

Blitz3D Forums/Blitz3D Programming/bouncing

Ben(t)

(Posted 2008) [#1]

How can i do it in blitz3d?

Matty

(Posted 2008) [#2]

http://blitzbasic.com/codearcs/codearcs.php?code=670

Ben(t)

(Posted 2008) [#3]

umm I feel dumb, how would i implement that code?

Charrua

(Posted 2008) [#4]

hi

any one gets in that state with vectors at first!

the dot product (this formula) if both vectors are normalized (have a length of 1) gives the asin of the angle between both vectors

if you know the angle that forms the way the ball is going respect of the face of the bodie wiht it has collided, then you can calculate the angle of going out.

That is the part of: NFx# = -2.0 * Nx# * VdotN# in each axis
(i dont analize the code totaly, but I supose that -2.0 is to get the reverse angle)

finally, sum the original motion vector (that your program keeps track?) to the calculated to obtain the new motion vector

Juan

note:
lenght as pitagoras say is sqrt(x*x + y*y + z*z)

(hope my traslation to english do not confuse, more than the vectors themselves)

Charrua

(Posted 2008) [#5]

Hi again
I keep bouncing with this question
last month i've done some research in the 3d maths and as a test I write some functions to work with vectors, that's the first real application that I have so, this is the code:

hope you enjoy

probably I've to put in the code archives (?)

;Autor Juan Odriozola
;Propósito: ver si entendí algo de vectores
;fuentes: <a href="http://blitzbasic.com/codearcs/codearcs.php?code=670" target="_blank">http://blitzbasic.com/codearcs/codearcs.php?code=670</a>

Type Punto
  Field X#
  Field Y#
  Field Z#
End Type


Type Vector
  Field x#
  Field y#
  Field z#
End Type

Local Temp, Luz, Camara, Plano, Espejo, Esfera, Entidad, VdotN#

Graphics3D 640,480,0,2

Temp = CreatePivot()
Luz = CreateLight()
PositionEntity Luz,-10,20,20
PointEntity Luz,Temp
Camara = CreateCamera()
PositionEntity Camara,-5,10,10
PointEntity Camara,Temp
FreeEntity Temp

Plano=CreatePlane()
EntityAlpha Plano,0.8
Local Textura
Textura=CreateTexture(128,128,9)
ClsColor 0,200,80
Cls
Color 255,255,255
Rect 0,0,64,64,1
Rect 64,64,64,64,1
CopyRect 0,0,128,128,0,0,BackBuffer(),TextureBuffer(Textura)
ScaleTexture Textura,20,20
EntityTexture Plano,Textura,0,0
Espejo=CreateMirror()

Esfera = CreateSphere()
PositionEntity Esfera,0,5,0
EntityColor Esfera, 255, 0,0

EntityType Plano,1
EntityType Esfera,2
Collisions 2,1,2,1

Global Normal.Vector = New Vector
Global Fuerza.Vector = New Vector
Global Movimiento.Vector = New Vector
Global Rebote#=0.5
Global VelocidadLineal#

Movimiento\x = -1
Movimiento\y = -3
Movimiento\z = -2

VelocidadLineal = Magnitud(Movimiento)
DebugLog "Velocidad Lineal: "+VelocidadLineal

;alineo la Esfera sobre el eje z, luego en el loop
;hago avanzar la esfera en ese eje.
AlignToVector Esfera,Movimiento\x,Movimiento\y,Movimiento\z,3

While Not KeyHit(1)
	
	Entidad = EntityCollided (Esfera,1)
	
	If  Entidad Then
		DebugLog "chocaron"
		Normal\x# = CollisionNX#(Entidad, 1) 
		Normal\y# = CollisionNY#(Entidad, 1) 
		Normal\z# = CollisionNZ#(Entidad, 1) 
		DebugLog "Normal: "+Normal\x+", "+Normal\y+", "+Normal\z
		
		; Compute the dot product of the ball's motion vector and the normal of the surface collided with. 
		VdotN = ProductoPuntual(Movimiento, Normal)
		DebugLog "arcoseno del angulo: "+VdotN+ ", angulo: "+ASin(VdotN)
		
		; Calculate the normal force.
		Fuerza = EscalarVector(Normal, -2.0 * VdotN)
		DebugLog "Fuerza normal: "+Fuerza\x+", "+Fuerza\y+", "+Fuerza\z
		
		; Add the normal force to the motion vector.
		Movimiento = SumarVectores(Fuerza,Movimiento)
		DebugLog "Nueva orientación: "+Movimiento\x+", "+Movimiento\y+", "+Movimiento\z
		Movimiento = EscalarVector(Movimiento,Rebote)
		DebugLog "Escalado segun factor de rebote: "+Movimiento\x+", "+Movimiento\y+", "+Movimiento\z
		AlignToVector Esfera,Movimiento\x,Movimiento\y,Movimiento\z,3
		VelocidadLineal = Magnitud(Movimiento)
		Entidad = 0
		
	End If
	
	MoveEntity Esfera,0,0,0.01*VelocidadLineal
	
	If KeyHit(57) Then
		Movimiento\y = -Movimiento\y
		VelocidadLineal = Magnitud(Movimiento)
		AlignToVector Esfera,Movimiento\x,Movimiento\y,Movimiento\z,3
		
	End If
	
	UpdateWorld
	RenderWorld
	
	Text 10,10, "Escape para salir, Espacio para cambiar sentido a la Esfera"
	
	Flip
Wend

End

End

;algunas rutinas utiles con vectores....
;

Function Magnitud#(V.Vector)	;devuelve un float y recibe un Type Vector
	Return Float(Sqr(V\x * V\x + V\y * V\y + V\z * V\z))
End Function

Function NormalizarVector.Vector(V.Vector)	;indico que devuelve un Type Vector y recibe un Type Vector
	Local Temp#
	Temp# = Float(1/Magnitud(V))
	V\x = V\x * Temp
	V\y = V\y * Temp
	V\z = V\z * Temp
	Return V
End Function

Function SumarVectores.Vector(v1.Vector, v2.Vector)
	Local v.Vector
	v.Vector = New Vector
	v\x = v1\x + v2\x
	v\y = v1\y + v2\y
	v\z = v1\z + v2\z
	Return v
End Function

Function RestarVectores.Vector(v1.Vector, v2.Vector)
	Local v.Vector
	v.Vector = New Vector
	v\x = v1\x - v2\x
	v\y = v1\y - v2\y
	v\z = v1\z - v2\z
	Return v
End Function

Function EscalarVector.Vector(v.Vector, s#)	;s>1 aumento, s<1 disminuyo, si negativo, cambio sentido
	v\x = v\x * s
	v\y = v\y * s
	v\z = v\z * s
	Return v
End Function


;ProductoPuntual = Magnitud(v1) * Magnitud(v2) * Cos(alfa), siendo alfa el ángulo entre ellos

Function ProductoPuntual#(v1.Vector, v2.Vector)
	Return ((v1\x * v2\x) + (v1\y * v2\y) + (v1\z * v2\z))
End Function


;ProductoCruzado de dos vectores, devuelve un vector que es perpendicular a ambos vectores.

Function ProductoCruzado.Vector(v1.Vector, v2.Vector)
	Local v.Vector
	v.Vector = New Vector
	v\x = (v1\y * v2\z) - (v1\z * v2\y)
	v\y = (v1\z * v2\x) - (v1\x * v2\z)
	v\z = (v1\x * v2\y) - (v1\y * v2\x)
	Return v
End Function

thank jv-ode for the floor (i stole from)
sorry, is in spanish, but the names are practically the same.

Rebote : gives the bouncing factor
VelocidadLineal: is afected (reduced if Rbote is less than 1) in each bounce.

the rest I think is self explanatory (??)

best regards

Juan

Axel Wheeler

(Posted 2008) [#6]

ben(t):

Bouncing can be easy or hard, depending on the complexity of the bouncing you want.

If you don't need to consider the shape of the bouncing object (i.e. a ball) AND the object it is hitting is flat and not moving (i.e. the floor or a wall) then you just need to:

1. Detect when the ball has passed into the wall (and how far) using collisions or your own checking.

2. Move the ball that same distance away from the wall and switch the sign of the speed in that direction (x,y, or z).

At the opposite extreme of complexity, for example if the bouncing object must rotate depending on where it is hit, you are probably better off with a physics engine like Tokamak.

The two approaches posted above by Matty and Charrua seem to be somewhere in the middle; the surface(s) are convoluted and you need to figure the new direction of the object(s), but not the new rotation speed.

That's three different scenarios with different solutions!

Hope this helps.

Charrua

(Posted 2008) [#7]

I agree,
I just try to explain the code refered by the link proposed, and forgot the purpose of the post, thank's axel!

Juan

Ben(t)

(Posted 2008) [#8]

Im still a little confused.
Im trying to do physics with balls that bounce by changing their pitch and yaw.
I know angle in equals angle out, but i dont know how to implement that in my code

Charrua

(Posted 2008) [#9]

hi

Ok, you have the pitch, yaw and roll of your ball, and probably you use moveentity ball,0,0,ForwardVel so it moves in the direction it faces.

You check for collisions, then, you get the normal: x,y,z wich you can translate to pitch, yaw and roll (see VectorYaw and VectorPitch), with this info, you can calculate the angle out.

Realign the ball and adjust ForwardVel according to the bouncing_factor you wish from the material of the ball and the object that has collided.

As Axel say, with this method, we only change direction and say nothing about angular velocity: the ball don't rotate relative to it's center due to the collisions.

Hope that helps

Juan