sending a long string in chunks to a type field

Blitz3D Forums/Blitz3D Programming/sending a long string in chunks to a type field

stayne

(Posted 2015) [#1]

I need to send each part (string) of a long sentence, that will be word-wrapped, to a type field then draw them with Draw3D's Text3D function since the latest version doesn't offer word wrap. I'm going to include the two functions I have lined up for this:


Type msg
	Field s$
	Field col
	Field timer
End Type

Function UpdateChat()

	If KeyDown(56) ;quick hack to drag the text around
		chatx = MouseX()-GraphicsWidth()/2
		chaty = -(MouseY()-GraphicsHeight()/2)
	EndIf

	tel = 0
	For m.msg = Each msg
		Text3D(Font,chatx,chaty-tel * textheight - scroll,m\s$,0)
		tel = tel + 1
		If tel = 14 Then Exit
	Next
	
	If scrollmode Then
		If scroll <= chatscroll Then scroll = scroll + 8;speed
		If scroll > chatscroll Then 
			scroll = 0
			Delete First msg
			scrollmode = 0
			chatscroll = 0
		End If
	Else
		If chatscroll = 0 Then If tel > 13 Then chatscroll = chatscroll + textheight: scrollmode = 1
	End If
	
	;For m.msg = Each msg
	;	If m\timer < MilliSecs() Then Delete m
	;Next

End Function

;-----------------------------------------------------------------------------------------------------
;													AddChat()
;-----------------------------------------------------------------------------------------------------
Function AddChat(s$)

	m.msg = New msg
	m\s$ = s$
	m\timer = MilliSecs() + 10000

End Function

I'm adding sentences via AddChat and some of them are pretty long. So...any ideas to break the strings up and wrap them? Sorry this is a bit enigmatic.

Midimaster

(Posted 2015) [#2]

With INSTR() you can look for a SPACE character With LEFT() and MID() you can divide the string.

Test$="abc def ghijk l mno"
Here%=0
Part$=""
Repeat 
    Here=Instr(Test," ")
    If Here=0
        Part=Test
    Else
       Part= Left(Test,Here-1)
    EndIf
    Print "PART=" + Part 
    Test=Mid(Test,Here+1)
Until Here=0

If you want to cut sentences longer than f.e. 30 characters, add a OFFSET test:

Test$="abc def ghijk l mno  fjgj jgjr rjghj jjtiu djjgj djfjg jglvjbls  jjgj esk"
Here%=0
Offset%=30
Part$=""
Repeat 
    NextHere%=0
    Here=0
    Repeat
        Here=Instr(Test," ",Here+1)
        NextHere=Instr(Test," ",Here+1)
    Until NextHere>Offset Or Here=0 Or NextHere=0
    If NextHere=0
        Part=Test
    Else
       Part= Left(Test,Here-1)
    EndIf
    Print "PART=" + Part + " (LEN=" + Len(Part) +")"
    Test=Mid(Test,Here+1)
Until NextHere=0

Bobysait

(Posted 2015) [#3]

here is two methods to split sentence
the first use only the width of the chatbox
the second use logic splitters to split sentence while preserving words at best. (uses ., and space, but you can add :; etc ...)

You might want to fit MSG_MAX_LINES to your needs. Basically, it's the maximum number of lines available for a message.


Global lorem_ipsum1$	= "  Lorem ipsum dolor sit amet, consectetur adipiscing elit. Sed non risus. Suspendisse lectus tortor,"
lorem_ipsum1=lorem_ipsum1+" dignissim sit amet, adipiscing nec, ultricies sed, dolor. Cras elementum ultrices diam. Maecenas"
lorem_ipsum1=lorem_ipsum1+" ligula massa, varius a, semper congue, euismod non, mi. Proin porttitor, orci nec nonummy molestie,"
lorem_ipsum1=lorem_ipsum1+" enim est eleifend mi, non fermentum diam nisl sit amet erat. Duis semper. Duis arcu massa, scelerisque"
lorem_ipsum1=lorem_ipsum1+" vitae, consequat in, pretium a, enim. Pellentesque congue. Ut in risus volutpat libero pharetra tempor."
Global lorem_ipsum2$	=" Cras vestibulum bibendum augue. Praesent egestas leo in pede. Praesent blandit odio eu enim."
lorem_ipsum2=lorem_ipsum2+" Pellentesque sed dui ut augue blandit sodales. Vestibulum ante ipsum primis in faucibus orci luctus"
lorem_ipsum2=lorem_ipsum2+" et ultrices posuere cubilia Curae; Aliquam nibh. Mauris ac mauris sed pede pellentesque fermentum."
lorem_ipsum2=lorem_ipsum2+" Maecenas adipiscing ante non diam sodales hendrerit."
lorem_ipsum2=lorem_ipsum2+"Ut velit mauris, egestas sed, gravida nec, ornare ut, mi. Aenean ut orci vel massa suscipit pulvinar."
Global lorem_ipsum3$	=" Nulla sollicitudin. Fusce varius, ligula non tempus aliquam, nunc turpis ullamcorper nibh, in tempus"
lorem_ipsum3=lorem_ipsum3+" sapien eros vitae ligula. Pellentesque rhoncus nunc et augue. Integer id felis. Curabitur aliquet"
lorem_ipsum3=lorem_ipsum3+" pellentesque diam. Integer quis metus vitae elit lobortis egestas. Lorem ipsum dolor sit amet,"
lorem_ipsum3=lorem_ipsum3+" consectetuer adipiscing elit. Morbi vel erat non mauris convallis vehicula. Nulla et sapien. Integer"
lorem_ipsum3=lorem_ipsum3+" tortor tellus, aliquam faucibus, convallis id, congue eu, quam. Mauris ullamcorper felis vitae erat."
Global lorem_ipsum4$	=" Proin feugiat, augue non elementum posuere, metus purus iaculis lectus, et tristique ligula justo vitae"
lorem_ipsum4=lorem_ipsum4+" magna. Aliquam convallis sollicitudin purus. Praesent aliquam, enim at fermentum mollis, ligula massa"
lorem_ipsum4=lorem_ipsum4+" adipiscing nisl, ac euismod nibh nisl eu lectus. Fusce vulputate sem at sapien. Vivamus leo. Aliquam"
lorem_ipsum4=lorem_ipsum4+" euismod libero eu enim. Nulla nec felis sed leo placerat imperdiet. Aenean suscipit nulla in justo."
lorem_ipsum4=lorem_ipsum4+" Suspendisse cursus rutrum augue. Nulla tincidunt tincidunt mi. Curabitur iaculis, lorem vel rhoncus"
lorem_ipsum4=lorem_ipsum4+" faucibus, felis magna fermentum augue, et ultricies lacus lorem varius purus. Curabitur eu amet."

Const MSG_MAX_LINES% = 8
Type MSG
	Field s$[MSG_MAX_LINES]
	Field count%
End Type

; don't care about the words as words, just care about the width
Function addMsg(s$, chatwidth%)
	
	If Trim(s)="" Then Return;
	
	Local m.MSG = New MSG;
	Local LS% = Len(s);
	Local offsetL%=1;
	Local p1$="", pw, i%, c$, cs%
	
	Repeat
		p1 = "" : pw = 0;
		For offsetL = offsetL To LS
			c = Mid(s, offsetL,1) : cs% = StringWidth(c);
			If pw + cs>=chatwidth Then Exit;
			pw = pw + cs : p1 = p1+c;
		Next
		
		m\count=m\count+1
		m\s[m\count-1]=p1;
		If m\count>=MSG_MAX_LINES Then Exit;
		
	Until offsetL>=LS;
	
End Function

; uses the ".", "," or " " as splitter for words
Function addMsg2(s$, chatwidth%)
	
	If Trim(s)="" Then Return;
	Local AOffset = chatwidth/StringWidth("A") - 1;
	Local BOffset = AOffset-15; '15' is an arbitrary number of chars at the end of the line to search for special characters.
	
	Local m.MSG = New MSG;
	
	While Len(s)>AOffset
		
		Local partLeft$ = "";
		Local found% = False;
		Local ofs = 0;
		For c = AOffset To BOffset Step -1
			Select Mid(s, c,1)
			Case " ", ",", "."
				ofs = c;
				Exit;
			End Select
		Next
		
		If ofs>0
			partLeft = Left(s, ofs-1);
			s = Right(s, Len(s)-ofs+1);
		Else
			partLeft = Left(s, AOffset-1)+"-";
			s = Right(s, Len(s)-AOffset+1);
		EndIf;
		
		m\count=m\count+1
		m\s[m\count-1]=partLeft;
		If m\count>=MSG_MAX_LINES Then Return;
		
	Wend;
	
	m\count=m\count+1
	m\s[m\count-1]=s;
	
End Function

Const GW = 900, GH=600
Graphics GW,GH,0,2
SetBuffer BackBuffer()

Color 100,100,100
Rect 10,10,GW-20,GH-20,1
Color 255,128,000
Rect 10,10,GW-20,GH-20,0

Color 255,255,100

addMsg2(lorem_ipsum1, GW-40)
Local m.MSG
Local y% = 25
For m = Each MSG
	For n = 0 To m\count-1
		Text 20,y, m\s[n]
		y=y+15
	Next
Next;

Flip (True);

WaitKey();
End;

[EDIT]
Damned ! 15 minutes too late :)

Matty

(Posted 2015) [#4]

Do you know how much room in pixels you have to display the text?
Do you know how wide the text string is in pixels?
If you know the string is 100 pixels wide but you have only 30 pixels display area for example simply find the first tab or space prior to '30/100' fraction of the string length in and cut it there and repeat with the remainder of the string.....basic idea/premise behind a solution.

stayne

(Posted 2015) [#5]

Thanks a lot guys I'll dig into this later this afternoon.

stayne

(Posted 2015) [#6]

Midimaster I am having an issue with strings like this:

AddChat("> "+"<#f00>"+c\name+"<#fff>"+" hit "+c\attacktargetname+" for "+c\damage+" points of damage!")

Is your code parsing +...+ strings as well?

Midimaster

(Posted 2015) [#7]

If there is an "+" in the string it will be handled as a normal character...

Or do you mean, whether also the "+" can be the point, where the string should be divided? Yes, that is possible.

Here=Instr(Test,"+")

But your sample strings will not contain any "+" at the end:
the command...

"> "+"<#f00>"+c\name+"<#fff>"+" hit "+c\attacktargetname+" for "+c\damage+" points of damage!"

becomes this strings....

"> <#f00>STAYNE<#fff> hit PETER for 999 points of damage!"

If you want to devide the strings on exaclty the old points, insert a new separator sign:

"> |"+"<#f00>|"+c\name+"|<#fff>|"+" hit |"+c\attacktargetname+"| for |"+c\damage+"| points of damage!"

now search for the "|"

Here=Instr(Test,"|")

stayne

(Posted 2015) [#8]

It's wrapping the string like so:

Guard Stayne
hit soandso for 4 points of damage.

Still working at it...thanks man. The <#xxx> entries are for Text3D color. I have a feeling this function is parsing those as well.

Bobysait

(Posted 2015) [#9]

both its code and mine don't care about "invisible" tags, so it's logical that the text is cut too early.
If you want to split only according to the "real text", you'll have to parse all the string and map the valid characters.
A simple tokenizer should do the job pretty well.

Global txt_1$	= " Let's Start with Some default color text, <#F80>Then switch to a nice orange one"
txt_1	=	txt_1+", which should continue on the next line !<#08F>And this is a fantastic light blue<#FFF> And end the first chapter with whyte text."
Global txt_2$	= "<#f00>|Marlon Brando|<#fff>|"+" hit <#f00>|a purple mouse|<#fff> for |0.002| points of damage!"

Const MSG_MAX_LINES% = 258
Type MSG
	Field s$[MSG_MAX_LINES]
	Field count%
End Type

Type tWord
	Field s$
End Type
Function TWord.tWord(v$)
	If v="" Then Return Null;
	Local w.tWord=New tWord:w\s=v:Return w;
End Function

; uses the ".", "," or " " as splitter for words
Function addMsg(s$, chatwidth%)
	
	If Trim(s)="" Then Return;
	Local AOffset = chatwidth/StringWidth("A") - 1;
	Local BOffset = AOffset-15; '15' is an arbitrary number of chars at the end of the line to search for special characters.
	
	Delete Each tWord;
	Local w.tWord;
	Local ln = Len(s):
	Local b%, c$
	Local cur$= ""
	For b = 1 To ln
		c = Mid(s, b,1)
		Select c
			Case "|"
				; skip this ... I don't know why you need this separator
			Case " ", ".", ":", ";", ",", ">", "!", "?";, "[", "]", "(", ")"
				TWord(cur):cur=""; ad current word
				TWord(c); add special char
			Case "<"
				TWord(cur):cur=""; add current word
				Local tag=False;
				If b<ln-5
					If Mid(s,b+1,1)="#"
						If Mid(s,b+5,1)=">"
							TWord(Mid(s,b,6));
							b=b+5;
							tag=True; add color tag
						EndIf;
					EndIf;
				EndIf;
				If Not(tag) Then cur=cur+c;
			Default
				cur=cur+c
		End Select
	Next;
	TWord(cur):cur="";
	
	Local m.MSG = New MSG;
	
	Local l%=0, curL$=""
	Local curtag$="";
	
	For w = Each tWord
		If Left(w\s,2) = "<#"
			curtag = w\s;
			curL = curL + w\s;
		Else
			If l + Len(w\s) > AOffset
				m\s[m\count] = curL;
				m\count=m\count+1;
				curL = curtag+w\s;
				l=Len(w\s);
			Else
				curL=curL+w\s;
				l = l + Len(w\s);
			EndIf;
		EndIf;
	Next;
	
	If curL<>""
		m\count=m\count+1
		m\s[m\count-1]=curL;
	EndIf;
	
End Function

Function HexInt%(h$)
	Local a=Asc(Lower(h));
	If a>=Asc("a") And a<=Asc("f") Then Return 10 + a-Asc("a");
	Return a-Asc("0");
End Function

Function tagColor(tag$)
	Color 16*HexInt(Left(tag,1)),16*HexInt(Mid(tag,2,1)),16*HexInt(Right(tag,1));
End Function

Function DrawText3D(x,y,t$)
	Local pos, px=0
	Local tx$=""
	For pos = 1 To Len(t)
		If Mid(t,pos,2)="<#"
			If tx<>"" Then Text x+px,y, tx: px=px+StringWidth(tx): tx="";
			tagColor Mid(t, pos+2,3);
			pos=pos+5
		Else
			tx=tx+Mid(t,pos,1);
		EndIf;
	Next;
	If tx<>"" Then Text x+px,y, tx: px=px+StringWidth(tx): tx="";
End Function

Const GW = 600, GH=300
Graphics GW,GH,0,2
SetBuffer BackBuffer()

Color 50,50,50
Rect 10,10,GW-20,GH-20,1
Color 255,128,000
Rect 10,10,GW-20,GH-20,0

Color 255,255,100

addMsg(txt_1, GW-40)
addMsg(txt_2, GW-40)

Local m.MSG
Local y% = 25
For m = Each MSG
	For n = 0 To m\count-1
		DrawText3D (20,y, m\s[n])
		y=y+15
	Next
Next;

Flip (True);

WaitKey();
End;

ps : Don't judge me !
Nobody like purple mice !

stayne

(Posted 2015) [#10]

Bobysait you have some serious skills there my friend.

Bobysait

(Posted 2015) [#11]

Thanks, but I don't pretend to own real skills, it's just experience.
I've been programming with blitz3d for more than 10 years.
Like many others here (*), almost everything asked on the forum, we have already experienced it.

BTW : Hope the code will help

(*) except for Xylvan ... He was naturally born good. So, since he began to code, he keeps on doing the same candy world, again and again and again ^_^
private joke ... I could (and/or should) have skip this one as it's totally free and irelevant ... but, you know ... :)