Project PLASMA FPS 2004: Thread 4

Type lifttype
Field name$
Field meshindex ; the mesh
Field xs,ys,zs ;starting position
Field xe,ye,ze ;ending position
Field ws,ps,rs ;starting rotation
Field we,pe,re ;ending rotation
Field f# ;0.0-1.0 where inbetween start and end is it?
Field speed# ;speed of motion
Field dir ;1=forward -1=back direction
Field triggertype ;what triggers it to move?
Field moving ;is it moving?
End Type

Type soundtype
Field name$
Field class ;ambient oneshot everytime ?
Field playing ;sound is playing now?
Field pivot ;used for entity distance triggering
Field radius# ;as above
Field soundindex ;which sound does this use?
Field timer ; how long has the sound been playing?
Field time ; when was the sound started?
End Type

The New and Improved BotSensor Model

Type sensor
	Field id%
	Field typeid%
	Field entityid%
	Field process.queue
End Type

Type ai
	Field id%
	Field typeid%
	Field action.action
	Field return#
	Field compare%
	Field value#
	Field state%
	Field priority% 
	Field life.clock
End type

Function sensorProcess%(this.sensor)
	;Checks Process queue items (ai objects)
	For loop= 1 To this\process\queueitems%
		this\ai.ai=aiid(this\process\queueitem[loop])
		If aiCompare(this\ai) state%=this\ai\state%
	Next
	Return state%
End Function

Function aiCompare(this.ai)
	this\return#=botaction(this\action)
	Select this\compare%
		Case 1;=
			if this\return#=this\value# Return True
		Case 2;<>
			if this\return#<>this\value# Return True
		Case 3;>
			if this\return#>this\value# Return True
		Case 4;<
			if this\return#<this\value# Return True
		Case 5;=>
			if this\return#=>this\value# Return True
		Case 6;<=
			if this\return#<=this\value# Return True
	End Select
End function

CallBuilder Code Wizard. Builds an ActionCall() Select...Case from a list of Function prototypes. The code wizard is Designed specifically to be used with the Action System.

;The CallBuilder Code Wizard by Frankie 'Techlord' Taylor
;Purpose: Reads and Parses Prototype File, Writes Select Case Tree File.

