Sonic Camera?

Blitz3D Forums/Blitz3D Programming/Sonic Camera?

Caton

(Posted April) [#1]

How can I get the camera to turn and follow at some current point?
like this.
https://www.youtube.com/watch?v=L-9UyTsaimc
Thanks.

Flanker

(Posted April) [#2]

Not exactly the same effect but there is a nice chasecam in the code archives : https://www.blitzbasic.com/codearcs/codearcs.php?code=2724

Caton

(Posted April) [#3]

I tried but it didn't work well.
Texture Here.

https://upload.wikimedia.org/wikipedia/commons/thumb/7/70/Checkerboard_pattern.svg/2000px-Checkerboard_pattern.svg.png

Global mode
AppTitle("CameraTest")
Graphics3D 800,600,32,2
SetBuffer BackBuffer()
Global camera=CreateCamera()
PositionEntity camera,0,1,-5
Global player=CreateCube()
Global DISTANCE#=5
light=CreateLight()
plane=CreatePlane()
planetex=LoadTexture("media\Checkerboard.png")
EntityTexture plane,planetex

While Not KeyDown( 1 )
Cls
ControlCamera()
ControlPlayer()
UpdateWorld
RenderWorld
Flip
Wend
End

Function ControlPlayer()
If KeyDown(200) Then TranslateEntity player,0,0,0.1
If KeyDown(208) Then TranslateEntity player,0,0,-0.1
If KeyDown(205) Then TranslateEntity player,0.1,0,0
If KeyDown(203) Then TranslateEntity player,-0.1,0,0
End Function

Function ControlCamera()
If Not (EntityX(player) < DISTANCE#) Then mode=2
If (EntityX(player) < DISTANCE#) Then mode=1
Select mode
Case 1
PointEntity camera,player
Case 2
PositionEntity camera,EntityX(player)-3,EntityY(player)+1,EntityZ(player)-5
End Select
End Function

Flanker

(Posted April) [#4]

More like the sonic camera, try this :

Graphics3D 800,600,32,2
SetBuffer BackBuffer()


camera = CreateCamera()
CameraRange camera,0.1,1000
PositionEntity camera,0,3,-10

light = CreateLight()
RotateEntity light,30,70,0


player = CreateCube()
EntityColor player,255,0,0
axis = CreateCube(player)
ScaleEntity axis,0.1,0.1,1.9
PositionEntity axis,0,0,1

target = CreatePivot(player)
PositionEntity target,0,3,0


For i = 1 To 100
	cube = CreateCube()
	PositionEntity cube,Rnd(100)-50,0,Rnd(100)-50
	TurnEntity cube,0,Rnd(360),0
Next


While Not KeyHit(1)

	
	If KeyDown(200) Then MoveEntity player,0,0,0.2
	If KeyDown(208) Then MoveEntity player,0,0,-0.2
	If KeyDown(205) Then TurnEntity player,0,-2,0
	If KeyDown(203) Then TurnEntity player,0,2,0
	
	vy# = vy - 0.02
	If MouseHit(1) Then vy = 0.5
	
	PositionEntity player,EntityX(player),EntityY(player)+vy,EntityZ(player)
	If EntityY(player) < 0 Then MoveEntity player,0,-EntityY(player),0
	
	UpdateCamera(camera,target,15)

	RenderWorld
	
	Text 10,10,"Use arrows to move/turn player, mouse left to jump"
	
	Flip


Wend

End

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
Function UpdateCamera(cam,ent,dist#)
	
	vx# = EntityX(ent,1)-EntityX(cam,1)
	vy# = EntityY(ent,1)-EntityY(cam,1)
	vz# = EntityZ(ent,1)-EntityZ(cam,1)
	
	distance# = EntityDistance(cam,ent)
	
	If distance > 0
		diff# = (distance-dist)/dist
	Else
		diff = 0
	EndIf
	
	PositionEntity cam,EntityX(cam,1)+vx*diff,EntityY(cam,1)+vy*diff,EntityZ(cam,1)+vz*diff,0.001
	If EntityY(cam,1)>EntityY(ent,1) Then MoveEntity cam,0,(EntityY(ent,1)-EntityY(cam,1))*0.01,0
	If EntityY(cam,1)<EntityY(ent,1) Then MoveEntity cam,0,(EntityY(ent,1)-EntityY(cam,1))*0.01,0
	PointEntity cam,ent

End Function

Caton

(Posted April) [#5]

anyway to change offset when pointing at player when moved to the right or left?

Flanker

(Posted April) [#6]

Position the target entity ahead of player.