[Solved] Alpha Flag and Animated Sprites 3D

Blitz3D Forums/Blitz3D Programming/[Solved] Alpha Flag and Animated Sprites 3D

RustyKristi

(Posted 2016) [#1]

I'm trying to use LoadAnimImage3D in SpriteControl with Textures that has alpha on them (cut out) but cannot get it to work. Masking works but it still does not look good.

@Kryzon
I also tried your solution 10 years ago here:
http://www.blitzbasic.com/Community/post.php?topic=64426&post=720004

but it still does not work, image is messed up :/

@Jim Brown?
Any ideas? thanks.
http://www.blitzbasic.com/codearcs/codearcs.php?code=456

RemiD

(Posted 2016) [#2]

You could use a quad+texture and load your texture with loadtexture("texture.png",1+2,framescount) and write the alpha value of each texel with your own procedure
and then use EntityTexture(Mesh,Texture,FrameN-1) to texture your mesh

what are you trying to achieve with this sprite control lib ?

RustyKristi

(Posted 2016) [#3]

Just basic UI and hud stuff with alphas on them. Gave up on Sprite Control, it seems it has no direct alpha support.

I will just look for another replacement. Thanks RemiD.

RemiD

(Posted 2016) [#4]

@RustyKristi>>btw, if you want to create your own HUD/GUI system you can use images, as long as there are not too many and they are not too big, it will be fast enough.

see this simple test : (old code, a little ugly)

Graphics3D(1024,768,32,2)

SeedRnd(MilliSecs())

Const COn% = 1
Const COff% = 2

Const CYes% = 1
Const CNo% = 2

Const CUp% = 1
Const CToDown% = 2
Const CDown% = 3
Const CToUp% = 4

Global MPX% = 0
Global MPY% = 0
Global MXDiff% = 0
Global MYDiff% = 0

;Fonts
Global Arial12Font = LoadFont("Arial",12,False,False,False)
Global Arial15Font = LoadFont("Arial",15,False,False,False)
Global Arial20Font = LoadFont("Arial",20,False,False,False)

;Origine
Global Origine = CreateCube()
ScaleMesh(Origine,0.01/2,0.01/2,0.01/2)
EntityColor(Origine,255,000,255)
EntityFX(Origine,1)

;Camera
Global Camera = CreateCamera()
CameraRange(Camera,0.1,100)
CameraClsColor(Camera,000,000,000)

Const C2D% = 1
Const C3D% = 2
Global InteractionMode%
InitializeInteractionMode()

;Ground
Global GroundMesh
BuildGround()

Global ThingsCount% = 0
Dim ThingMesh(100)
Dim ThingSelectionState%(100)

BuildThings() 
UpdateThingsAppearances()

Global GUIBackgroundR% = 100
Global GUIBackgroundG% = 100
Global GUIBackgroundB% = 100
Global GUITextR% = 150
Global GUITextG% = 150
Global GUITextB% = 150
Global GUIBorderR% = 125
Global GUIBorderG% = 125
Global GUIBorderB% = 125

Local WindowsMaxCount% = 100
Global WindowsCount% = 0
Dim WindowNameInt%(WindowsMaxCount)
Dim WindowImageMNO(WindowsMaxCount)
Dim WindowImageMO(WindowsMaxCount)
Dim WindowPX%(WindowsMaxCount)
Dim WindowPY%(WindowsMaxCount)
Dim WindowPWidth%(WindowsMaxCount)
Dim WindowPHeight%(WindowsMaxCount)
Dim WindowZOrder%(WindowsMaxCount)
Dim WindowDisplayState%(WindowsMaxCount) ;COn or COff
Dim WindowOverableState%(WindowsMaxCount) ;COn or COff
Dim WindowOveredState%(WindowsMaxCount) ;CYes or CNo
;Dim WindowClickableState%(WindowsMaxCount) ;COn or COff 
;Dim WindowClickedState%(WindowsMaxCount) ;CYes or CNo
;Dim WindowHeldableState%(WindowsMaxCount) ;COn or COff
;Dim WindowHeldState%(WindowsMaxCount) ;CYes or CNo

BuildWindows()

DLight = CreateLight(1)
LightColor(DLight,255,255,255)
PositionEntity(DLight,50,1000,-1000)
RotateEntity(DLight,45,0,0)

AmbientLight(025,025,025)

PositionEntity(Camera,50,50,-25,True)
RotateEntity(Camera,45,0,0,True)

Main()

End()

Function Main()
 While( KeyDown(1) <> 1 )

  MainloopMsStart% = MilliSecs()

  GetInput()

  If( InteractionMode = C3D )
   UpdateInteractionMode()
  ElseIf( InteractionMode = C2D )
   UpdateInteractionMode()
   UpdateWindows()
  EndIf

  WireFrame(False)
  If(KeyDown(2)=1)
   WireFrame(True)
  EndIf

  Render3dMsStart% = MilliSecs()
  SetBuffer(BackBuffer())
  ClsColor(000,000,000)
  Cls()
  RenderWorld()
  Render3dMsTime% = MilliSecs() - Render3dMsStart

  If( InteractionMode = C2D ) 
   Draw2DElementsMsStart% = MilliSecs()
   DrawWindows()
   Draw2DElementsMsTime% = MilliSecs() - Draw2DElementsMsStart
  Else If( InteractionMode = C3D )
   Draw2DElementsMsTime% = 0
  EndIf

  SetFont(Arial15Font)
  Color(255,255,255)
  CText("Triangles = "+Str(TrisRendered()),0,0)
  CText("FPS = "+Str(FPS),0,15)
  CText("Render3dMsTime = "+Str(Render3dMsTime),0,30)
  CText("Draw2DElementsMsTime = "+Str(Draw2DElementsMsTime),0,45)

  Flip(1)

  MainloopMsTime% = MilliSecs() - MainloopMsStart
  If( MainloopMsTime < 0 )
   MainloopMsTime = 1
  EndIf

  FPS% = 1000.0/MainloopMsTime

 Wend
End Function

Function CText(TString$,TPX%,TPY%)
 Text(TPX,TPY,TString,False,False)
End Function

Function PositionRotateEntityLikeOtherEntity(Entity,OtherEntity)
 PositionEntity(Entity,EntityX(OtherEntity,True),EntityY(OtherEntity,True),EntityZ(OtherEntity,True))
 RotateEntity(Entity,EntityPitch(OtherEntity,True),EntityYaw(OtherEntity,True),EntityRoll(OtherEntity,True))
End Function

Function PositionEntityLikeOtherEntity(Entity,OtherEntity)
 PositionEntity(Entity,EntityX(OtherEntity,True),EntityY(OtherEntity,True),EntityZ(OtherEntity,True))
End Function

Function RotateEntityLikeOtherEntity(Entity,OtherEntity)
 RotateEntity(Entity,EntityPitch(OtherEntity,True),EntityYaw(OtherEntity,True),EntityRoll(OtherEntity,True))
End Function

Function GetInput()

 ;Mouse pointer properties
 MXDiff = MouseXSpeed()  
 MYDiff = MouseYSpeed() 
 MPX = MouseX()
 MPY = MouseY()

End Function

Function BuildGround()
 GroundMesh = CreateCube()
 ScaleMesh(GroundMesh,100.0/2,0.001/2,100.0/2)
 PositionEntity(GroundMesh,100.0/2,-0.001/2,100.0/2)
 EntityColor(GroundMesh,125,125,125)
 NameEntity(GroundMesh,"GRO"+Str(1))
End Function

Function InitializeInteractionMode()
 InteractionMode = C3D
 HidePointer()
End Function

Function UpdateInteractionMode()
 If(KeyHit(15)=1)
  If( InteractionMode = C2D )
   InteractionMode = C3D
   HidePointer()
  ElseIf( InteractionMode = C3D )
   InteractionMode = C2D
   ShowPointer()
  EndIf
  FlushKeys()
 EndIf
End Function

Function InteractionModeModeStr$()
 TStr$ = ""
 If( InteractionMode = C2D )
  TStr = "2D"
 ElseIf( ControlMode = C3D )
  TStr = "3D"
 EndIf
 Return TStr
End Function

Function BuildThings()
 For n% = 1 To 100
  ThingsCount = ThingsCount + 1
  I% = ThingsCount
  ThingMesh(I) = CreateCube()
  ScaleMesh(ThingMesh(I),1.0/2,1.0/2,1.0/2)
  PositionMesh(ThingMesh(I),0,1.0/2,0)
  PositionEntity(ThingMesh(I),Rand(0,99)+0.5,0,Rand(0,99)+0.5)
  EntityColor(ThingMesh(I),Rand(025,250),Rand(025,250),Rand(025,250))
  NameEntity(ThingMesh(I),"THI"+Str(n))
  ThingSelectionState(I) = Rand(1,2)
 Next
End Function

Function UpdateThingsAppearances()
 For I% = 1 To ThingsCount
  EntityAlpha(ThingMesh(I),1.0)
  If(ThingSelectionState(I) = CYes)
   EntityAlpha(ThingMesh(I),0.5)
  EndIf
 Next
End Function

Function BuildWindows()
 For n% = 1 To 100
  WindowsCount = WindowsCount + 1
  WI% = WindowsCount
  TPWidth% = Rand(100,200)
  TPHeight% = Rand(100,200)
  TPX% = Rand(0,GraphicsWidth()-1-TPWidth)
  TPY% = Rand(0,GraphicsHeight()-1-TPHeight)
  WindowImageMNO(WI) = CreateImage(TPWidth,TPHeight)
  WindowPX(WI) = TPX
  WindowPY(WI) = TPY 
  SetBuffer(ImageBuffer(WindowImageMNO(WI)))
   TR% = Rand(050,200)
   TG% = Rand(050,200)
   TB% = Rand(050,200)
   ClsColor(TR,TG,TB)
   Cls()
   Color(TR+050,TG+050,TB+050)
   Line(0,0,TPWidth-1,0)
   Color(TR-025,TG-025,TB-025)
   Line(0,TPHeight-1,TPWidth-1,TPHeight-1)
   Color(TR+025,TG+025,TB+025)
   Line(0,TPHeight-1,0,0)
   Color(TR+025,TG+025,TB+025)
   Line(TPWidth-1,TPHeight-1,TPWidth-1,0)
   TString$ = "Window"+Str(WI)
   TSPWidth% = StringWidth(TString)
   TSPHeight% = StringHeight("X")
   TSPX% = TPWidth/2-TSPWidth/2
   TSPY% = 0 
   Color(TR+050,TG+050,TB+050)
   Text(TSPX,TSPY,TString)
  SetBuffer(BackBuffer())
  WindowDisplayState(WI) = Rand(1,2)
 Next
;Dim WindowNameInt%(WindowsMaxCount)
;Dim WindowImageNO(WindowsMaxCount)
;Dim WindowImageO(WindowsMaxCount)
;Dim WindowPX%(WindowsMaxCount)
;Dim WindowPY%(WindowsMaxCount)
;Dim WindowPWidth%(WindowsMaxCount)
;Dim WindowPHeight%(WindowsMaxCount)
;Dim WindowZOrder%(WindowsMaxCount)
;Dim WindowDisplayState%(WindowsMaxCount) ;COn or COff
;Dim WindowOverableState%(WindowsMaxCount) ;COn or COff
;Dim WindowOveredState%(WindowsMaxCount) ;CYes or CNo
End Function

Function UpdateWindows()
 If(KeyHit(57)=1)
  For WI% = 1 To WindowsCount
   WindowDisplayState(WI) = COff
   RandomChoice% = Rand(1,2)
   If(RandomChoice = 2)
    WindowDisplayState(WI) = COn
   EndIf
  Next
 EndIf
End Function

Function DrawWindows()
 For WI% = 1 To WindowsCount
  If(WindowDisplayState(WI) = COn)
   DrawImage(WindowImageMNO(WI),WindowPX(WI),WindowPY(WI))
  EndIf
 Next
End Function

(press tab to show/hide the 3d world or the 2d world (with the GUI elements), press space to update the "displaystate" of the GUI elements)

Or you can create your own HUD/GUI system using quads+textures, and my recent code here : http://www.blitzbasic.com/Community/posts.php?topic=106954 (post #1)
demonstrates how to create a quad (and texture) which will use the exact same pixels area (width,height) used by an image of the same size (width,height)

RustyKristi

(Posted 2016) [#5]

Thanks again RemiD! Actually I'd prefer existing and ready made gui libs because eventually I will need more functionality but for now I can try these codes.

Kryzon

(Posted 2016) [#6]

Wow, ten years ago. I must've been 16 when I wrote that post. I don't remember much about this, I don't have the files anymore.

Things like that "sprite control" library are for doing 2D-in-3D graphics under a perspective camera, which is a challenge.
With what we have available now this is much easier, like BlitzMax with its Max2D module that does exactly that. You can have pixel-perfect 2D graphics on top of your MiniB3D scene by calling a couple of functions.

RustyKristi

(Posted 2016) [#7]

ha that was really a long time ago! anyway thats ok, yes I'm doing 2D in 3D just like any game with HUDs in it.

I'm putting this on hold while I try RemiD's suggestions.

RemiD

(Posted 2016) [#8]

If your HUD images are small enough, and not many, just draw them on top of your 3dscene rendered image, it will be fast enough (see my code example in post #4)

RustyKristi

(Posted 2016) [#9]

thanks!

RemiD

(Posted 2016) [#10]

another example to create an HUD with a quad + a texture : http://www.blitzbasic.com/codearcs/codearcs.php?code=529