BlitzForest/Grass - Dense trees & grass rendering

Blitz3D Forums/Blitz3D Programming/BlitzForest/Grass - Dense trees & grass rendering

John J.

(Posted 2007) [#1]

Note: This is two of several libraries that have been sitting on my hard drive for about a year not being used (since I have moved on to my own C++ game engine [using Ogre]). I have decided to release a few of these libraries since can be very useful to many of you, I'm sure.

Download BlitzForest & BlitzGrass Here

BlitzForest Library:
BlitzForest enables you to place thousands, and literally tens of thousands of trees in your game with little performance penalty. Using 30 thousand, or even 50 thousand trees would not be too much for BlitzForest to handle. Even old video cards will be able to render up to 50,000 trees at relatively smooth frame rates. BlitzForest's only limitation is the required use of prop-style trees.

BlitzForest uses a complex optimization method, taking full advantage of minimal-surface renders, LOD optimization, batch loading and reprocessing, and occlusion.

What makes BlitzForrest so useful is not only it's features, but the fact that all these complex operations are done automatically! All you have to worry about is using the very simple commands of BlitzForrest, such as BF_PositionTree() and BF_LoadTree().

Even though initialization of BlitzForrest and LOD settings is easy, this is probably as hard as it gets when using BlitzForrest. Simply let BlitzForrest know what detail you want your trees displayed at, and at what relative scale your world is, and you're ready to go!

Features:
• Easy-to-use functions, which automatically take care of all optimizations transparently
• Automatically optimized loading procedures, offering unmatched loading speed with thousands of trees
• Automatic single and minimal-surface render optimizations for realtime display of thousands of trees
• Automatic level-of-detail (LOD) optimizations for amazing performance
• Optimal mesh regeneration and optimization system with possible realtime tree manipulation

BlitzGrass Library:
BlitzGrass provides you with an easy way to add infinite amounts of dense, realistic, and extremely fast grass to your Blitz3D world. BlitzGrass generates grass and adds it to your terrain automatically, additionally batching grass meshes for maximum performance. Since BlitzGrass uses a built-in paging system, there's no need to pre-load grass - everything is loaded as you move around in you're world. This means that you're world could be 1000 or 1000000 units long - it makes no difference to BlitzGrass.

Ricky Smith

(Posted 2007) [#2]

Very useful - Thanks !!

t3K|Mac

(Posted 2007) [#3]

whew. very nice. decent. great. i think i let my grassengine die and use yours ;)

IPete2

(Posted 2007) [#4]

thanks very much nice one

IPete2

Mikele

(Posted 2007) [#5]

Thanks John!

slenkar

(Posted 2007) [#6]

thanks! some great code there

jfk EO-11110

(Posted 2007) [#7]

These numbers sound really good. But two things: you should use a ground texture that disguises the grass quads bottom lines. Basicly a texture that has about the same hue and birghtness as the grass itself. This will make it look much better.

And 2nd a question: how does it handle alpha, is it sorting it, and how does sorting interact with other alpha objects in the scene?

John J.

(Posted 2007) [#8]

you should use a ground texture that disguises the grass quads bottom lines. Basicly a texture that has about the same hue and birghtness as the grass itself. This will make it look much better.

Well of course. Remember that the screenshots above and the demo are just for demonstration purposes - when I actually used this naturally I used a matching ground texture.

And 2nd a question: how does it handle alpha, is it sorting it, and how does sorting interact with other alpha objects in the scene?

The grass quads are not individually sorted, but each batch should be. This means that there will be some incorrect alpha, but hopefully not too much.

These numbers sound really good. But

I have used both the tree and grass system in my (canceled) BattleTanks III project, and I know for a fact that they run very well (about 90 FPS on a GeForce 5200 at moderate detail settings):

Vorderman

(Posted 2007) [#9]

That screenshot looks brilliant!

jfk EO-11110

(Posted 2007) [#10]

That's looking much better. I wish I had access to this before I added grass to my project. The one that I use utilizes CopyEntity. It's pretty fast, but a contingent of 3 thousand quads already has an obvious impact on the framerate of a "worst-case-rig" radeon 9200se.

Although, it's not only the number of tris and surfaces that makes the diffrence. The higher the grass (y-scale), the more the quads are overlapping onscreen, resulting a high number of alpha levels for the renderer. At the other hand: the lower the height of the grass, the more quads you need to cover the ground. It's a dilemma.

So what is the trick of your method that allows to render 10'000 on a 5200 without high costs?

John J.

(Posted 2007) [#11]

Although, it's not only the number of tris and surfaces that makes the diffrence. The higher the grass (y-scale), the more the quads are overlapping onscreen, resulting a high number of alpha levels for the renderer. At the other hand: the lower the height of the grass, the more quads you need to cover the ground. It's a dilemma.

So what is the trick of your method that allows to render 10'000 on a 5200 without high costs?

Like you mentioned, there are three major performance factors on a video card:
#1: Fill rate
#2: Batch count
#3: Polygon count

Notice that polygon count is the least important. On practically any video card past a GeForce 2, polygon count has become quite trivial in comparison to other factors (like batch count and fill rate).

Batch count refers to the number of individual draw calls Blitz3D (or whatever engine you use) has to make. By combining multiple objects into a single object, you can reduce the draw calls, even though the polygon count stays the same. This can lead to EXTREMELY high boosts of frame rate. For example, drawing 20,000 mesh trees individually on a GeForce 7800 GT barely runs at 1 FPS, while grouping them into ~20-30 batches runs at 150 FPS.

And often the most important (depending on the nature of your geometry) is fill rate. Like you mentioned, reducing the y-scale reduces the amount of pixels used by each grass quad, and therefore boosting performance. If you have a modern card, grass shouldn't be too much of a problem, but cards like a 5200 have terrible fill rates and really benefit from lower grass heights.

The only real way to avoid the fill rate bottleneck on older cards is to either scale down your grass, or possibly try alpha-rejection on your textures (called "masking" in Blitz3D). Alpha-rejection rejects transparent pixels from being unnecessarily processed from the pixel pipeline, which can help slightly (although I don't think Blitz3D allows both masking and alph at the same time).

So what is the trick of your method that allows to render 10'000 on a 5200 without high costs?

Batching and low y-scale. There's not much else you can do beyond that - at this point you've pretty much reached the limits of your hardware.

jfk EO-11110

(Posted 2007) [#12]

Open land as in your screenie is very hard to achieve. I am rather trying to design levels with a low camera range. For example, a canyon enviroment that allows rich vegetation at all times.

John J.

(Posted 2007) [#13]

Open land as in your screenie is very hard to achieve. I am rather trying to design levels with a low camera range. For example, a canyon enviroment that allows rich vegetation at all times.

You mean like this? (p.s. the trees are just placeholders - I know they look bad)

(View movie here)

I'm designing my current game engine to handle it all - dense swamplands, wide open grassy planes, mountainous forests, etc., :)

(I guess this is a little bit off topic, but I'm sure some of you are a little interested in why I'm giving my old code away ;) )

Fuller

(Posted 2007) [#14]

what did you make the trees in? I wish I could make better trees

John J.

(Posted 2007) [#15]

what did you make the trees in? I wish I could make better trees

I used Blender. The trees above are really very simple, just a square-ish trunk with a dome top textured with leaves.

msx123

(Posted 2007) [#16]

Xira engine is your new engine with c++?

Danny

(Posted 2007) [#17]

Thanks again John, this looks very cool! !!!!

semar

(Posted 2007) [#18]

Yup, very nice, thank you John for this really *good* tree library !

Sergio.

John J.

(Posted 2007) [#19]

Xira engine is your new engine with c++?

Yes, that's what I'm planning on calling it. It's actually more of a framework, so unfortunately I don't think I could port it to BlitzMax without converting the entire engine (though I probably could add my tree/grass system to something like Flow). When it's done it'll probably be more like Torque to the "casual" developer, but with a very powerful world/script editor and many advanced features like hardware grass animation, highly optimized 3D trees (for 50,000+ tree forests), splatting terrains, possibly dynamic tree destruction, portal occlusion, horizon occlusion (hopefully), full shader support + fallback system (since I'm using Ogre for rendering) etc. The demo used to make the screenshots/video above (10,000 trees, animated grass, 50 physically simulated boxes) runs at ~300 FPS on a Gf7800, and ~30 FPS on a Gf5200.

Naughty Alien

(Posted 2007) [#20]

John, how to place this grass chunks on to mesh terrain?? There is no specific BG command for positioning...

John J.

(Posted 2007) [#21]

John, how to place this grass chunks on to mesh terrain?? There is no specific BG command for positioning...

You don't specifically position the grass. Instead you first add a grass layer (which appears everywhere), then apply a grassmap. The grassmap should be a greyscale image just like your heightmap, but instead of setting terrain height, the grassmap sets grass density.

P.S. I'm not sure if the grass map functions are working 100% - I think the axes might be inverted or swapped. Also, the grass map isn't smoothed, so the grass densities may appear in blocks. This is the one section of BlitzGrass that I never finished (and unfortunately, I probably don't have enough time to finish it now due to other projects).

Naughty Alien

(Posted 2007) [#22]

yes..that should be fine with terraing made from bitmap, but what about mesh terrains?? How to use gras system with with mesh terrains?

John J.

(Posted 2007) [#23]

How to use gras system with with mesh terrains?

In this case you'll have to create you're own MeshTerrainY() function that operates similarly to Blitz3D's TerrainY() and change the TerrainY() calls in BlitzGrass to MeshTerrainY() (or whatever).

Nexus6

(Posted 2007) [#24]

John, dont know if I'm doing something wrong or not but I can't seem to get the grass system to work with a grassmap, it just ignores it and places the grass all over the grass layer.
In fact, you've commented out the grassmap function in your demo.
Any idea's what i might be doing wrong or what might be wrong with the grassmap function.

John J.

(Posted 2007) [#25]

Nexus6: I'm not sure why that's happening, but like I said the grassmap feature wasn't finished, and I probably don't have time to finish this when I already have a much nicer grass system working in C++.

Hopefully the grass library will at least provide a good starting point for anyone who needs it (although the tree system should be 100% working).

P.S. If you're "fluent" in C++, my latest project might be helpful here (especially GrassLoader.cpp), since it's density/color map features are complete.

Tom	(Posted 2007) [#26]

Nice stuff John! That pic above is pretty, but tell me, can we have the StickyBoulderOnSlope code too? :P

Mortiis

(Posted 2007) [#27]

Great system thanks! Is it possible to implement it into a world editor to put grass in certain places? I don't ask you to do it but is it just possible? :)

Svenart

(Posted 2007) [#28]

this is really great, thank you very much. Can anyone tell my how I can load treemeshes instead of images?

John J.

(Posted 2007) [#29]

this is really great, thank you very much. Can anyone tell my how I can load treemeshes instead of images?

BlitzForest isn't capable of doing that, unfortunately.

Is it possible to implement it into a world editor to put grass in certain places? I don't ask you to do it but is it just possible? :)

With grassmaps it is, but like I said above I don't think the grassmap support included is fully working.

On these lines:

		xp# = Rnd(x - BG_BlockSize, x + BG_BlockSize)
		zp# = Rnd(z - BG_BlockSize, z + BG_BlockSize)
		
		Density = BG_sysArrayGet(em\GrassMap, scl*xp, scl*zp)
		If Rand(0, 255) < Density Then

If you set Density to a value between 0 and 255, depending on how dense you want the grass at (xp, zp), you should be able to have full control over the density.

Nice stuff John! That pic above is pretty, but tell me, can we have the StickyBoulderOnSlope code too? :P

You mean the soft-edged minimap? :D

Tom	(Posted 2007) [#30]

/me rubs eyes.. so it is! :P

Rick Nasher

(Posted 2014) [#31]

Anybody ever got this(the grassmap system) to work with a BlitzTerrain?'

Appears John J was right about it not being 100% OK cos I noticed the grass is partially rendering off the map and gives an "offset out of range" error.

Rick Nasher

(Posted 2014) [#32]

This screenshot demonstrates the grass on terrain:

And this one where things go wrong(no longer getting the "offset out of range" error anymore though):

For anybody who doesn't have the BlitzForrest/BlitzGrass (I see the links are dead),
here's a download link for the original package with my addapted code(GrassyTerrain TryOut.bb) and some media included.

Help on this one is greately appreciated.

RemiD

(Posted 2014) [#33]

What do you want exactly ?

Do you want to prevent the grass meshes to be positioned outside of the terrain ?
Do you use a Blitz3d terrain or a custom mesh terrain ?

Rick Nasher

(Posted 2014) [#34]

Indeed, it's running out of bounds, probably because of the positioning and as John J. mentioned above:

"P.S. I'm not sure if the grass map functions are working 100% - I think the axes might be inverted or swapped. Also, the grass map isn't smoothed, so the grass densities may appear in blocks. This is the one section of BlitzGrass that I never finished (and unfortunately, I probably don't have enough time to finish it now due to other projects)."

I'm using a standard Blitz3d terrain, scaled 8x200x8, that I've included in the above download.

RemiD

(Posted 2014) [#35]

I don't have time to read the code but what i would do to have a lot of grass on a terrain is to use a colormap to texture the terrain and use a specific color for the grass.
Then use a system similar to a single surface particle system to position the grass meshes around the player, and use the same specific color for the grass texture. This way it should produce the illusion of unlimited grass.
You can also use several shades of green to make sure the different grass meshes are visible.

Also about grass on terrain, you may be interested in the example "Blitz3D\samples\AGore\GrassDemo"

Good luck.

Rick Nasher

(Posted 2014) [#36]

Yeah I know how to do it in theory but getting to run as fast and smooth as in BlitzGrass is something else. Weirdly enough the GrassDemo you suggested is giving me MAV's on loading textures and sprites with alpha flags set. Perhaps an extension(fastext?) playing tricks on me.

Rick Nasher

(Posted 2014) [#37]

Found the culprit: ClearTextureFilters

disabled it and go.

Rick Nasher

(Posted 2014) [#38]

Nevertheless: not nearly as good(fast) as the BlitzGrass thing unfortunately. I don't need a whole lot of grass, I just need it in patches on some places, therefore a grassmap would be more flexible and useable. Thanks anyway.

Hotshot2005

(Posted 2014) [#39]

There was TREE and Grass party for Blitzbasic but now it is on sale for Darkbasic pro only I think

Rick Nasher

(Posted 2014) [#40]

Yeah I know, that's why I'm after the previous version: BlitzGrass, but it's bugged unfortunately.

Rick Nasher

(Posted 2014) [#41]

Hi all,

I was doing my own grass thing, then I stumbled upon this one, which seems pretty brilliant: Grass on a landscape (lite version) by Matt Merkulov

I modified it so one can load their own terrain or use the in-build procedural terrain as in the original, and made it a bit more modular. Future enhancements would be: custom bush models and a grass/bush map.

Works great sofar but, I would now also like to load 3D models for the bushes to create a more diverse plantlife and flexibility. I'm attempting to do this by using below line instead of the in-build procedural bush:

m=LoadMesh("Plant Imperata N300813.3DS") ; <<< causes MAV later in program.

But I'm gettting a MAV in CreateBushes() function on(even though it can load the model successfully) on this line:

AddMesh m2, m ; <<< fails w MAV if BusModel contains Loaded Mesh?

;Grass rendering algorhytm by Matt Merkulov
;Adapted to suit loaded heightmaps/texturing and allow larger scaling.
;Modularized.
;
;To Do: 
;- abillity to load custom 3d grass/bush models.
;- grass/bush map.
;
;Bugs: MAV on using custom loaded 3d grass/bush model.

.Initialise_Vars
SeedRnd MilliSecs() 


Global ProceduralGfx=True ; set to use in-build terrain generation.


Global LandscapeSize = 512 ;256 ; will change aftr LoadLandscape
Global DitheringTextureSize = 512
Global DitheringTextureScale = 4
;Global LandscapeSizeMask=LandscapeSize - 1
Global LandscapeHeight# = 200; 32
Global LandscapeSizeScale#=8 ;things go wrong soon as above 1, crashes at 8
Global LandscapeSizeMask# = (LandscapeSize * LandscapeSizeScale) - 1 ;


Global GrassColor = 100
Global GrassDColor = 20
Global GrassBackground = 100
Global MaxGrassSpreadingRadius# = 0.72

Dim GreenMapColor(GreenMapSize,GreenMapSize) ; added 


Global BushesThreshold# = -0.01;displays also below waterline ; -0.05 ;0.28
Global MaxBushesThreshold# = 0.34

Global BushTypesQuantity = 2
Global BushModelsQuantity = 2
Global BushTextureSize = 256

Global BushModelScaleMin# = 0.3
Global BushModelScaleMax# = 0.6

;Used for procedural terrain
Global SandThreshold# = 0.3
Global HillsMinRadius = 16
Global HillsMaxRadius = 64 
Global HillsMinHeight# = 0.2
Global HillsMaxHeight# = 1.0 
Global HillsQuantity# = 100


Global PlayerHeight# = 1.5
Global PlayerSpeedPerSecond# = 10.0;*2
Global PlayerTurnPerSecond# = 180.0
Global PlayerX#
Global PlayerZ#

Global FadingTimeInSeconds# = 1.0
Global MaxAlpha# = 1.0
Global FadingIn = 1, FadingOut = 2 


;Small grass quadrants - smooth, but slow grass rendering
Global GrassGridCellSize# = 2.0  * LandscapeSizeScale
Global BushesQuantityPerSquare = 12
Global GrassRadiusInSquares# = 8


;Largel grass quadrants - jerky, but fast grass rendering
;Global GrassGridCellSize# = 8.0
;Global BushesQuantityPerSquare = 192
;Global GrassRadiusInSquares# = 2


Global GrassGridSize = LandscapeSize * LandscapeSizeScale/ GrassGridCellSize#
Global BushTextureXTexSize# = 1.0 / BushTypesQuantity
Global BushTextureYTexSize# = 1.0 / BushModelsQuantity
Global GrassRadius# = GrassRadiusInSquares# * GrassGridCellSize#

Global Skybox	

Global screenwidth=1270, screenheight=720, screenmidx=screenwidth/2 , screenmidy=screenheight/2
Graphics3D screenwidth, screenheight,32

Global Camera = CreateCamera()
;CameraRange Camera,0.2,1300 
CameraRange Camera,0.2,2300 
ScaleEntity Camera, 0.3, 0.3, 0.3
PositionEntity Camera, LandscapeSize / 2, 100, LandscapeSize / 2
;RotateEntity Camera, 45, 0, 0
CameraFogMode camera,1
;CameraFogColor camera,140,140,120
CameraFogColor camera,240,240,220
;CameraFogColor camera,0,0,256
CameraFogRange camera,1,1000



RotateEntity CreateLight(), 45, 45, 0
Global mvx#,mvy#,mvz#,targetpitch#,targetyaw# ; for camcontrols

Type ActiveSquare
	Field X, Z, JustAdded
End Type

Type FadingBush
	Field Alpha#, FadingMode, X, Z
End Type

Dim ServiceMap(LandscapeSize, LandscapeSize)
Global VisibleActiveSquare = %11
Global InvisibleActiveSquare = %10
Global VisibleSquare = %01
Global InvisibleSquare = %00
Global Visibility = %01
Global Activity = %10

Dim BushModel(BushTypesQuantity - 1, BushModelsQuantity - 1)
Dim BushQuantityMap#(GrassGridSize - 1, GrassGridSize - 1)
Dim BushMap(GrassGridSize - 1, GrassGridSize - 1)
Dim BushFader.FadingBush(GrassGridSize - 1, GrassGridSize - 1)
Global m,m2 ;makes no difference


;Global Landscape = CreateTerrain(LandscapeSize)
Global LandscapeTexture = CreateTexture(LandscapeSize, LandscapeSize, 15) ;procedural
Global LandscapeDitheringTexture = CreateTexture(DitheringTextureSize, DitheringTextureSize, 15)
Global Grass = CreateTexture(BushTextureSize * BushTypesQuantity, BushTextureSize * BushModelsQuantity, 13)

.Setup
;ScaleEntity Landscape,LandscapeSizeScale# , LandscapeHeight#, LandscapeSizeScale#


;CreateLandscape ;procedural
Global Landscape ; = CreateTerrain(LandscapeSize)




If ProceduralGfx=True
	LandscapeSizeScale#=1 : LandscapeHeight#=32 : BushesThreshold# = 0.28:MaxBushesThreshold# = 1.0

    Landscape = CreateTerrain(LandscapeSize)
	CreateLandscape ; Create procedural terrain.
	ScaleEntity Landscape,LandscapeSizeScale# , LandscapeHeight#, LandscapeSizeScale#
	PaintTextures() ; Paint the actual texture created with PaintLandscape()
Else
	LoadLandscape()
	ScaleEntity Landscape,LandscapeSizeScale# , LandscapeHeight#, LandscapeSizeScale#
	LoadLandscapeTexture() ;Nogo,why? Needed data from above functions first, now is go.
EndIf
;BB=LoadMesh("Plant Imperata N300813.3DS")
;PositionEntity BB,10,10,10



CreateBushes()

TryToAddSquare EntityX(Camera) / GrassGridCellSize#, EntityZ(Camera) / GrassGridCellSize#


Global qua ; used for displaying active square#
Global PrevFrameRenderingTimeInSeconds#

; Additional Scenery
If ProceduralGfx=False
	CreateWater()
	MakeSkybox()
EndIf


.MainLoop
Repeat

	If KeyDown(200) Or KeyDown(208) Or KeyDown(203) Or KeyDown(205) <>0
		MoveEntity Camera, 0, 0, PrevFrameRenderingTimeInSeconds# * PlayerSpeedPerSecond# * (KeyDown(200) - KeyDown(208))
		TurnEntity Camera, 0, PrevFrameRenderingTimeInSeconds# * PlayerTurnPerSecond# * (KeyDown(203) - KeyDown(205)), 0
	Else 
	 	MouseTurn2(Camera)
	EndIf
	

	PlayerX# = EntityX(Camera)
	PlayerZ# = EntityZ(Camera)
	PositionEntity Camera, PlayerX#, TerrainY#(Landscape, PlayerX#, 0, PlayerZ#) + PlayerHeight#, PlayerZ#
	If ProceduralGfx=False
		PositionEntity Skybox,EntityX(Camera),EntityY(Camera),EntityZ(Camera) 
	EndIf
	FrameBeginningTime = MilliSecs()



UpdateBush()

;	SetBuffer TextureBuffer(LandscapeTexture)

;	qua = 0
;	For S.ActiveSquare=Each ActiveSquare
;		tmp = ServiceMap(S\X, S\Z)
;		If (ServiceMap(S\X, S\Z) And Activity) = Activity And S\JustAdded Then
;		 	Delete S
;		Else
;			S\JustAdded = False
;			Dist# = EntityDistance(BushMap(S\X, S\Z), Camera)
;			;Stop
;			If Dist# > GrassRadius# Then
;				If (ServiceMap(S\X, S\Z) And Visibility) = VisibleSquare Then
;					ExpandSquare S
;					If Paint Then WritePixel S\X * GrassGridCellSize#, S\Z * GrassGridCellSize#, $FF00FFFF
;					If BushMap(S\X, S\Z) Or GrassMethod = MethodHide Then
;						If BushFader(S\X, S\Z) <> Null Then
;							FB.FadingBush = BushFader(S\X, S\Z)
;						Else
;							FB.FadingBush = New FadingBush
;							FB\X = S\X
;							FB\Z = S\Z
;							FB\Alpha# = MaxAlpha#
;							BushFader(S\X, S\Z) = FB
;						End If
;						FB\FadingMode = FadingOut
;					End If
;					ServiceMap(S\X, S\Z) = InvisibleActiveSquare
;				Else
;					If CountNeighbors(S, VisibleSquare) = 0 Then
;						ServiceMap(S\X, S\Z) = InvisibleSquare
;						Delete S
;					Else
;						ServiceMap(S\X, S\Z) = InvisibleActiveSquare
;					End If
;				End If
;			Else
;				If (ServiceMap(S\X, S\Z) And Visibility) = InvisibleSquare Then
;					ExpandSquare S
;					If Paint Then WritePixel S\X * GrassGridCellSize#, S\Z * GrassGridCellSize#, $FFFF0000
;					ServiceMap(S\X, S\Z) = VisibleActiveSquare
;					S\JustAdded = False
;					ShowEntity BushMap(S\X, S\Z)
;					If BushFader(S\X, S\Z) <> Null Then
;						FB.FadingBush = BushFader(S\X, S\Z)
;					Else
;						FB.FadingBush = New FadingBush
;						FB\X = S\X
;						FB\Z = S\Z
;						FB\Alpha# = 0.0
;						BushFader(S\X, S\Z) = FB
;					End If
;					FB\FadingMode = FadingIn
;				Else
;					If CountNeighbors(S, InvisibleSquare) = 0 Then
;						ServiceMap(S\X, S\Z) = VisibleSquare
;						Delete S
;					Else
;						ServiceMap(S\X, S\Z) = VisibleActiveSquare
;					End If
;				End If
;			End If
;		End If
;	Next

;	DFading# = PrevFrameRenderingTimeInSeconds# / FadingTimeInSeconds#
;	For FB.FadingBush = Each FadingBush
;		A# = FB\Alpha#
;		If FB\FadingMode = FadingIn Then
;			A# = A# + DFading#
;			If A# > MaxAlpha# Then A# = MaxAlpha#
;			FB\Alpha# = A#
;			EntityAlpha BushMap(FB\X, FB\Z), A#
;			If A# = MaxAlpha# Then Delete FB
;		Else
;			A# = A# - DFading#
;			If A# < 0.0 Then A# = 0.0
;			FB\Alpha# = A#
;			EntityAlpha BushMap(FB\X, FB\Z), A#
;			If A# = 0.0 Then
;				HideEntity BushMap(FB\X, FB\Z)
;				BushFader(FB\X, FB\Z) = Null
;				Delete FB
;			End If
;		End If
;	Next
;
;	For S.ActiveSquare=Each ActiveSquare
;		qua = qua + 1
;	Next

;	SetBuffer BackBuffer()


	RenderWorld

	;Stop

	If FPSCounterResetTime <= MilliSecs() Then
		FPSCounterResetTime = MilliSecs() + 1000
		FPS = FPSCounter
		FPSCounter = 0
	Else
		FPSCounter = FPSCounter + 1
	End If
	Text 0, 0, "Frames / sec:" + FPS + ", activesquares: " + qua

	Flip

	PrevFrameRenderingTimeInSeconds# = 0.001 * (MilliSecs() - FrameBeginningTime)
Until KeyHit(1)

For X = 0 To GrassGridSize - 1
	For Y = 0 To GrassGridSize - 1
		If BushMap(X, Y) Then FreeEntity BushMap(X, Y)
	Next
Next

FreeEntity Landscape
FreeTexture LandscapeTexture
FreeTexture LandscapeDitheringTexture

Function CreateLandscape()
	SetBuffer FrontBuffer()
	Text 0, 0, "Generating landscape..."
	For n = 1 To HillsQuantity
		HillRadius = Rnd(HillsMinRadius, HillsMaxRadius)
		HillX = Rand(0, LandscapeSize)
		HillY = Rand(0, LandscapeSize)
		HillHeight# = Rnd(HillsMinHeight#, HillsMaxHeight#)

		If -HillRadius < -HillX Then DXFrom = -HillX Else DXFrom = -HillRadius
		If HillRadius > LandscapeSize - HillX Then DXTo = LandscapeSize - HillX - 1 Else DXTo = HillRadius
		If -HillRadius < -HillY Then DYFrom = -HillY Else DYFrom = -HillRadius
		If HillRadius > LandscapeSize - HillY Then DYTo = LandscapeSize - HillY - 1 Else DYTo = HillRadius

		For DY = DYFrom To DYTo
			For DX = DXFrom To DXTo
				X = HillX + DX
				Y = HillY + DY
				K# = Sqr(DX * DX + DY * DY) / HillRadius
				If K# > 1.0 Then K# = 1.0
				Height# = 0.5 * (1.0 + Cos(180.0 * K#)) * HillHeight# * HillRadius / 64
				If Height# > TerrainHeight#(Landscape, X, Y) Then ModifyTerrain Landscape, X, Y, Height#
			Next
		Next
	Next
	
	

	SetBuffer FrontBuffer()
	Text 0, 10, "Painting landscape..."
	SetBuffer TextureBuffer(LandscapeTexture)
	For Y = 0 To LandscapeSize - 1
		For X = 0 To LandscapeSize - 1
			If TerrainHeight#(Landscape, X, Y) > SandThreshold# Then
				WritePixel X, Y, $FF00FF00
			Else
				WritePixel X, Y, $FFFFFF00
			End If
		Next
	Next
End Function

Function PaintTextures()
	ScaleTexture LandscapeTexture, LandscapeSize, -LandscapeSize
	TerrainShading Landscape, True

	ScaleTexture LandscapeDitheringTexture, DitheringTextureScale, DitheringTextureScale
	SetBuffer TextureBuffer(LandscapeDitheringTexture)
	For Y = 0 To DitheringTextureSize
		For X = 0 To DitheringTextureSize
			WritePixel X, Y, (Rand(96,160) * $010101) Or $FF000000
		Next
	Next

	EntityTexture Landscape, LandscapeDitheringTexture
	EntityTexture Landscape, LandscapeTexture, 0, 1
	TextureBlend LandscapeTexture, 2
End Function

Function CreateBushes()
	;SetBuffer BackBuffer()
	SetBuffer FrontBuffer()
	Text 0, 20, "Painting textures..."

	SetBuffer TextureBuffer(Grass) ; create original bushtexture image (can use another source her
	For Y = 0 To BushTextureSize * BushTypesQuantity - 1
		For X = 0 To BushTextureSize * BushModelsQuantity - 1
			WritePixel X, Y, 256 * GrassBackground ;color set in var
		Next
	Next

	For n1 = 0 To BushTypesQuantity - 1
		For n2 = 0 To BushModelsQuantity - 1
			
			m = CreateMesh()
			s = CreateSurface(m) ; s is a surface of mesh m
			
			
			If n1 = 0 Then  ;bushtype 1, paint texture on surface s
				For nn = 1 To 100 + n2 * 100
					Radius# = Rnd(BushTextureSize / 2, BushTextureSize)
					X = BushTextureSize * (Rnd(0,1) ^ 2 * (Rand(0, 1) * 2 - 1) + 1) * 0.5
					Repeat
						Angle# = Rnd(70, 110)
						X2 = Cos(Angle#) * Radius# + X
						Y2 = BushTextureSize - 1 - Sin(Angle#) * Radius# + n2 * BushTextureSize
					Until X2 >=0 And X2 < BushTextureSize
					For DeltaX = -3 To 3 ; create grass strands of bush1
						If ProceduralGfx=True Then ; make differnt color better suiting the landscape.
							;Color 30, GrassColor + DeltaX * GrassDColor-30, 50
							Color 0, GrassColor + DeltaX * GrassDColor, 0

						Else ; use the color without DeltaX and GrassDColor cos I've set them to 0 so can control more directly while debugging.
						     ; restore line below when done and introduce UnProceduralGrassDColor etc..
							;Color 232, GrassColor + DeltaX * GrassDColor+249, 189
							Color 232,  249+Rnd(0,10), 189
						EndIf

						Line X + DeltaX, (n2 + 1) * BushTextureSize - 1, X2, Y2
					Next
				Next
				;create bush 1 quads
				For nn= 0 To 7 ; Create 8 Quads (using surface s, previously painted)per bush?
					Angle# = nn * 45
					;CreateQuad s, Cos(Angle# - 45), Sin(Angle# - 45), Cos(Angle# + 45), Sin(Angle# + 45), Cos(Angle#) * 0.75, Sin(Angle#) * 0.75
					CreateQuad s, Cos(Angle#) * 0.5, Sin(Angle#) * 0.5, -Cos(Angle#) * 0.5, -Sin(Angle#) * 0.5, n1, n2, Cos(Angle# + 90), Sin(Angle# + 90)
				Next
				
				
			
			Else ;n2<>0 bushtype 2, paint texture on surface s

				For nn = 1 To 150 + n2 * 150
					X = Rnd(BushTextureSize * 2 / 5, BushTextureSize * 3 / 5) + BushTextureSize
					Angle# = Rnd(10, 170)
					Radius# = Rnd(0, 1) * (1 - Abs(angle - 90) / 133) *  BushTextureSize
					X2 = Cos(Angle#) * Radius# + BushTextureSize / 2 + BushTextureSize
					Y2 = (n2 + 1) * BushTextureSize - 1 - Sin(Angle#) * Radius# 
					For DeltaX = -3 To 3
						If ProceduralGfx=True Then ; make differnt color better suiting the landscape.
							Color 0, GrassColor  + DeltaX * GrassDColor, 0
							;Color 0, GrassColor + DeltaX * GrassDColor, 0
						Else
							
							;Color 218, GrassColor + DeltaX * GrassDColor+252, 127
							Color 218, 252+Rnd(0,10), 127
				
						EndIf
						Line X + DeltaX, (n2 + 1) * BushTextureSize - 1, X2, Y2
					Next
				Next
				
				;create bush 2 quads
				For nn = 0 To 3 ; create 4 quads s using above texture.
					Angle# = nn * 45
					xx# = Cos(Angle#)
					yy# = Sin(Angle#)
					CreateQuad s, xx#, yy#, -xx#, -yy#, n1, n2
				Next
				
				
			End If	
			
			; Instead of above in-code creation of bush entity LoadMesh
	        m=LoadMesh("Plant Imperata N300813.3DS") ;<<< causes MAV later in program, put a ':' before these 2 lines in order for it to run without error.
			ScaleMesh m,0.5,0.5,0.5 
			
			
			
			BushModel(n1, n2) = m ;fill aray BushModel(n1,n2) with mesh m
			HideEntity m

			
		Next
		
	Next

	SetBuffer FrontBuffer()
	Color 255, 255, 255
	Text 0, 30, "Generating grass squares (it might take some more time)..."

	;Create Grassgrid(put bushes created above onto an area of predetermined size

	For Z = 0 To GrassGridSize - 1 ; create grass grid of preset size
		For X = 0 To GrassGridSize - 1
			m = CreateMesh()
			EX# = X * GrassGridCellSize#
			EZ# = Z * GrassGridCellSize#
			EH# = TerrainY(Landscape, EX#, 0, EZ#) ;Landscape TerrainY(height) at
			

			
			For n3 = 1 To BushesQuantityPerSquare  ; creating bushes of preset quantity

				Repeat
					DX# = Rnd(-MaxGrassSpreadingRadius#, MaxGrassSpreadingRadius#)
					DZ# = Rnd(-MaxGrassSpreadingRadius#, MaxGrassSpreadingRadius#)
					If  Sqr(DX# * DX# + DZ# * DZ#) <= MaxGrassSpreadingRadius# Then
						LX# = DX# * GrassGridCellSize# + EX#
						LZ# = DZ# * GrassGridCellSize# + EZ#
						LH# = TerrainY(Landscape, LX#, 0, LZ#)
						DH# = LH# - EH#

						Height# = LH# / LandscapeHeight# ; devided by scale so getting to use with %?
						If Height# > BushesThreshold#  And Height# < MaxBushesThreshold# Then ;And mapcolor=green1  Then   
							Quantity# = 1.0 * (Height# - BushesThreshold#) / (MaxBushesThreshold# - BushesThreshold#)
							If Rnd(1) < Quantity# Then
								m2 = CopyMesh(BushModel(Rand(0, BushTypesQuantity - 1), Rand(0, BushModelsQuantity - 1)))
								SXZ# = Rnd(BushModelScaleMin#, BushModelScaleMax#)
								SY# = Rnd(BushModelScaleMin#, BushModelScaleMax#)
								DY1# = TerrainY(Landscape, LX# + 1.0, 0, LZ#) - LH#
								DY2# = TerrainY(Landscape, LX#, 0, LZ# + 1.0) - LH#
								
								AlignToVector m2, -DY1#, 1.0, -DY2#, 2
								RotateMesh m2, 0, Rnd(0,359), 0
								ScaleMesh m2, SXZ#, SY#, SXZ#
								
								s = GetSurface(m2, 1)
								For n = 0 To CountVertices(s) - 1
									VertexNormal s, n, 0, 1, 0
								Next
								
								RotateMesh m2, EntityPitch(m2), EntityYaw(m2) , EntityRoll(m2)
								PositionMesh m2, DX# * GrassGridCellSize#, DH#, DZ# * GrassGridCellSize#
								AddMesh m2, m ; <<< fails w MAV if BusModel contains Loaded Mesh..??
								FreeEntity m2
							End If
						End If
						Exit
					End If
				Forever
			Next
			BushMap(X, Z) = m
			PositionEntity m, EX#, EH#, EZ#
			EntityFX m, 16
			EntityTexture m, Grass
			HideEntity m
			EntityAlpha m, 0.0
		Next
	Next

	For n1 = 0 To BushTypesQuantity - 1
		For n2 = 0 To BushModelsQuantity - 1
			FreeEntity BushModel(n1, n2)
		Next
	Next
End Function

Function CreateQuad(Surface, X1#, Y1#, X2#, Y2#, XTex#, YTex#, DX# = 0, DY# = 0)
	XTex# = XTex# * BushTextureXTexSize#
	YTex# = YTex# * BushTextureYTexSize#
	v1 = AddVertex(Surface, X1#, 0, Y1#, XTex#, YTex# + BushTextureYTexSize#)
	v2 = AddVertex(Surface, X1# + DX#, 1, Y1# + DY#, XTex#, YTex#)
	v3 = AddVertex(Surface, X2# + DX#, 1, Y2# + DY#, XTex# + BushTextureYTexSize#, YTex#)
	v4 = AddVertex(Surface, X2#, 0, Y2#, XTex# + BushTextureYTexSize#, YTex# + BushTextureYTexSize#)
	AddTriangle Surface, v1, v2, v3
	AddTriangle Surface, v3, v4, v1
End Function

Function TryToAddSquare(X, Z)
	S.ActiveSquare = New ActiveSquare
	S\X = X
	S\Z = Z
	S\JustAdded = True
End Function

Function ExpandSquare(S.ActiveSquare)
	If S\X > 0 Then TryToAddSquare S\X - 1, S\Z
	If S\X < GrassGridSize - 1 Then TryToAddSquare S\X + 1, S\Z
	If S\Z > 0 Then TryToAddSquare S\X, S\Z - 1
	If S\Z < GrassGridSize - 1 Then TryToAddSquare S\X, S\Z + 1
End Function

Function CountNeighbors(S.ActiveSquare, NeighborType)
	If S\X > 0 Then If (ServiceMap(S\X - 1, S\Z) And Visibility) = NeighborType Then SquaresQuantity = SquaresQuantity + 1
	If S\X < GrassGridSize - 1 Then If (ServiceMap(S\X + 1, S\Z) And Visibility) = NeighborType Then SquaresQuantity = SquaresQuantity + 1
	If S\Z > 0 Then If (ServiceMap(S\X, S\Z - 1) And Visibility) = NeighborType Then SquaresQuantity = SquaresQuantity + 1
	If S\Z < GrassGridSize - 1 Then If (ServiceMap(S\X, S\Z + 1) And Visibility) = NeighborType Then SquaresQuantity = SquaresQuantity + 1
	Return SquaresQuantity
End Function


Function UpdateBush()

	SetBuffer TextureBuffer(LandscapeTexture)

	qua = 0
	For S.ActiveSquare=Each ActiveSquare
		tmp = ServiceMap(S\X, S\Z)
		If (ServiceMap(S\X, S\Z) And Activity) = Activity And S\JustAdded Then
		 	Delete S
		Else
			S\JustAdded = False
			Dist# = EntityDistance(BushMap(S\X, S\Z), Camera)
			;Stop
			If Dist# > GrassRadius# Then
				If (ServiceMap(S\X, S\Z) And Visibility) = VisibleSquare Then
					ExpandSquare S
					If Paint Then WritePixel S\X * GrassGridCellSize#, S\Z * GrassGridCellSize#, $FF00FFFF
					If BushMap(S\X, S\Z) Or GrassMethod = MethodHide Then
						If BushFader(S\X, S\Z) <> Null Then
							FB.FadingBush = BushFader(S\X, S\Z)
						Else
							FB.FadingBush = New FadingBush
							FB\X = S\X
							FB\Z = S\Z
							FB\Alpha# = MaxAlpha#
							BushFader(S\X, S\Z) = FB
						End If
						FB\FadingMode = FadingOut
					End If
					ServiceMap(S\X, S\Z) = InvisibleActiveSquare
				Else
					If CountNeighbors(S, VisibleSquare) = 0 Then
						ServiceMap(S\X, S\Z) = InvisibleSquare
						Delete S
					Else
						ServiceMap(S\X, S\Z) = InvisibleActiveSquare
					End If
				End If
			Else
				If (ServiceMap(S\X, S\Z) And Visibility) = InvisibleSquare Then
					ExpandSquare S
					If Paint Then WritePixel S\X * GrassGridCellSize#, S\Z * GrassGridCellSize#, $FFFF0000
					ServiceMap(S\X, S\Z) = VisibleActiveSquare
					S\JustAdded = False
					ShowEntity BushMap(S\X, S\Z)
					If BushFader(S\X, S\Z) <> Null Then
						FB.FadingBush = BushFader(S\X, S\Z)
					Else
						FB.FadingBush = New FadingBush
						FB\X = S\X
						FB\Z = S\Z
						FB\Alpha# = 0.0
						BushFader(S\X, S\Z) = FB
					End If
					FB\FadingMode = FadingIn
				Else
					If CountNeighbors(S, InvisibleSquare) = 0 Then
						ServiceMap(S\X, S\Z) = VisibleSquare
						Delete S
					Else
						ServiceMap(S\X, S\Z) = VisibleActiveSquare
					End If
				End If
			End If
		End If
	Next

	DFading# = PrevFrameRenderingTimeInSeconds# / FadingTimeInSeconds#
	For FB.FadingBush = Each FadingBush
		A# = FB\Alpha#
		If FB\FadingMode = FadingIn Then
			A# = A# + DFading#
			If A# > MaxAlpha# Then A# = MaxAlpha#
			FB\Alpha# = A#
			EntityAlpha BushMap(FB\X, FB\Z), A#
			If A# = MaxAlpha# Then Delete FB
		Else
			A# = A# - DFading#
			If A# < 0.0 Then A# = 0.0
			FB\Alpha# = A#
			EntityAlpha BushMap(FB\X, FB\Z), A#
			If A# = 0.0 Then
				HideEntity BushMap(FB\X, FB\Z)
				BushFader(FB\X, FB\Z) = Null
				Delete FB
			End If
		End If
	Next

	For S.ActiveSquare=Each ActiveSquare
		qua = qua + 1
	Next
	
	SetBuffer BackBuffer()
End Function

Function LoadLandscape()
		Landscape=LoadTerrain( "blitzhmp512(2a).png" ) ;512x512x256 heightmap so terra_size=512
		EntityFX Landscape,1	
		TerrainDetail Landscape,8000,True ; if set to 1000 then weird fx
End Function

Function LoadLandscapeTexture()
		Landscape_tex=LoadTexture( "blitzhmptext4096(2).png" )		
		ScaleTexture Landscape_tex,512,512
		tex0=LoadTexture( "detailLIGHT.png" )           ; crackedstone (base texture, which shows through at track,
		;ScaleTexture tex0,2,2	
		ScaleTexture tex0,.5,.5	

		EntityTexture Landscape,Landscape_tex;,0,0 ; original terrain
		EntityTexture Landscape,tex0,0,1	 ; crackedstone (detail)
End Function


Function MouseTurn2(cam1) ;(from sunflares demo)
	mxspd# = MouseXSpeed()*0.25
	myspd# = MouseYSpeed()*0.25

	MoveMouse screenmidx,screenmidy

	targetpitch = targetpitch + myspd
	targetpitch = ClampValue(targetpitch, -360,360) ;85
	targetyaw = targetyaw - mxspd	

	cam_pitch = cam_pitch + (targetpitch - cam_pitch)/8.0
	cam_yaw = cam_yaw + (targetyaw - cam_yaw)/8.0
	
	;RotateEntity player,cam_pitch,cam_yaw,0
	RotateEntity cam1,cam_pitch,cam_yaw,0
	
	If MouseDown(2) Then 
		MoveEntity cam1, 0, 0, PlayerSpeedPerSecond# * PrevFrameRenderingTimeInSeconds#

		;CreateProjectile( cam1 )
	EndIf
End Function 

Function ClampValue(Original#, low#, high#) ;belongs to mouseturn2 (from sunflares demo)
	If Original<low  Then Return low
	If Original>high Then Return high
	Return Original
End Function

Function MakeSkybox()
	Skybox=CreateMesh()
	;front face
	b=LoadBrush( "sky_FR.bmp",49 )
	s=CreateSurface( skybox,b )
	AddVertex s,-1,+1,-1,0,0:AddVertex s,+1,+1,-1,1,0
	AddVertex s,+1,-1,-1,1,1:AddVertex s,-1,-1,-1,0,1
	AddTriangle s,0,1,2:AddTriangle s,0,2,3
	FreeBrush b
	;left face
	b=LoadBrush( "sky_LF.bmp",49 )
	s=CreateSurface( skybox,b )
	AddVertex s,+1,+1,-1,0,0:AddVertex s,+1,+1,+1,1,0
	AddVertex s,+1,-1,+1,1,1:AddVertex s,+1,-1,-1,0,1
	AddTriangle s,0,1,2:AddTriangle s,0,2,3
	FreeBrush b
	;back face
	b=LoadBrush( "sky_BK.bmp",49 )
	s=CreateSurface( skybox,b )
	AddVertex s,+1,+1,+1,0,0:AddVertex s,-1,+1,+1,1,0
	AddVertex s,-1,-1,+1,1,1:AddVertex s,+1,-1,+1,0,1
	AddTriangle s,0,1,2:AddTriangle s,0,2,3
	FreeBrush b
	;right face
	b=LoadBrush( "sky_RT.bmp",49 )
	s=CreateSurface( skybox,b )
	AddVertex s,-1,+1,+1,0,0:AddVertex s,-1,+1,-1,1,0
	AddVertex s,-1,-1,-1,1,1:AddVertex s,-1,-1,+1,0,1
	AddTriangle s,0,1,2:AddTriangle s,0,2,3
	FreeBrush b
	;top face
	b=LoadBrush( "sky_UP.bmp",49 )
	s=CreateSurface( skybox,b )
	AddVertex s,-1,+1,+1,0,1:AddVertex s,+1,+1,+1,0,0
	AddVertex s,+1,+1,-1,1,0:AddVertex s,-1,+1,-1,1,1
	AddTriangle s,0,1,2:AddTriangle s,0,2,3
	FreeBrush b
	;bottom face	
	;b=LoadBrush( "sky.bmp",49 )
	;s=CreateSurface( skybox,b )
	;AddVertex s,-1,-1,-1,1,0:AddVertex s,+1,-1,-1,1,1
	;AddVertex s,+1,-1,+1,0,1:AddVertex s,-1,-1,+1,0,0
	;AddTriangle s,0,1,2:AddTriangle s,0,2,3
	;FreeBrush b
	ScaleMesh Skybox,10,10,10
	FlipMesh Skybox
	EntityFX Skybox,9
	EntityOrder Skybox,20
End Function

Function CreateWater()
	Water=CreatePlane()
	Water_tex=LoadTexture("Water01.jpg")
	ScaleTexture Water_tex,4,4
	EntityTexture Water,Water_tex
	EntityAlpha Water,0.75
	PositionEntity Water,0,3.0,0
	UnderWater=CopyEntity (Water)
	RotateEntity UnderWater,180,0,0 

End Function
End

Any body got a clue why? (code with bush model on link here )

Yue	(Posted 2014) [#42]

Download code.
https://code.google.com/p/heightmap-dynamic-grass/

Rick Nasher

(Posted 2014) [#43]

@Yue:

I know about that one, but it's more slow and not what I'm looking for as I don't really need full grass coverage. Besides I don't think it will look nice on standard Blitz3D cos will eat up it's speed, which I need for other stuff too. Just an occasional bush here and there will do, but with different types of vegetation.

Density I can increase:

I just don't get why it won't let me add 3d models instead of the ones generated in the code..

What am I missing?

Rick Nasher

(Posted 2014) [#44]

Update:

OK, found that I *can* replace the in-code generated bush with a loaded mesh.
I now added a grass quad in place pf the original bushtype 1. So it now has a mixture of bush type2 and grass:

But:
1) It apperantly only works with a simple thing like a quad for some reason.
2) I noticed that if I increase the density beyond a certain range I also get a MAV, so perhaps it's a size/memory issue?

If anyone has an idea it's greatly appreciated.

RGR	(Posted 2014) [#45]

This video looks rather nice, Yue
The only thing which is in my opinion annoying is the wannabe lens flare effect.
Looks as if the poor guy has a big ball around his left foot most of the time.

My opinion on lens flares: if you see lens flares in real life then urgently go to a good doctor. ;-)
No normal person sees lens flares while walking in the sun. Maybe if he runs around looking through two cameras fixed in front of his eyes all the time ... but that's quite unusual, too ;-)

Rick Nasher

(Posted 2014) [#46]

@RGR: True, but if you are watching a movie(one could consider a game as an interactive movie) or when wearing certain glasses you might experience something like it.

Besides all that: a game isn't always a real life representation, just good old mindless fun with lots of weird effects.

Hotshot2005

(Posted 2014) [#47]

The links is dead :(

GSimms

(Posted 2014) [#48]

Sure, they are terribly old!

Rroff

(Posted 2014) [#49]

Link in the OP atleast works for me.

Rick Nasher

(Posted 2014) [#50]

@Hotshot2005: Heyhey, which one do you need? I probably have it and can put it up for you as I was on the lookout for something that could give a nice diverse 'realistic' vegetation.

But ought to warn you: neither one of the pieces of these code is finished and bugfree, so that's why I attempted to do something myself and found that "Grass on a landscape (lite version) by Matt Merkulov" helt most promise as a foundation.

Managed to get it to swallow a vegetation map(different colors for different plants), my own 3d plant models(quads and combined quads using masked textures rather than alpha) and trees, plus I added a bit of simple wind. But too slow for my needs. See my last post here: http://www.blitzbasic.com/Community/posts.php?topic=102163#1236462

Hotshot2005

(Posted 2014) [#51]

I used to have Grass and tree party but I have lost them :(

Having realtic grass and tree on various different terrain height does added bit of extra things to it instead of looking so bland!

Rick Nasher

(Posted 2014) [#52]

Unfortunately Grass/Tree party seem to have gone down the bit fields. :-( indeed.