Wireframe certain objects, other objects shaded...

Blitz3D Forums/Blitz3D Programming/Wireframe certain objects, other objects shaded...

hollifd

(Posted April) [#1]

Is it possible to show certain objects in Wireframe and other objects as shaded? If so, can someone tell me how it is done?

Another question...my models show the triangles that make up the surfaces. Is there a way in Blitz to only show the edges and not the triangles?

Rick Nasher

(Posted April) [#2]

I think so. I think Krischan used this technique here:
https://www.blitzbasic.com/codearcs/codearcs.php?code=2393

BlitzSupport

(Posted April) [#3]

Couple of approaches here...

http://www.blitzbasic.com/codearcs/codearcs.php?code=22
http://www.blitzbasic.com/codearcs/codearcs.php?code=380

hollifd

(Posted April) [#4]

Krischan has some impressive code in that link.

I am not really a game programmer and it was not obvious to me how I can show certain things as Wireframe and other things as shaded. I saw where you can use Wireframe True to turn everything Wireframe. I am thinking it may not be possible.

RemiD

(Posted April) [#5]

We talked about a similar thing here :
https://www.blitzbasic.com/Community/posts.php?topic=100959 (post#11)

it may help...

Matty

(Posted April) [#6]

The wireframe mode that blitz ships with is not very good really - it is not meant really for visualising wireframes in a finished product.

You have a few options.

One of the simplest is the following:

Iterate through each triangle in the surface of the mesh.
You will need to use the countsurfaces, getsurface and other surface vertex and triangle commands.

Get the position of the vertices that make up a triangle in world space.

Use cameraproject to project the 3d positions to 2d screen coordinates. If projectedz() is less than zero it is behind the camera.

Join the dots with 2d line commands.

That is the easiest.

A more complex way would be to create a mesh with thin rectangular strips joining each of the vertices in question and show these. This is more complex but will give a better visual appearance and you have more control over the depth perception of the wireframe lines.

BlitzMan

(Posted April) [#7]

; ID: 1108
; Author: Noel - Banned
; Date: 2004-07-17 02:51:48
; Title: Wire Primitives and Drawing
; Description: Functions to create wireframe primitives and draw them

Graphics3D 800,600,0,2

Camera = CreateCamera()
CameraClsColor Camera,128,128,128

Cylinder = CreateCylinder(8)
EntityAlpha Cylinder,0.5
WireCylinder = CreateWireCylinder(8)
EntityColor WireCylinder,0,255,128
EntityColor Cylinder,96,96,96
EntityParent Cylinder,WireCylinder

Cube = CreateCube()
;EntityAlpha Cube,0.5
WireCube = CreateWireCube()
EntityColor Cube,96,96,96
EntityColor WireCube,0,255,128
EntityParent Cube,WireCube

Sphere = CreateSphere(8)
EntityAlpha Sphere,0
WireSphere = CreateWireSphere(8)
EntityColor Sphere,96,96,96
EntityColor WireSphere,0,255,128
EntityParent Sphere,WireSphere

PositionEntity WireCube,3,0,-3
PositionEntity WireSphere,-3,0,3

PositionEntity Camera,4,4,4
PointEntity Camera,Cylinder

Repeat
	
	HideEntity Cylinder
	HideEntity Cube
	HideEntity Sphere
	
	TurnEntity WireCylinder,.5,.6,.7
	TurnEntity WireCube,.5,.6,.7
	TurnEntity WireSphere,.5,.6,.7
	
	DrawWireMeshes(Camera,1)
	
	ShowEntity Cylinder
	ShowEntity Cube
	ShowEntity Sphere
	
	RenderWorld
	UpdateWorld
	
	Flip
	
Until KeyHit(1)


Type WireMesh
	Field Entity
End Type

Function DrawWireMeshes(Cam,Tween#=-1)
	For W.WireMesh = Each WireMesh
		EntityAlpha W\Entity,1
	Next
	
	CameraClsMode Cam,1,1
	WireFrame True
	
	If Tween Then
		RenderWorld Tween
	Else
		RenderWorld
	EndIf
	
	WireFrame False
	CameraClsMode Cam,0,0
	
	For W.WireMesh = Each WireMesh
		EntityAlpha W\Entity,0
	Next
End Function

Function CreateWireCube()
	M=CreateMesh()
	S = CreateSurface(M)
	;outer edges
	WireLine3D S,-1,-1,-1,-1,1,-1
	WireLine3D S,1,-1,-1,1,1,-1
	WireLine3D S,1,-1,1,1,1,1
	WireLine3D S,-1,-1,1,-1,1,1
	
	;top edges
	WireLine3D S,1,1,1,-1,1,1
	WireLine3D S,1,1,-1,-1,1,-1
	WireLine3D S,-1,1,-1,-1,1,1
	WireLine3D S,1,1,-1,1,1,1
	
	; bottom edges
	WireLine3D S,1,-1,1,-1,-1,1
	WireLine3D S,1,-1,-1,-1,-1,-1
	WireLine3D S,-1,-1,-1,-1,-1,1
	WireLine3D S,1,-1,-1,1,-1,1
	
	EntityFX M,1+4+16
	EntityAlpha M,0
	W.WireMesh = New WireMesh
	W\Entity = M
	Return M
End Function

Function CreateWireSphere(Segments=8)
	M = CreateMesh()
	S = CreateSurface(M)
	Dummy = CreateSphere(Segments)
	DS = GetSurface(Dummy,1)
	For N = 0 To CountTriangles(DS)-1
		V1 = TriangleVertex(DS,N,0)
		V2 = TriangleVertex(DS,N,1)
		V3 = TriangleVertex(DS,N,2)
		If V1 < Segments*2 Then WireLine3D S,VertexX(DS,V1),VertexY(DS,V1),VertexZ(DS,V1),VertexX(DS,V2),VertexY(DS,V2),VertexZ(DS,V2)
		WireLine3D S,VertexX(DS,V2),VertexY(DS,V2),VertexZ(DS,V2),VertexX(DS,V3),VertexY(DS,V3),VertexZ(DS,V3)
		
	Next
	FreeEntity Dummy
	EntityFX M,1+4+16
	W.WireMesh = New WireMesh
	W\Entity = M
	Return M
End Function

Function CreateWireCylinder(Segments=8)
	M = CreateMesh()
	S = CreateSurface(M)
	AngleStep# = 360.0/Segments
	While N < 360
		WireLine3D S,Sin(N),1,Cos(N),Sin(N),-1,Cos(N)
		WireLine3D S,Sin(N),1,Cos(N),Sin(N+AngleStep),1,Cos(N+AngleStep)
		WireLine3D S,Sin(N),-1,Cos(N),Sin(N+AngleStep),-1,Cos(N+AngleStep)
		N = N + AngleStep
	Wend
	EntityFX M,1+16
	EntityAlpha M,0
	W.WireMesh = New WireMesh
	W\Entity = M
	Return M
End Function

;Function CreateWireRing(Segments=8)
;	M = CreateMesh()
;	S = CreateSurface(M)
;	AngleStep# = 360.0/Segments
;	While N < 360
;		WireLine3D S,Sin(N),0,Cos(N),Sin(N+AngleStep),0,Cos(N+AngleStep)
;		N = N + AngleStep
;	Wend
;	EntityFX M,1+16
;	EntityAlpha M,0
;	W.WireMesh = New WireMesh
;	W\Entity = M
;	Return M
;End Function

Function WireLine3D(S,X#,Y#,Z#,X2#,Y2#,Z2#)
	V=AddVertex(S,X,Y,Z)
	AddVertex(S,X2,Y2,Z2)
	AddVertex(S,(X+X2)/2,(Y+Y2)/2,(Z+Z2)/2)
	AddTriangle S,V,V+1,V+2
End Function

BlitzMan

(Posted April) [#8]