QHull dll

Blitz3D Forums/Blitz3D Programming/QHull dll

Picklesworth

(Posted 2004) [#1]

I'm playing about with the QHull dll, and I've encountered a problem. It's quite simple to describe:
If I call the create_Tok_Hull() function twice in the same program, I get I memory access violation on the QHull function. How can I fix this?

elias_t

(Posted 2004) [#2]

Hi. If you are using my qhull dll version I have uploaded a new version of this dll. It had to do with a memory release problem.

Please redownload from here: http://www.freewebs.com/elias_t/qhulldll.htm

Bye.
Elias.

Picklesworth

(Posted 2004) [#3]

okay, works great now.
Thanks a lot

Filax

(Posted 2009) [#4]

Sorry to up this topic, but here is a quick test in blitz3D for the hull dll.


Type hull
	Field x0#
	Field y0#
	Field z0#
	
	Field x1#
	Field y1#
	Field z1#
	
	Field x2#
	Field y2#
	Field z2#

End Type

Dim qvix(0)
Dim qviy(0)
Dim qviz(0)
Dim txv(0)



Graphics3D 600,600,32,2

Global cam = CreateCamera()
CameraClsColor cam,25,30,70
PositionEntity cam,0,2,-5


light= CreateLight(2)
PositionEntity light,50,50,50
LightRange light,50

entity=LoadMesh("m:\BlitzMax\sources\Tachyon Storm - Design Test\Galaxy Engine\Medias\chikara.b3d")

Create(entity,"Test.txt","Test.off",0.6,1,0.02,0.02,0.02)


PointEntity cam,entity

While Not KeyHit(1)
	TurnEntity entity,0,0.1,0
	
	RenderWorld()
	Flip
Wend

End




; -----------------------------------------------------------------------------------------------------
; Create a hull mesh from an entity, delta=hull complexity (bugged ?), weld = weld the hull mesh vertex
; -----------------------------------------------------------------------------------------------------
Function Create%(Entity%,File1$,File2$,Delta#,Weld%=1,Sx#=1,Sy#=1,Sz#=1)
	Local points%
	Local stream%
	
	Local vx#
	Local vy#
	Local vz#
	
	Local k%
	Local l%
	
	Local count%
	Local res%
	
	Local v0%
	Local v1%
	Local v2%
	
	Local vt0%
	Local vt1%
	Local vt2%
	
	Local t_f$
			
	Local rx#
	Local ry#
	Local rz#
	
	Local px#
	Local py#
	Local pz#
	
	Local su%
	Local mesh%
	Local surf%

	ScaleEntity Entity,10,10,10,1
	
	rx=EntityPitch(Entity,1)
	ry=EntityYaw(Entity,1)
	rz=EntityRoll(Entity,1)
	RotateEntity Entity,0,0,0,1
	
	px=EntityX(Entity,1)
	py=EntityY(Entity,1)
	pz=EntityZ(Entity,1)
	PositionEntity Entity,0,0,0,1
	
	Local surfs%=CountSurfaces(Entity) 
	If surfs=0 Return -1
	
	For k=1 To surfs
		surf=GetSurface(Entity,k)
		points=points+CountVertices(surf)
	Next
		
	stream=WriteFile(File1$)
	WriteLine Stream,"3"
	WriteLine Stream,points
	
	
	
	
	count=0
	
	For k=1 To surfs
		surf=GetSurface(Entity,k)
		
		For l=0 To CountVertices(surf)-1		
			count=count+1	
		Next
	Next
		
	Dim qvix(count*2)
	Dim qviy(count*2)
	Dim qviz(count*2)
	
	count=0
	
	For k=1 To surfs
		surf=GetSurface(Entity,k)
		
		For l=0 To CountVertices(surf)-1
			vx=VertexX(surf,l)
			vy=VertexY(surf,l)
			vz=VertexZ(surf,l)
			
			TFormPoint vx,vy,vz,Entity,0
			
			WriteLine stream,TFormedX()+" "+TFormedY()+" "+TFormedZ()
			
			DebugLog count+TFormedX()+" "+TFormedY()+" "+TFormedZ()

			qvix(count)=TFormedX()
			qviy(count)=TFormedY()
			qviz(count)=TFormedZ()
			
			count=count+1
		Next
	Next
	
	CloseFile stream
	
	RotateEntity Entity,rx,ry,rz,1
	PositionEntity Entity,px,py,pz,1	
	res=qhull(File1$,File2$,Delta,1,1)
	
	Stream=ReadFile(file2)
	t_f=ReadLine(Stream)

	If Lower(Left(t_f,1))<>"n"
		Dim qvix(0)
		Dim qviy(0)
		Dim qviz(0)
		Return False 
	EndIf
	
	mesh=CreateMesh()
	su=CreateSurface(mesh)
		
	While Not Eof(Stream)
		t_f=ReadLine(Stream)
		
		If t_f<>""
			v0=Int(GetString(t_f,1))
			v1=Int(GetString(t_f,2))
			v2=Int(GetString(t_f,3))
			
			vt0=AddVertex (su,qvix(v0),qviy(v0),qviz(v0))
			vt1=AddVertex (su,qvix(v1),qviy(v1),qviz(v1))
			vt2=AddVertex (su,qvix(v2),qviy(v2),qviz(v2))
			
			AddTriangle (su,vt0,vt2,vt1)
		EndIf
	Wend
	
	CloseFile Stream	

	If weld=1 Then 
		WeldMesh(mesh)
		UpdateNormals(mesh)
	EndIf
	
	EntityAlpha mesh,0.4
	EntityColor mesh,150,150,0
	EntityFX mesh,1
	EntityBlend mesh,3
	EntityParent mesh,Entity
	
	ScaleEntity Entity,Sx,Sy,Sz,1
	
	; ------------------
	; Freeing ressources
	; ------------------
	Dim qvix(0)
	Dim qviy(0)
	Dim qviz(0)
		
	DeleteFile File1$
	DeleteFile File2$
		
	Return Mesh	
End Function

Function WeldMesh(Mesh%,Thresh#=0.001)	
	Local su%=GetSurface(mesh,1)
	Local count%=0
	Local mycount%=0
	
	Dim txv(CountTriangles(su))

	For tq% = 0 To CountTriangles(su)-1
		txv(0) = TriangleVertex(su,tq,0)
		txv(1) = TriangleVertex(su,tq,1)
		txv(2) = TriangleVertex(su,tq,2)
		
		Local vq.Hull = New Hull
		vq\x0 = VertexX(su,txv(0))
		vq\y0 = VertexY(su,txv(0))
		vq\z0 = VertexZ(su,txv(0))
		vq\x1 = VertexX(su,txv(1))
		vq\y1 = VertexY(su,txv(1))
		vq\z1 = VertexZ(su,txv(1))
		vq\x2 = VertexX(su,txv(2))
		vq\y2 = VertexY(su,txv(2))
		vq\z2 = VertexZ(su,txv(2))
	Next
	
	ClearSurface su,True,True
	
	For vq.Hull = Each Hull
		Local vt1%=FindVertice(su,vq\x0,vq\y0,vq\z0,Thresh)
			
		If vt1=-1 Then
			vt1=AddVertex(su,vq\x0,vq\y0,vq\z0)
			vt1 = mycount
			mycount = mycount +1
		EndIf

		Local vt2%=FindVertice(su,vq\x1,vq\y1,vq\z1,Thresh)
		
		If Vt2=-1 Then
			vt2=AddVertex(su,vq\x1,vq\y1,vq\z1)
			vt2 = mycount
			mycount = mycount +1
		EndIf
		
		Local vt3%=FindVertice(su,vq\x2,vq\y2,vq\z2,Thresh)
		
		If vt3=-1 Then
			vt3=AddVertex(su,vq\x2,vq\y2,vq\z2)
			vt3 = mycount
			mycount = mycount +1
		EndIf
	
		AddTriangle su,vt1,vt2,vt3
	Next

				
	UpdateNormals(Mesh)
End Function

Function FindVertice%(su%,X2#,Y2#,Z2#,Thresh#)
	For T%=0 To CountVertices(su)-1
		If Abs(VertexX(su,T)-x2)<Thresh Then 
			If Abs(VertexY(su,T)-y2)<Thresh Then 
				If Abs(VertexZ(su,T)-z2)<Thresh Then 
					Return t%
				EndIf
			EndIf
		EndIf
	Next
	
	Return -1
End Function

; -------------------------------------------------
; Function to parse a string with space delimitator
; -------------------------------------------------	
Function GetString$(in$, num%)
	Local Stemp$ = ""
	Local NumTemp% = 0
	
	For Temp%=1 To Len(in)
	
		If Mid(In, Temp, 1)<>" " Then
			Stemp = Stemp + Mid(in, temp, 1)
		Else
			numtemp = numtemp + 1
			
			If numtemp = num
				Return stemp
			Else
				stemp = ""
			EndIf
		EndIf
	
	Next

	Return ""
End Function