Select Object Arrows

Blitz3D Forums/Blitz3D Programming/Select Object Arrows

Caton

(Posted 2017) [#1]

I'm trying to select and move the object for my level editor with the mouse anyway I could do that?
<Image Removed>

grable

(Posted 2017) [#2]

A CameraPick for the colored parts on first detected MouseDown, then move the entity with MouseXSpeed/MouseYSpeed depending on picked direction.

My code for moving with the mouse usually follows this pattern:

Global down

If MouseDown(1) Then
	If Not down Then
		; enter move state
		down = True
		MouseXSpeed()
		MouseYSpeed()
	EndIf
	; inside move state
	; move it here using MouseXSpeed() and MouseYSpeed())
ElseIf down Then
	; leaving move state
	down = False
EndIf

Caton

(Posted 2017) [#3]

I have two objects, Now when I select one object to move, the other one goes missing

If MouseDown(1) Then
CameraPick(Maincam, MouseX(), MouseY())
For obj.tobj = Each tobj
If PickedEntity() Then PositionEntity obj\mesh,PickedX#(),0,PickedZ#()
Next
EndIf

grable

(Posted 2017) [#4]

I assumed from your picture you wanted a movable thingy, like what 3D editors have, but looking at your code you are doing placement instead?

In any case, heres some code to move a thingy with the mouse:


Graphics3D 800,600

Global cam = CreateCamera()
MoveEntity cam, 0,5, -10

Global thing = MakeThingy()

PointEntity cam, thing

Const MOVE_COEF# = 0.10

Global ismoving
Global movingent

Repeat
	
	If MouseDown(1) Then
		If Not ismoving Then
			If CameraPick( cam, MouseX(), MouseY()) Then
				Local e = PickedEntity()
				Local t = GetEntityType(e)
				If t >= 1 And t <= 3 Then
					ismoving = t
					movingent = thing
					MouseXSpeed()
					MouseYSpeed()
				EndIf
			EndIf
		EndIf
		Select ismoving
			Case 1	MoveEntity movingent, 0, -MouseYSpeed() * MOVE_COEF, 0
			Case 2	MoveEntity movingent, MouseXSpeed() * MOVE_COEF , 0, 0
			Case 3	MoveEntity movingent, 0, 0, -MouseYSpeed() * MOVE_COEF
		End Select
	ElseIf ismoving Then
		ismoving = 0
		movingent = 0
	EndIf

	RenderWorld
	Flip
	Cls

Until KeyHit(1)
End


Function MakeThingy()
	Local thing = CreateCube()
	
	Local y = CreateCube()
	ScaleEntity y, 0.25, 1, 0.25
	EntityColor y, 255,0,0
	MoveEntity y, 0,1,0
	EntityPickMode y, 3
	EntityType y, 1
	EntityParent y, thing
	
	Local x = CreateCube()
	ScaleEntity x, 1, 0.25, 0.25
	EntityColor x, 0,255,0
	MoveEntity x, 1,0,0
	EntityPickMode x, 3
	EntityType x, 2
	EntityParent x, thing
		
	Local z = CreateCube()
	ScaleEntity z, 0.25, 0.25, 1
	EntityColor z, 0,0,255
	MoveEntity z, 0,0,-1
	EntityPickMode z, 3
	EntityType z, 3
	EntityParent z, thing
		
	Return thing
End Function

Caton

(Posted 2017) [#5]

but what about object rotation?

grable

(Posted 2017) [#6]

Replace MoveEntity with TurnEntity?

Caton

(Posted 2017) [#7]

I know this off topic but I need to fix this error.
Trying to make level list

ListDir=ReadDir("c:\test") 
Repeat
lvfile$=NextFile$(ListDir)
If lvfile$="" Then Exit
If FileType("c:\test"+"\"+lvfile$) = 2 Then
DebugLog("c:\test"+"\"+lvfile$)
list.levlist = New levlist
y=y+1
list\y=y
EndIf
Forever
CloseDir ListDir

Type levlist
field name$,y
End Type

I only have one folder in test but it says three how can I fix this?

grable

(Posted 2017) [#8]

You need to check for "." and ".." too and skip them.

Caton

(Posted 2017) [#9]

I did but it still doesn't work.

ListDir=ReadDir("c:\test") 
Repeat
lvfile$=NextFile$(ListDir)
If lvfile$="" or lvfile$="." or lvfile$=".." Then Exit
If FileType("c:\test"+"\"+lvfile$) = 2 Then
DebugLog("c:\test"+"\"+lvfile$)
list.levlist = New levlist
y=y+1
list\y=y
EndIf
Forever
CloseDir ListDir

Type levlist
field name$,y
End Type

grable

(Posted 2017) [#10]

"." and ".." are the two first elements of a directory, your loop never reaches any further because you exit to early.

Caton

(Posted 2017) [#11]

Still didn't work

ListDir=ReadDir("c:\test") 
Repeat
lvfile$=NextFile$(ListDir)
If lvfile$="" Then Exit
If FileType("c:\test"+"\"+lvfile$) = 2 Then
list.levlist = New levlist
y=y+1
list\y=y
DebugLog("c:\test"+"\"+lvfile$)
EndIf
If lvfile$="." or lvfile$=".." Then Exit
Forever
CloseDir ListDir

Type levlist
field name$,y
End Type

Chalky

(Posted 2017) [#12]

That's because you're still exiting as soon as you find them.

You should only exit if lvfile$ is empty (untested):

ListDir=ReadDir("c:\test") 
Repeat
  lvfile$=NextFile$(ListDir)
  If lvfile$="" Then Exit
  If FileType("c:\test\"+lvfile$) = 2 Then
    If lvfile$<>"." And lvfile$<>".." Then
      list.levlist = New levlist
      y=y+1
      list\y=y
      DebugLog("c:\test\"+lvfile$)
    EndIf
  EndIf
Forever
CloseDir ListDir

Type levlist
  field name$,y
End Type

Caton

(Posted 2017) [#13]

Only will do one object but not other objects

Global controlermode=1
Global LineX,LineY,LineZ,AxlX,AxlY,AxlZ,objectselected
Global ismoving
Const AXLOFFSET# = 5.0
Const MOVE_COEF# = 0.12
Const MOVE_COEF2# = 1.0
AppTitle("Editor")
Graphics3D 800,600,32,2
SetBuffer BackBuffer()
While Not KeyDown( 1 )
Cls
UpdateEditor()
Renderworld()
Updateworld()
Flip
Wend
ClearWorld(True,True,True)
EndGraphics()
End

Function SetupEditor()
CreateEditorCamera()
CreateAxl()
PlaceObject()
End Function

Function PlaceObject()
obj.iobject = new iobject
CreateObject(obj)
End Function

Function ControlEditorCamera()
If KeyDown(205) Then TranslateEntity MainCam,0.3,0,0
If KeyDown(200) Then TranslateEntity MainCam,0,0,0.3
If KeyDown(203) Then TranslateEntity MainCam,-0.3,0,0
If KeyDown(208) Then TranslateEntity MainCam,0,0,-0.3
End Function

Function CreateEditorCamera()
MainCam=CreateCamera()
PositionEntity MainCam,0,20,-15
RotateEntity MainCam,68,0,0
End Function

Function CreateObject(obj.iobject,x#=0,y#=0,z#=0)
obj\mesh=CreateCube()
If obj\mesh Then
EntityPickMode obj\mesh,2
PositionEntity obj\mesh,x#,y#,z#
FlipMesh obj\mesh
EndIf
End Function

Function UpdateEditor()
If controlermode=2 Then controlermode=0
If KeyHit(2) Then controlermode=controlermode+1
ControlEditorCamera()
ControlAxl()
End Function

Function ControlAxl()
If MouseDown(1) Then
		If Not ismoving Then
		objectselected=0
			If CameraPick( Maincam, MouseX(), MouseY()) Then
If PickedEntity() Then objectselected=1
				Local e = PickedEntity()
				Local t = GetEntityType(e)
				If t >= 1 And t <= 3 Then
					ismoving = t
					MouseXSpeed()
					MouseYSpeed()
				EndIf
			EndIf
		EndIf
		Select ismoving
			Case 1	
            For obj.iobject = Each iobject
         Select controlermode
            Case 1
			MoveEntity obj\mesh, 0, -MouseYSpeed() * MOVE_COEF, 0
			Case 2
			TurnEntity obj\mesh, 0, -MouseYSpeed() * MOVE_COEF2, 0
			End Select
			PositionEntity AxlX,AXLOFFSET#+EntityX(obj\mesh),EntityY(obj\mesh),EntityZ(obj\mesh)
			PositionEntity AxlY,EntityX(obj\mesh),AXLOFFSET#+EntityY(obj\mesh),EntityZ(obj\mesh)
			PositionEntity AxlZ,EntityX(obj\mesh),EntityY(obj\mesh),-AXLOFFSET#+EntityZ(obj\mesh)
			Next
			Case 2
			For obj.iobject = Each sobject
			Select controlermode
            Case 1
			MoveEntity obj\mesh, MouseXSpeed() * MOVE_COEF , 0, 0
			Case 2
			TurnEntity obj\mesh, MouseXSpeed() * MOVE_COEF2 , 0, 0
			End Select
			PositionEntity AxlX,AXLOFFSET#+EntityX(obj\mesh),EntityY(obj\mesh),EntityZ(obj\mesh)
			PositionEntity AxlY,EntityX(obj\mesh),AXLOFFSET#+EntityY(obj\mesh),EntityZ(obj\mesh)
			PositionEntity AxlZ,EntityX(obj\mesh),EntityY(obj\mesh),-AXLOFFSET#+EntityZ(obj\mesh)
			Next
			Case 3
			For obj.iobject = Each sobject
			Select controlermode
            Case 1
			MoveEntity obj\mesh, 0, 0, -MouseYSpeed() * MOVE_COEF
			Case 2
			TurnEntity obj\mesh, 0, 0, -MouseYSpeed() * MOVE_COEF2
			End Select
			PositionEntity AxlX,AXLOFFSET#+EntityX(obj\mesh),EntityY(obj\mesh),EntityZ(obj\mesh)
			PositionEntity AxlY,EntityX(obj\mesh),AXLOFFSET#+EntityY(obj\mesh),EntityZ(obj\mesh)
			PositionEntity AxlZ,EntityX(obj\mesh),EntityY(obj\mesh),-AXLOFFSET#+EntityZ(obj\mesh)
			Next
		End Select
	ElseIf ismoving Then
		ismoving = 0
	EndIf

Select objectselected
Case 0
PositionEntity AxlX,0,0,0
PositionEntity AxlY,0,0,0
PositionEntity AxlZ,0,0,0
HideEntity AxlX
HideEntity AxlY
HideEntity AxlZ
Case 1
ShowEntity AxlX
ShowEntity AxlY
ShowEntity AxlZ
For obj.iobject = Each sobject
PositionEntity AxlX,AXLOFFSET#+EntityX(obj\mesh),EntityY(obj\mesh),EntityZ(obj\mesh)
PositionEntity AxlY,EntityX(obj\mesh),AXLOFFSET#+EntityY(obj\mesh),EntityZ(obj\mesh)
PositionEntity AxlZ,EntityX(obj\mesh),EntityY(obj\mesh),-AXLOFFSET#+EntityZ(obj\mesh)
Next
End Select
End Function

Type iobject
Field pitch#,yaw#,roll#,x#,y#,z#
Field mesh,entity,texture
End Type

Function CreateAxl()	
	AxlY = CreateCone()
	ScaleEntity AxlY, 0.5, 0.7, 0.5
	EntityColor AxlY, 255,0,0
	EntityPickMode AxlY, 3
	EntityType AxlY, 1
	HideEntity AxlY
	
	LineY = CreateCylinder()
	PositionEntity LineY,0,-2,0
	ScaleEntity LineY, 0.1, 1.5, 0.1
	EntityColor LineY, 255,0,0
	EntityPickMode LineY, 3
	EntityType LineY, 2
	EntityParent LineY,AxlY
		
	AxlX = CreateCone()
	ScaleEntity AxlX, 0.5, 0.7, 0.5
	RotateEntity AxlX,-90,90,0
	EntityColor AxlX, 0,255,0
	EntityPickMode AxlX, 3
	EntityType AxlX, 2
	HideEntity AxlX
	
	LineX = CreateCylinder()
	PositionEntity LineX,-2,0,0
	ScaleEntity LineX, 0.1, 1.5, 0.1
	RotateEntity LineX,90,90,0
	EntityColor LineX, 0,255,0
	EntityPickMode LineX, 3
	EntityType LineX, 2
	EntityParent LineX,AxlX
		
	AxlZ = CreateCone()
	ScaleEntity AxlZ, 0.5, 0.7, 0.5
	EntityColor AxlZ, 0,0,255
	RotateEntity AxlZ,90,180,0
	EntityPickMode AxlZ, 3
	EntityType AxlZ, 3
	HideEntity AxlZ
	
	LineZ = CreateCylinder()
	PositionEntity LineZ,0,0,2
	ScaleEntity LineZ, 0.1, 1.5, 0.1
	RotateEntity LineZ,90,0,0
	EntityColor LineZ, 0,0,255
	EntityPickMode LineZ, 3
	EntityType LineZ, 2
	EntityParent LineZ,AxlZ
	
	ObjBox = CreateCube()
	PositionEntity ObjBox,0,0,5
	ScaleEntity ObjBox,0.7,0.7,0.7
	EntityColor ObjBox,111,55,38
	EntityAlpha ObjBox,0.5
	EntityPickMode ObjBox, 3
	EntityType ObjBox, 2
	EntityParent ObjBox,AxlZ
End Function

Chalky

(Posted 2017) [#14]

1.
Did the code I posted for you in #12 work?

2.
If you're posting as much code as you have in #13 it's probably better to use [codebox][/codebox] than [code][/code].

3.
Did you write the code in #13 yourself - or are you trying to adapt someone else's? I assume you want to know why only one object is getting processed in the For/Next loop? Could you please highlight where in your code are you creating multiple objects?

Repeatedly posting chunks of code with a vague question/statement is not likely to get much response - particularly if you do not acknowledge people's efforts to help.

Caton

(Posted 2017) [#15]

Yep the level list works now.

grable's code

Graphics3D 800,600

Global cam = CreateCamera()
MoveEntity cam, 0,5, -10

Global thing = MakeThingy()

PointEntity cam, thing

Const MOVE_COEF# = 0.10

Global ismoving
Global movingent

Repeat
	
	If MouseDown(1) Then
		If Not ismoving Then
			If CameraPick( cam, MouseX(), MouseY()) Then
				Local e = PickedEntity()
				Local t = GetEntityType(e)
				If t >= 1 And t <= 3 Then
					ismoving = t
					movingent = thing
					MouseXSpeed()
					MouseYSpeed()
				EndIf
			EndIf
		EndIf
		Select ismoving
			Case 1	MoveEntity movingent, 0, -MouseYSpeed() * MOVE_COEF, 0
			Case 2	MoveEntity movingent, MouseXSpeed() * MOVE_COEF , 0, 0
			Case 3	MoveEntity movingent, 0, 0, -MouseYSpeed() * MOVE_COEF
		End Select
	ElseIf ismoving Then
		ismoving = 0
		movingent = 0
	EndIf

	RenderWorld
	Flip
	Cls

Until KeyHit(1)
End


Function MakeThingy()
	Local thing = CreateCube()
	
	Local y = CreateCube()
	ScaleEntity y, 0.25, 1, 0.25
	EntityColor y, 255,0,0
	MoveEntity y, 0,1,0
	EntityPickMode y, 3
	EntityType y, 1
	EntityParent y, thing
	
	Local x = CreateCube()
	ScaleEntity x, 1, 0.25, 0.25
	EntityColor x, 0,255,0
	MoveEntity x, 1,0,0
	EntityPickMode x, 3
	EntityType x, 2
	EntityParent x, thing
		
	Local z = CreateCube()
	ScaleEntity z, 0.25, 0.25, 1
	EntityColor z, 0,0,255
	MoveEntity z, 0,0,-1
	EntityPickMode z, 3
	EntityType z, 3
	EntityParent z, thing
		
	Return thing
End Function

My code

Global controlermode=1
Global LineX,LineY,LineZ,AxlX,AxlY,AxlZ,objectselected
Global ismoving
Const AXLOFFSET# = 5.0
Const MOVE_COEF# = 0.12
Const MOVE_COEF2# = 1.0
AppTitle("Editor")
Graphics3D 800,600,32,2
SetBuffer BackBuffer()
While Not KeyDown( 1 )
Cls
UpdateEditor()
Renderworld()
Updateworld()
Flip
Wend
ClearWorld(True,True,True)
EndGraphics()
End

Function SetupEditor()
CreateEditorCamera()
CreateAxl()
PlaceObject()
End Function

Function PlaceObject()
obj.iobject = new iobject
CreateObject(obj)
End Function

Function ControlEditorCamera()
If KeyDown(205) Then TranslateEntity MainCam,0.3,0,0
If KeyDown(200) Then TranslateEntity MainCam,0,0,0.3
If KeyDown(203) Then TranslateEntity MainCam,-0.3,0,0
If KeyDown(208) Then TranslateEntity MainCam,0,0,-0.3
End Function

Function CreateEditorCamera()
MainCam=CreateCamera()
PositionEntity MainCam,0,20,-15
RotateEntity MainCam,68,0,0
End Function

Function CreateObject(obj.iobject,x#=0,y#=0,z#=0)
obj\mesh=CreateCube()
If obj\mesh Then
EntityPickMode obj\mesh,2
PositionEntity obj\mesh,x#,y#,z#
FlipMesh obj\mesh
EndIf
End Function

Function UpdateEditor()
If controlermode=2 Then controlermode=0
If KeyHit(2) Then controlermode=controlermode+1
ControlEditorCamera()
ControlAxl()
End Function

Function ControlAxl()
If MouseDown(1) Then
		If Not ismoving Then
		objectselected=0
			If CameraPick( Maincam, MouseX(), MouseY()) Then
If PickedEntity() Then objectselected=1
				Local e = PickedEntity()
				Local t = GetEntityType(e)
				If t >= 1 And t <= 3 Then
					ismoving = t
					MouseXSpeed()
					MouseYSpeed()
				EndIf
			EndIf
		EndIf
		Select ismoving
			Case 1	
            For obj.iobject = Each sobject
         Select controlermode
            Case 1
			MoveEntity obj\mesh, 0, -MouseYSpeed() * MOVE_COEF, 0
			Case 2
			TurnEntity obj\mesh, 0, -MouseYSpeed() * MOVE_COEF2, 0
			End Select
			PositionEntity AxlX,AXLOFFSET#+EntityX(obj\mesh),EntityY(obj\mesh),EntityZ(obj\mesh)
			PositionEntity AxlY,EntityX(obj\mesh),AXLOFFSET#+EntityY(obj\mesh),EntityZ(obj\mesh)
			PositionEntity AxlZ,EntityX(obj\mesh),EntityY(obj\mesh),-AXLOFFSET#+EntityZ(obj\mesh)
			Next
			Case 2
			For obj.iobject = Each sobject
			Select controlermode
            Case 1
			MoveEntity obj\mesh, MouseXSpeed() * MOVE_COEF , 0, 0
			Case 2
			TurnEntity obj\mesh, MouseXSpeed() * MOVE_COEF2 , 0, 0
			End Select
			PositionEntity AxlX,AXLOFFSET#+EntityX(obj\mesh),EntityY(obj\mesh),EntityZ(obj\mesh)
			PositionEntity AxlY,EntityX(obj\mesh),AXLOFFSET#+EntityY(obj\mesh),EntityZ(obj\mesh)
			PositionEntity AxlZ,EntityX(obj\mesh),EntityY(obj\mesh),-AXLOFFSET#+EntityZ(obj\mesh)
			Next
			Case 3
			For obj.iobject = Each sobject
			Select controlermode
            Case 1
			MoveEntity obj\mesh, 0, 0, -MouseYSpeed() * MOVE_COEF
			Case 2
			TurnEntity obj\mesh, 0, 0, -MouseYSpeed() * MOVE_COEF2
			End Select
			PositionEntity AxlX,AXLOFFSET#+EntityX(obj\mesh),EntityY(obj\mesh),EntityZ(obj\mesh)
			PositionEntity AxlY,EntityX(obj\mesh),AXLOFFSET#+EntityY(obj\mesh),EntityZ(obj\mesh)
			PositionEntity AxlZ,EntityX(obj\mesh),EntityY(obj\mesh),-AXLOFFSET#+EntityZ(obj\mesh)
			Next
		End Select
	ElseIf ismoving Then
		ismoving = 0
	EndIf

Select objectselected
Case 0
PositionEntity AxlX,0,0,0
PositionEntity AxlY,0,0,0
PositionEntity AxlZ,0,0,0
HideEntity AxlX
HideEntity AxlY
HideEntity AxlZ
Case 1
ShowEntity AxlX
ShowEntity AxlY
ShowEntity AxlZ
For obj.iobject = Each iobject
PositionEntity AxlX,AXLOFFSET#+EntityX(obj\mesh),EntityY(obj\mesh),EntityZ(obj\mesh)
PositionEntity AxlY,EntityX(obj\mesh),AXLOFFSET#+EntityY(obj\mesh),EntityZ(obj\mesh)
PositionEntity AxlZ,EntityX(obj\mesh),EntityY(obj\mesh),-AXLOFFSET#+EntityZ(obj\mesh)
Next
End Select
End Function

Type iobject
Field pitch#,yaw#,roll#,x#,y#,z#
Field mesh,entity,texture
End Type

Function CreateAxl()	
	AxlY = CreateCone()
	ScaleEntity AxlY, 0.5, 0.7, 0.5
	EntityColor AxlY, 255,0,0
	EntityPickMode AxlY, 3
	EntityType AxlY, 1
	HideEntity AxlY
	
	LineY = CreateCylinder()
	PositionEntity LineY,0,-2,0
	ScaleEntity LineY, 0.1, 1.5, 0.1
	EntityColor LineY, 255,0,0
	EntityPickMode LineY, 3
	EntityType LineY, 2
	EntityParent LineY,AxlY
		
	AxlX = CreateCone()
	ScaleEntity AxlX, 0.5, 0.7, 0.5
	RotateEntity AxlX,-90,90,0
	EntityColor AxlX, 0,255,0
	EntityPickMode AxlX, 3
	EntityType AxlX, 2
	HideEntity AxlX
	
	LineX = CreateCylinder()
	PositionEntity LineX,-2,0,0
	ScaleEntity LineX, 0.1, 1.5, 0.1
	RotateEntity LineX,90,90,0
	EntityColor LineX, 0,255,0
	EntityPickMode LineX, 3
	EntityType LineX, 2
	EntityParent LineX,AxlX
		
	AxlZ = CreateCone()
	ScaleEntity AxlZ, 0.5, 0.7, 0.5
	EntityColor AxlZ, 0,0,255
	RotateEntity AxlZ,90,180,0
	EntityPickMode AxlZ, 3
	EntityType AxlZ, 3
	HideEntity AxlZ
	
	LineZ = CreateCylinder()
	PositionEntity LineZ,0,0,2
	ScaleEntity LineZ, 0.1, 1.5, 0.1
	RotateEntity LineZ,90,0,0
	EntityColor LineZ, 0,0,255
	EntityPickMode LineZ, 3
	EntityType LineZ, 2
	EntityParent LineZ,AxlZ
	
	ObjBox = CreateCube()
	PositionEntity ObjBox,0,0,5
	ScaleEntity ObjBox,0.7,0.7,0.7
	EntityColor ObjBox,111,55,38
	EntityAlpha ObjBox,0.5
	EntityPickMode ObjBox, 3
	EntityType ObjBox, 2
	EntityParent ObjBox,AxlZ
End Function

Caton

(Posted 2017) [#16]

umm... so why is it doing it wrong moving only one object?

dna	(Posted 2017) [#17]

I get a memory access violation

Caton

(Posted 2017) [#18]

your debugger is off.

grable

(Posted 2017) [#19]

I tried your latest code, but it doesnt even compile, and even after making it compile its not setup correctly.

Anyway...
You are confusing the various objects you are selecting and moving, i assume you dont want to move ALL objects like you are attempting to do (with all those For loops), lots of redundant code.

Heres what i got after some fixing, i added creation of new objects with space. Also i added some indentation, as i could not read it without.
Notice that the first mousedown has 2 states now, using entity type 0 for the real objects and still 1,2,3 for the axl.


Global controlermode=1
Global LineX,LineY,LineZ,AxlX,AxlY,AxlZ,objectselected
Global ismoving
Global MainCam
Global selectedobj.iobject

Const AXLOFFSET# = 5.0
Const MOVE_COEF# = 0.12
Const MOVE_COEF2# = 1.0

AppTitle("Editor")
Graphics3D 800,600,32,2

SetupEditor()

SetBuffer BackBuffer()
While Not KeyDown( 1 )
	Cls
	
	If KeyHit(57) Then PlaceObject()
	UpdateEditor()
	
	UpdateWorld()
	RenderWorld()
	Flip
Wend
;ClearWorld(True,True,True)
;EndGraphics()
End

Function SetupEditor()
	CreateEditorCamera()
	CreateAxl()
	PlaceObject()
End Function

Function PlaceObject()
	obj.iobject = New iobject
	CreateObject(obj)
End Function

Function ControlEditorCamera()
	If KeyDown(205) Then TranslateEntity MainCam,0.3,0,0
	If KeyDown(200) Then TranslateEntity MainCam,0,0,0.3
	If KeyDown(203) Then TranslateEntity MainCam,-0.3,0,0
	If KeyDown(208) Then TranslateEntity MainCam,0,0,-0.3
End Function

Function CreateEditorCamera()
	MainCam=CreateCamera()
	PositionEntity MainCam,0,20,-15
	RotateEntity MainCam,68,0,0
End Function

Function CreateObject(obj.iobject,x#=0,y#=0,z#=0)
	obj\mesh=CreateCube()
	If obj\mesh Then
		EntityPickMode obj\mesh,2
		PositionEntity obj\mesh,x#,y#,z#
		FlipMesh obj\mesh
	EndIf
End Function

Function UpdateEditor()
	If controlermode=2 Then controlermode=0
	If KeyHit(2) Then controlermode=controlermode+1
	ControlEditorCamera()
	ControlAxl()
End Function

Function ControlAxl()
	If MouseDown(1) Then
		If Not ismoving Then
			If CameraPick( Maincam, MouseX(), MouseY()) Then
				Local e = PickedEntity()
				Local t = GetEntityType(e)
				If t = 0 Then
					; find real object
					For obj.iobject = Each iObject
						If obj\mesh = e Then
							selectedobj = obj
							Goto done
						EndIf
					Next
					.done
					objectselected = selectedobj <> Null
				ElseIf t >= 1 And t <= 3 Then
					If selectedobj <> Null Then						
						ismoving = t
						MouseXSpeed()
						MouseYSpeed()
					EndIf
				EndIf
			Else
				objectselected = 0
				selectedobj = Null
			EndIf
		EndIf
		Select ismoving
			Case 1	
	        	Select controlermode
		            Case 1	MoveEntity selectedobj\mesh, 0, -MouseYSpeed() * MOVE_COEF, 0
					Case 2	TurnEntity selectedobj\mesh, 0, -MouseYSpeed() * MOVE_COEF2, 0
				End Select
			Case 2
				Select controlermode
		            Case 1	MoveEntity selectedobj\mesh, MouseXSpeed() * MOVE_COEF , 0, 0
					Case 2	TurnEntity selectedobj\mesh, MouseXSpeed() * MOVE_COEF2 , 0, 0
				End Select
			Case 3
				Select controlermode
		            Case 1	MoveEntity selectedobj\mesh, 0, 0, -MouseYSpeed() * MOVE_COEF
					Case 2	TurnEntity selectedobj\mesh, 0, 0, -MouseYSpeed() * MOVE_COEF2
				End Select
		End Select
	ElseIf ismoving Then
		ismoving = 0
	EndIf

	Select objectselected
		Case 0
			PositionEntity AxlX,0,0,0
			PositionEntity AxlY,0,0,0
			PositionEntity AxlZ,0,0,0
			HideEntity AxlX
			HideEntity AxlY
			HideEntity AxlZ
		Case 1
			ShowEntity AxlX
			ShowEntity AxlY
			ShowEntity AxlZ
			PositionEntity AxlX,AXLOFFSET#+EntityX(selectedobj\mesh),EntityY(selectedobj\mesh),EntityZ(selectedobj\mesh)
			PositionEntity AxlY,EntityX(selectedobj\mesh),AXLOFFSET#+EntityY(selectedobj\mesh),EntityZ(selectedobj\mesh)
			PositionEntity AxlZ,EntityX(selectedobj\mesh),EntityY(selectedobj\mesh),-AXLOFFSET#+EntityZ(selectedobj\mesh)
	End Select
End Function

Type iobject
	Field pitch#,yaw#,roll#,x#,y#,z#
	Field mesh,entity,texture
End Type

Function CreateAxl()	
	AxlY = CreateCone()
	ScaleEntity AxlY, 0.5, 0.7, 0.5
	EntityColor AxlY, 255,0,0
	EntityPickMode AxlY, 3
	EntityType AxlY, 1
	HideEntity AxlY
	
	LineY = CreateCylinder()
	PositionEntity LineY,0,-2,0
	ScaleEntity LineY, 0.1, 1.5, 0.1
	EntityColor LineY, 255,0,0
	EntityPickMode LineY, 3
	EntityType LineY, 2
	EntityParent LineY,AxlY
		
	AxlX = CreateCone()
	ScaleEntity AxlX, 0.5, 0.7, 0.5
	RotateEntity AxlX,-90,90,0
	EntityColor AxlX, 0,255,0
	EntityPickMode AxlX, 3
	EntityType AxlX, 2
	HideEntity AxlX
	
	LineX = CreateCylinder()
	PositionEntity LineX,-2,0,0
	ScaleEntity LineX, 0.1, 1.5, 0.1
	RotateEntity LineX,90,90,0
	EntityColor LineX, 0,255,0
	EntityPickMode LineX, 3
	EntityType LineX, 2
	EntityParent LineX,AxlX
		
	AxlZ = CreateCone()
	ScaleEntity AxlZ, 0.5, 0.7, 0.5
	EntityColor AxlZ, 0,0,255
	RotateEntity AxlZ,90,180,0
	EntityPickMode AxlZ, 3
	EntityType AxlZ, 3
	HideEntity AxlZ
	
	LineZ = CreateCylinder()
	PositionEntity LineZ,0,0,2
	ScaleEntity LineZ, 0.1, 1.5, 0.1
	RotateEntity LineZ,90,0,0
	EntityColor LineZ, 0,0,255
	EntityPickMode LineZ, 3
	EntityType LineZ, 2
	EntityParent LineZ,AxlZ
	
	ObjBox = CreateCube()
	PositionEntity ObjBox,0,0,5
	ScaleEntity ObjBox,0.7,0.7,0.7
	EntityColor ObjBox,111,55,38
	EntityAlpha ObjBox,0.5
	EntityPickMode ObjBox, 3
	EntityType ObjBox, 2
	EntityParent ObjBox,AxlZ
End Function