Object Follow Player Trick?

Blitz3D Forums/Blitz3D Programming/Object Follow Player Trick?

Caton

(Posted March) [#1]

https://www.youtube.com/watch?v=B4Kmkxaysf4
starts at 0:46 to 1:00

Dan	(Posted March) [#2]

That is pretty easy.

The monsters are aiming at the x,y coordinates of the player.

If they hit the wall, they stop.

this is the theoretical functioning code without the check for the walls:

if playerx>monsterx then monsterx=monsterx+monsterspeedx
if playerx<monsterx then monsterx=monsterx-monsterspeedx
if playery>monstery then monstery=monstery+monsterspeedy
if playery<monstery then monstery=monstery-monsterspeedy

here is an 2d example, for 3d you would render only the part of the playground array.

;By Dan
Graphics 640,480,32,2
Graphics 320,240,32,3

SetBuffer BackBuffer()

Dim playground(15,12)

;Readdata
For y=1 To 12
	For x=1 To 15
		Read playground(x,y)
		If playground(x,y)=1 Then 
			playerx=x
			playery=y
		EndIf
		If playground(x,y)=2 Then 
			monsterx=x
			monstery=y
		EndIf
	Next ;x
Next ;y

playermovetimer=MilliSecs()
monstermovetimer=MilliSecs()

Repeat
    If MilliSecs()-playermovetimer>150 Then Gosub moveplayer
	If MilliSecs()-monstermovetimer>550 Then Gosub movemonster
	Gosub drawscreen
	Delay 1
	Flip
Until KeyDown(1)

WaitKey()
End

.movemonster
monstermovetimer=MilliSecs()
If monsterx>playerx Then 
	If playground(monsterx-1,monstery)=0 And monsterx>1
		playground(monsterx,monstery)=0
		monsterx=monsterx-1
		playground(monsterx,monstery)=2
	EndIf
EndIf

If monsterx<playerx Then
	If playground(monsterx+1,monstery)=0 And monsterx<=14
		playground(monsterx,monstery)=0
		monsterx=monsterx+1
		playground(monsterx,monstery)=2
	EndIf
EndIf

If monstery>playery Then 
	If playground(monsterx,monstery-1)=0 And monstery>1
		playground(monsterx,monstery)=0
		monstery=monstery-1
		playground(monsterx,monstery)=2
	EndIf
EndIf

If monstery<playery Then
	If playground(monsterx,monstery+1)=0 And monstery<=11
		playground(monsterx,monstery)=0
		monstery=monstery+1
		playground(monsterx,monstery)=2
	EndIf
EndIf

Return

.moveplayer
playermovetimer=MilliSecs()
If KeyDown(200) Then ;up
	If playground(playerx,playery-1) = 0 And playery>1
		playground(playerx,playery)=0
		playery=playery-1
		playground(playerx,playery)=1
	EndIf 
EndIf	

If KeyDown(208) Then ;down
	If playground(playerx,playery+1) = 0 And playery<=11
		playground(playerx,playery)=0
		playery=playery+1
		playground(playerx,playery)=1
	EndIf
EndIf

If KeyDown(203) Then ;left
	If playground(playerx-1,playery) = 0 And playerx>1
		playground(playerx,playery)=0
		playerx=playerx-1
		playground(playerx,playery)=1
	EndIf
EndIf

If KeyDown(205) Then ;right
	If playground(playerx+1,playery) = 0 And playerx<=14
		playground(playerx,playery)=0
		playerx=playerx+1
		playground(playerx,playery)=1
	EndIf
EndIf

Return

.drawscreen
Cls
Color $ff,$ff,$ff
Text 150,20,LSet("PlayerX= "+playerx,11)+LSet(" Y="+Playery,5)
Text 150,35,LSet("MonsterX="+monsterx,11)+LSet(" Y="+MonsterY,5)
Rect 8,14,(15*FontWidth())+1,(12*FontHeight())-1,0
For y=1 To 12
	For x=1 To 15
		xx=x*FontWidth()
		yy=y*FontHeight()
		If playground(x,y)=1 Then Color 0,$ff,$0 : Text xx,yy,"P"
		If playground(x,y)=2 Then Color $ff,0,$0 : Text xx,yy,"M"
		If playground(x,y)=3 Then Color 0,$0,$ff : Text xx,yy,"#"
	Next ;x
Next ;y

Return 


.blah
Data 0,0,0,0,0,0,0,0,0,0,0,0,0,0,0
Data 0,0,1,0,0,0,0,0,0,0,0,0,0,0,0
Data 0,0,0,0,0,0,0,0,0,0,0,0,0,0,0
Data 0,0,0,0,3,3,3,3,3,0,0,0,0,0,0
Data 0,0,0,0,0,0,3,0,0,0,0,0,0,0,0
Data 0,0,0,0,0,0,3,0,0,0,0,0,0,0,0
Data 0,0,0,3,3,3,3,3,3,3,3,0,0,0,0
Data 0,0,0,3,0,0,0,0,0,0,3,0,0,0,0
Data 0,0,0,3,0,0,0,0,0,0,3,0,0,0,0
Data 0,0,0,3,0,0,2,0,0,0,3,0,0,0,0
Data 0,0,0,0,0,0,0,0,0,0,3,0,0,0,0
Data 0,0,0,0,0,0,0,0,0,0,0,0,0,0,0