Chat bots

;Set up screen
Graphics 640,480,0,2
Cls

;Main loop
While 1
	x$ = Input()
	Print Reply(x)
	
	;debug
	;For t.Word = Each Word
	;	Print t\txt+": "+t\Links
	;Next
Wend
End



Type Word
	Field Txt$
	Field Link.Word[256]
	Field LinkStrength[256]
	Field Links
End Type

;Generate a rely for the given sentance
Function Reply$(s$)
	Local word$[256]
	Local words = 1

	;Split to words
	For i = 1 To Len(s)
		m$ = Mid(s, i, 1)
		If m$ = " " Then
			If word[words] <> "" Then words = words + 1
		Else
			If m <> "." And m <> "," And m <> "!" And m <> "?" Then word[words] = word[words] + m
		End If
	Next
	If words = 1 And word[1] = "" Then
		words = 0
	Else
		words = words + 1
		word[words] = "."
	End If
	
	;Remember the words and their relationships
	For i = 1 To words
		AddWord(Lower(word[i]))
		If i > 1 Then AddLink(Lower(word[i-1]), Lower(word[i]))
	Next
	
	;If nothing is in memory, return blank
	t.Word = First Word
	If t = Null Then Return ""
	
	;Pick a keyword for the reply (t.Word)
	If words = 0 Then
		;Pick a word at random
		count = 0
		For t.Word = Each Word: count = count + 1: Next
		pick = Rand(1, count)
		t.Word = First Word
		For i = 2 To pick
			t = After t
		Next
	Else
		;Pick a word the user used that has the least links
		maxlinks = 100000
		maxword.Word = Null
		For i = 1 To words
			lw$ = Lower(word[i])
			For t.Word = Each Word
				If t\Txt = lw Then Exit
			Next
			If t\Links > 0 And t\Links < maxlinks Then maxlinks = t\Links: maxword = t
		Next
		t = maxword
	End If
	
	;Generate a sentance
	out$ = "": done = False
	While done = False
		out = out + t\Txt + " "
		If t\Txt = "." Then
			done = True
		Else
			pick = Rand(1, t\Links)
			pick2 = Rand(1, t\Links)
			If t\LinkStrength[pick] > t\LinkStrength[pick2] Then t = t\Link[pick] Else t = t\Link[pick2]
		End If
	Wend
	
	;Decay
	If s = "" Then
		;For t.Word = Each Word
		;	Decay(t)
		;Next
	End If
	
	Return out
	
End Function

;Add a word to the AI bot's memory
Function AddWord(word$)
	For t.Word = Each Word
		If t\Txt = word Then Return ;word is already in memory
	Next
	this.Word = New Word
	this\Txt = word
	this\Links = 0
End Function

;Link two words together so the AI will know how to form sentances later
Function AddLink(word$, linkword$)
	;Get the objects for the words specified
	For t.Word = Each Word
		If t\Txt = word Then this.Word = t: Exit
	Next
	If this.Word = Null Then Return
	For t.Word = Each Word
		If t\Txt = linkword Then link.Word = t: Exit
	Next
	If link.Word = Null Then Return
	
	;Does the link exist?
	exists = False
	For i = 1 To this\Links
		If this\Link[i] = link Then exists = True: Exit
	Next
	
	;If link exists, strengthen it
	If exists = True Then
		this\LinkStrength[i] = this\LinkStrength[i] + 1
	End If
	
	;If link does not exist, add it
	If exists = False Then
		this\Links = this\Links + 1
		this\Link[this\Links] = link
		this\LinkStrength[this\Links] = 1
	End If
	
End Function

;Weaken all word links for the specified word. Using "decay" for word links allows old unused
;words (such as mis-spelled words) to be forgotten.
Function Decay(word.Word)
	For i = 1 To word\Links
		word\LinkStrength[i] = word\LinkStrength[i] - 1
		
		If word\LinkStrength[i] = 0 Then
			word\LinkStrength[i] = word\LinkStrength[word\Links]
			word\Link[i] = word\Link[word\Links]
			word\Link[word\Links] = Null
			word\LinkStrength[word\Links] = 0
			word\Links = word\Links - 1
			i = i - 1
		End If
	Next
End Function

file = WriteFile("output.bot")
For this.Word = Each Word
	WriteString this\Txt
	WriteInt this\Links
	For i = 1 To this\Links
		WriteInt this\LinkStrength[i]
		WriteString this\Link[i]\Txt
	Next
Next
CloseFile(file)