Dim RFileNames$(0),METHODPar$(0),METHODS$(1024)
Function TreeBuild(RFileName$,WFileName$,AppendFlg=False,Argument$="this\",DataTypeI$="i%",DataTypeF$="f#",DataTypeS$="s$")
	Dim RFileNames$(256),METHODPar$(16)
	RF=ReadFile(RFileName$)
	DebugLog "Reading RF "+RFileName$+" "+Str$(RF)
	If RF
		WF=WriteFile(WFileName$+"call.bb")
		WriteLine(WF,";"+Upper$(WFileName$+" ACTIONCALL"))
		WriteLine(WF,"Function "+WFileName$+"Call(this.action)")
		WriteLine(WF,"If this\method%")
		WriteLine(WF,"Select this\method%")
		Repeat
			Line$=ReadLine(RF)
			If Left$(Line$,9)="Function " Or Upper$(Left$(Line$,8))="Method "
				Funct=Funct+1
				ArgStart=0
				ArgCt=0
				For Char = 1 To Len(Line$)
					Ch$=Mid$(Line$,Char,1)
					If Ch$="(" Then ArgStart=Char
					If Ch$="." And ArgStart Then Obj=True ;getObject
					If Obj Then ObjS$=ObjS$+Ch$
					If Ch$="," Or Ch$=")"
						ArgCt=ArgCt+1
						Ch$=Mid$(Line$,Char-1,1)
						METHODPar$(ArgCt)=DataTypeI$
						If Ch$="#" Then METHODPar$(ArgCt)=DataTypeF$
						If Ch$="$" Then METHODPar$(ArgCt)=DataTypeS$
						;If Ch$="=" Then 
						If Ch$="(" Then ArgCt=0
						If Obj
							METHODPar$(ArgCt)=Left$(ObjS$,Len(ObjS$)-1)
							Obj=False
							ObjS$=Nil$
						EndIf
					EndIf
				Next
				Method$=Right$(Left$(Line$,ArgStart-1),Len(Left$(Line$,ArgStart-1))-9)
				Par$="("
				For ArgList = 1 To ArgCt
					;If argseq
						Select METHODPar$(ArgList)
							Case DataTypeI$
								datatypeicount=datatypeicount+1	
								Par$=Par$+Argument$+METHODPar$(ArgList)+"["+Str$(datatypeicount)+"]"
							Case DataTypeF$
								datatypefcount=datatypefcount+1
								Par$=Par$+Argument$+METHODPar$(ArgList)+"["+Str$(datatypefcount)+"]"								
							Case DataTypeS$
								datatypescount=datatypescount+1
								Par$=Par$+Argument$+METHODPar$(ArgList)+"["+Str$(datatypescount)+"]"
							Default 
								Par$=Par$+"this"+Right$(METHODPar$(ArgList),Len(METHODPar$(ArgList))-1)+METHODPar$(ArgList)
						End Select	
					;Else
					;	Par$=Par$+Argument$+METHODPar$(ArgList)+"["+Str$(ArgList)+"]"
					;EndIf
					If ArgList<ArgCt Then Par$=Par$+","
				Next
				Par$=Par$+")"
				WriteLine(WF,"Case "+Str$(Funct)+":"+Method$+Par$)
				datatypeicount=reset
				datatypefcount=reset
				datatypescount=reset
			EndIf
			If Left$(Line$,7)="Append "
				Incl=Incl+1
				AppendFlg=True
				RFileNames$(Incl)=Left$(Right$(Line$,Len(Line$)-9),Len(Right$(Line$,Len(Line$)-9))-1)
			EndIf
			If Left$(Line$,6)="Macro " 
				Funct=Funct+1
				Macro=True
				MacroLabel$=Nil$
				METHODMacro$=Nil$
				For Char = 7 To Len(Line$)
					Ch$=Mid$(Line$,Char,1)
					If Ch$="}" Then Exit
					If Macro Then MacroLabel$=MacroLabel$+Ch$
					If Not Macro Then METHODMacro$=METHODMacro$+Ch$
					If Ch$="{" Then Macro=False
				Next
				WriteLine(WF,"Case "+Str$(Funct)+":"+METHODMacro$+";"+Left$(MacroLabel$,Len(MacroLabel$)-1)+" MACRO")
			EndIf
		Until EOF(RF)
		CloseFile(RF)
		WriteLine(WF,";+"+Str$(Funct))
		WriteLine(WF,"End Select")
		WriteLine(WF,"EndIf")
		WriteLine(WF,"End Function")
		CloseFile(WF)
	Else
		CloseFile(RF)
	EndIf
End Function

;Example of missile object

Const MISSILE_MAX%=100 ;<-- Predefined maximum number of missiles
Global missileIndex.stack=stackIndexCreate(MISSILE_MAX%) ;<-- Dedicated FILO Stack

Type missile ;<-- missile Game Object Custom Type
	Field id%<-- Primary Key
	Field typeid% <-- Composite Key
	Field shipid%<-- Foreign Key
	Field entityid%
	Field targetid%	
	Field state%
	Field life%
	Field damage%
End Type

Dim missileID.missile(MISSILE_MAX%) ;<-- Array of Types (Reference)

Function missileNew.missile() ;<-- initiallizes a new instance of object aka constructor
	this.missile=New missile
	this\id%=0 ;<-- Default values (optional)
	this\typeid%=0
	this\shipid%=0
	this\entityid%=0
	this\targetid%=0
	this\state%=0
	this\life%=0
	this\damage%=0
	this\id%=StackPop(missileIndex.stack) ;<-- Pops available ID off FILO Stack
	missileId(this\id%)=this ;<-- assign Primary Key to object matching array index/object id
	Return this
End Function

Function missileDelete(this.missile)
	missileId(this\id%)=Null
	StackPush(missileIndex.stack,this\id%)
	Delete this
End Function 

Function missileCreate.missile(typeid%,shipid%,targetid%,state%,life%,damage%)
	this.missile=missileNew()
	this\typeid%=typeid%
	this\shipid%=shipid%
	this\entityid%=stackPop(missileEntity.stack[this\typeid])
	this\targetid%=targetid%
	this\state%=state%
	this\life%=life%
	this\damage%=damage%	
End Function

Function missileDestroy(this.missile)
	stackPush(missileEntity.stack[this\typeid],this\entityid%)
	missileDelete(this)
End Function

Function missileUpdate() ;<-- update function included in primary game loop
	For this.missile = Each missile
		Select this\state%
			Case 1 ;flight movement and collsion
				Select this\typeid% ;<-- 
					Case 1 ;guided 
						missileGuide(this)
					Case 2 ;heatseeker
						missileHeatSeek(this)
					Case 3 ;rocket
						missileMove(this)
				End Select
			Case 2 ;impact
				missileDamage(this)
			Case 3 ;detonated
				missileDestroy(this)
		End Select
	Next
End Function

Naming Convention:
[Object][Purpose](ie: ClockSet) 
[Object][Property][Purpose](ie: ActionIntSet(myaction,index,255)) 
[Object][SubObject][Purpose](ie: DatabaseRowNext(db)) 
[Object][SubObject][Property][Purpose](ie: CameraRumbleXSet(camera,2.0))