AlignToVector

Blitz3D Forums/Blitz3D Programming/AlignToVector

Yue	(Posted 2016) [#1]

What really makes this command. I appreciate a simple example.

Zethrax

(Posted 2016) [#2]

There's some examples at the link below.

http://www.blitzbasic.com/b3ddocs/command.php?name=AlignToVector&ref=3d_cat

Yue	(Posted 2016) [#3]

Graphics3D ( 800, 600, 32, 2 )
SetBuffer (BackBuffer())



Local camera% 	= CreateCamera()
Local cube1%	= CreateCube()
Local cube2%    = CreateCube()
Local light%    = CreateLight()

PositionEntity 	( cube1%, 0, 0, 10 )
PositionEntity 	( cube2%, 0, 0, 5 )
EntityAlpha cube1%, .5

Local x#, y#, z#

While KeyDown(1) = False 
	
	
	If KeyDown(200) TranslateEntity ( cube2%, 0, 0, .1 ) 
		If KeyDown(208) TranslateEntity ( cube2%, 0, 0, -.1 )
			If KeyDown(203) TranslateEntity ( cube2%, -.1, 0, 0 ) 
				If KeyDown(205) TranslateEntity ( cube2%, .1, 0, 0 )	
			
	
	x# = EntityX( cube2% )
	y# = EntityY( cube2% )
	z# = EntityZ( cube2% )
	
	AlignToVector ( cube1%, x#, y#, z#,0,1)
	
	UpdateWorld
	RenderWorld 
	Flip
	
Wend

Sorry , I do not speak English , I think I need something more simple to understand .

In this case , I see that the organization is aligned with the other, and this is very similar to PointEntity , in this case , this lines up with another entity ?

RemiD

(Posted 2016) [#4]

As i understand it, AlignToVector will align an entity according to a vector, on one specified axis (x,y,z).

This is usually used to align an entity on a terrain (the normal of a triangle of a terrain is a vector), or a decal (example : a bullet hole) on a wall (the normal of a triangle of a wall is a vector)...

You seem to have already used this in your project with the robot on mars, when you align the tracks of the tires according to the terrain relief.

Yue	(Posted 2016) [#5]

What mde Mars Project , unfortunately a lot of code is copied and pasted , but not understood , so I want to understand this.

Kryzon

(Posted 2016) [#6]

Try this:
http://www.blitzbasic.com/Community/posts.php?topic=98358#1148878

AlignToVector rotates the entity so that one of its axes (that you choose as the 'axis' parameter) is aligned with (becomes parallel to) the vector you provided.
The vector you provide is a direction in 3D space. (EDIT: it's actually more than that, but it's simpler to imagine it as just a direction.)

Yue	(Posted 2016) [#7]

@Kryzon
Thanks You.

Try again to understand these commands transformations .

Rick Nasher

(Posted 2016) [#8]

See:

Graphics3D 800,600
SetBuffer BackBuffer()
AppTitle "Super Cube Galaxy"
light=CreateLight();Es werde Licht
TurnEntity light,0,45,0
cam=CreateCamera()
MoveEntity cam,0,0,-5
world=CreateSphere()
EntityColor world,0,200,0
EntityType world,2
MoveEntity world,2,0,0
player=CreateCube()
EntityColor player,255,0,0
ScaleEntity player,.1,.2,.1
MoveEntity player,0,2,0
EntityType player,1
EntityRadius player, .2
Global playeryspeed#
Collisions 1,2,2,2
timer=CreateTimer(60)
While Not KeyHit(1)	
	WaitTimer(timer)	
	AlignToVector player,EntityX(player)-EntityX(world),EntityY(player)-EntityY(world),EntityZ(player)-EntityZ(world),2	
	If EntityCollided(player,2)=0		
		playeryspeed=playeryspeed-0.002	
	Else
		playeryspeed=0
	EndIf
	If KeyHit(57)
		playeryspeed=0.05
	EndIf		
	MoveEntity player,0,playeryspeed,0
	If KeyDown(200)
		MoveEntity player,0,0,.02
	EndIf
	TurnEntity player,0,(KeyDown(203)-KeyDown(205))*3,0
	UpdateWorld()
	RenderWorld()
	Flip 0
Wend
End

aligntovector to create bullet holes using sprites..bb

; Using Aligntovector to make bullet holes

Graphics3D 800,600,0,0

CentreX=GraphicsWidth()/2
CentreY=GraphicsHeight()/2

; bullet hole & spark sprites
hole=CreateSprite()
ScaleSprite hole,0.25,0.25
SpriteViewMode hole,2
EntityBlend hole,2
EntityTexture hole,Cirtex(32)
HideEntity hole

spark=CreateSprite()
ScaleSprite spark,0.1,0.1
EntityBlend spark,3
HideEntity spark

; make environment

AmbientLight 0,0,0

camera=CreateCamera()
PositionEntity camera, 0,-15,0

room=CreatePivot()

Cube=CreateSegCube(12,room)
EntityPickMode cube,2
EntityColor cube,250,100,50
ScaleMesh cube,40,40,40
FlipMesh cube

Column=CreateCylinder(16,True,room)
EntityPickMode column,2
EntityFX column,4
EntityColor column,150,120,120
PositionMesh column,0,1,0
ScaleMesh Column,6,24,6

sphere=CreateSphere(12,column)
EntityShininess sphere,0.25
EntityColor sphere,200,200,50
EntityPickMode sphere,2
ScaleMesh sphere,-6,-6,-6 ; flip normals
PositionMesh sphere,0,54,0

PositionEntity Column,-30,-40,-30
PositionEntity CopyEntity(column,room),30,-40,-30
PositionEntity CopyEntity(column,room),30,-40,30
PositionEntity CopyEntity(column,room),-30,-40,30

; add a few lights

lpiv=CreatePivot(room)
light=CreateLight(2,lpiv) : PositionEntity light,-30,14,-30
light=CreateLight(2,lpiv) : PositionEntity light,30,14,-30
light=CreateLight(2,lpiv) : PositionEntity light,30,14,30
light=CreateLight(2,lpiv) : PositionEntity light,-30,14,30

; load gunshot sound - your path to this may be different.
shot = LoadSound("C:\Program Files\Blitz3D\Samples\Blitz 3D Samples\si\fps\gunshot.wav")

holes  = CreatePivot(room) ; bullet hole list
sparks = CreatePivot(room) ; sparks list

; main ---------------------------------------------------------

MoveMouse CentreX,CentreY

Repeat
	mxs#=MouseXSpeed()
	mys#=MouseYSpeed()

	If MouseDown(2) Then
		MoveEntity camera,0,0,-mys*0.25
	Else
		TurnEntity camera,mys*0.5,0,0 : TurnEntity camera,0,-mxs*0.5,0,True
	EndIf
	
	MoveMouse centrex,centrey
	
	If MouseDown(1) Or KeyHit(57) Then 
		If MilliSecs()>delaytime Then
			delaytime=MilliSecs()+100
			If shot Then PlaySound shot				
			picked=CameraPick(camera, CentreX+Rnd(-10,10),CentreY+Rnd(-10,10))
			If picked<>0 Then
				makehole(hole,holes)
				makespark(spark,sparks)				
			EndIf
		EndIf
	EndIf
	
	updatesparks(sparks)
	
	For i=1 To CountChildren(lpiv)
		light=GetChild(lpiv,i)
		LightRange light,15+Sin((MilliSecs() And $FFFFF)/24+i*90 )*8
	Next
	
	If KeyHit(17) Then wire=Not wire : WireFrame wire
	
	RenderWorld
	Color 255,255,255
	Line centrex-4,centrey,centrex+4,centrey : Line centrex,centrey-4,centrex,centrey+4
	Flip
Until KeyHit(1)

;----------------------------------------------------------------------------------------

Function makehole(hole,holes)
	hole=CopyEntity(hole,holes)
	PositionEntity hole,PickedX(),PickedY(),PickedZ(),True
	AlignToVector hole,-PickedNX(),-PickedNY(),-PickedNZ(),3
	MoveEntity hole,0,0,-0.05
	If CountChildren(holes)>200 Then FreeEntity GetChild(holes,1)
End Function

Function makespark(spark,sparks)
	Local rv#=Rnd(-0.8,0.8)
	spark=CopyEntity(spark,sparks)
	PositionEntity spark,PickedX(),PickedY(),PickedZ(),True
	AlignToVector spark,-PickedNX()+rv,-PickedNY()+rv,-PickedNZ()+rv,3
End Function

Function updatesparks(sparks)
	Local i,life
	For i=1 To CountChildren(sparks)
		spark=GetChild(sparks,i)
		life=EntityName(spark) : life=life+1 : NameEntity spark,life
		MoveEntity spark,0,0,-1 : TranslateEntity spark,0,-life/5.0,0,True
		EntityColor spark,512/life,512/life,512/life
		If life>20 Then FreeEntity spark : i=i-1
	Next
End Function

Function Cirtex(rad)
	texture=CreateTexture(rad,rad)
	SetBuffer TextureBuffer(texture)
	Color 255,255,255 : Rect 0,0,rad,rad,True
	Color 200,200,200 : Oval 0,0,rad,rad,True
	Color 100,100,100 : Oval 12,12,rad-24,rad-24,True
	SetBuffer BackBuffer()
	Return texture
End Function

; Birdies CreateSegCube Function from the archives (slightly modified)
Function CreateSegCube(segs=1,parent=0)
	Local a,b,scnt,stp#=2.0/segs,stx#,sty#,x#,y#,u#,v#,v0,v1,v2
	Local mesh=CreateMesh( parent )
	For scnt=0 To 5
		surf= CreateSurface( mesh )
		stx = -1 : sty = stx : y = sty
		For a=0 To segs
			x = stx : v = a / Float(segs)
			For b=0 To segs
				u = b / Float(segs)
				VertexNormal(surf,AddVertex(surf,x,y,1,u,v),0,0,1) 
				x = x + stp
			Next
			y = y + stp
		Next
		For a=0 To segs-1
			For b=0 To segs-1
				v0 = a*(segs+1)+b       : v1 = v0+1
				v2 = (a+1)*(segs+1)+b+1 : v3 = v2-1
				AddTriangle( surf,v0,v1,v2 )
				AddTriangle( surf,v0,v2,v3 )
			Next
		Next
		If scnt<4 Then RotateMesh mesh,0,90,0  ; rotate to side
		If scnt=3 Then RotateMesh mesh,90,0,0  ; rotate to top
		If scnt>3 Then RotateMesh mesh,180,0,0 ; rotate to bottom
	Next
	Return mesh
End Function

AlignToVector To guide a missile towards a moving target.bb

; Declare global variables used in the code.
Global vx#, vy#, vz#
Global not_collided = True

; Create a timer to do rough and ready logic framerate limiting.
Global timer = CreateTimer( 25 )

; Setup the graphics mode and buffers.
Graphics3D 800, 600, 0, 2
SetBuffer BackBuffer()

; Create a camera, set its focus, and move it offline from world center.
Global cam = CreateCamera()
CameraZoom cam, 1.6
MoveEntity cam, 2.0, 2.0, -10.0

; Create a light.
Global light = CreateLight()

; Create the missile cone.
Global cone = CreateCone()

; Rotate the cone to point along the z axis.
RotateMesh cone, 90.0, 0.0, 0.0

; Update the normals for the missile cone.
UpdateNormals cone

; Create the target cube, update its normals, and set its initial position.
Global cube = CreateCube()
UpdateNormals cube
PositionEntity cube, 20.0, 10.0, 40.0

While Not KeyHit( 1 ) ; Start of the main loop. Pressing the escape key exits the loop.
	
	; If the cone has not yet collided with the cube...
	If not_collided	

		; If a collision has occurred between the cone and the cube...
		If EntityDistance( cube, cone ) < 1.0
		
			; Hide the cone, color the cube red, and set the 'not_collided' variable to false.
			HideEntity cone
			EntityColor cube, 255.0, 0.0, 0.0
			not_collided = False
			
		EndIf	
	
		; Move the target cube.
		MoveEntity cube, -0.22, 0.0, 0.0
		
		; Calculate the vector between the missile cone and the target cube.
		vx# = EntityX( cube ) - EntityX( cone )
		vy# = EntityY( cube ) - EntityY( cone )
		vz# = EntityZ( cube ) - EntityZ( cone )
		
		; Smoothly align the missile cone to the vector.
		AlignToVector( cone, vx#, vy#, vz#, 3, 0.15 )
		
		; Move the missile cone in the direction it is pointing.
		MoveEntity cone, 0.0, 0.0, 0.31
	
	EndIf
	
	UpdateWorld ; Update collisions, animations, etc.
	RenderWorld ; Render the 3D graphics.
	Flip ; Flip the backbuffer to the drawn frontbuffer, and visa versa.
	
	; Wait for a new timer tick. This forces the program to run at the same speed on different systems.
	WaitTimer( timer )

Wend ; End of the main loop.

End ; End the program.

Yue	(Posted 2016) [#9]

I think I'm about to learn something, as happened when I discovered TFormPoint operation.

Then after the image of our friend Kryzon, a vector is a line that runs from the side of a polygon, this line or vector marks the angle looking side, in this case if we have a cube, each side we have two vectors normal for each triangle of the face, and two pointing left (-1) two others point to the right (1), and the same for the top and bottom.

When using this AlignToVector command, what I want is to know the angle at which point these vectors, I repeat myself based on the image, and this will have to do for example with PickedNX, CollisionNX, etc commands, where N tells me is a vector of normal, which is not normal, I think it's the same as a vector.

I'm right ?, in this case when two bodies collide, for example with the CollisionNX command, I can find the angle of rotation of the normal vector and paste a sticker of a shot on the object that receives the collision.

I am right?...

RemiD

(Posted 2016) [#10]

a vector is a line that runs from the side of a polygon

No, this would be a normal. But a normal is a normalized vector.

A vector is a line with a start point and an end point, which has a direction and a length.

A normal is a normalized vector (which means that the length is always 1.0), and is used to shows a direction. (Where the triangle looks at, to where it faces)

For collisions, a collided normal vector is useful if you want to calculate a "reflection angle", like with pool or marbles.

For movements, a vector is useful to translate an entity in the world, for example i have made a spaceship exploration/fighting game prototype in which the spaceship turns/moves with angularvelocities and linearvelocities, similarly to a body in a physics engine.

Vectors are also used to calculate lighting/shading of the vertices or of the texels in an environment. ("vertexlighting" or "texellighting" (also know as "lightmapping"))

Yue	(Posted 2016) [#11]

@RemiD

You have given me the respuesto why never do a video game. I think it's time ebandonar this and keep what if I can do .

The translator is not much help .

Rick Nasher

(Posted 2016) [#12]

This might be helpful:
CREATING AND USING NORMAL MAPS - A Tutorial

RemiD

(Posted 2016) [#13]

(maybe it is my english that is bad and not understood by the translator !)

Yue	(Posted 2016) [#14]

These are normal two vectors?

Rick Nasher

(Posted 2016) [#15]

Hmm, never heard of that, but I'm not an expert on this too."Learning all the time.."( as Benny Hill would say). That probably only applies when a surface has a backface(please correct me if I'm wrong).

RemiD

(Posted 2016) [#16]

With Blitz3d (or maybe it is a directx 7 thing) the normal is a normalized vector perpendicular to the "frontface" of the triangle.

If you try to light a backface you will see how the vertices lighting is not calculated properly on the backface... So i suppose that the considered normal is the one of the frontface.

Yue	(Posted 2016) [#17]

Trying to understand the concept of vector.

A vector is a line that is perpendicular to another vector in a plane, or a polygon , or a triangle ?

Yue	(Posted 2016) [#18]

Vector:

Definition: In a 3D space , a vector is a segment of a straight line placed at any point in a certain direction.

Normal.

Definition : A normal is a vector that is perpendicular to a polygon .

Definition: A normal is a vector perpendicular to any polygon .

Perpendicular.

So this shows me that AlignToVector command , aligns the axes of an entity with the axes of another entity , in this case a normal shaft alignment for example a stain sprite of a bullet in a building vector.

:)

Thanks You Guys.