Entity does not exsist [EntityName]

Blitz3D Forums/Blitz3D Programming/Entity does not exsist [EntityName]

Rrtaya_Tsamsiyu

(Posted 2015) [#1]

So, i'm having a problem with this simple program. Right now all it really does is test collisions.

Basically there's a square map, and spheres start out on either side and head toward each other. If they hit each other on the way through, one gets deleted.
Every now and then it will give me a Entity Doesn't Exist error at the line with EntityName, near the bottom of my code. It's especially a problem if there are a lot of objects existing at once.

Escape exits, R spawns another wave of spheres.

;Setup:
; Title
; Graphics
; Buffer
; Light
; Camera
; Keys
; Seed Random

;Collisions
; Object
; Shell
; Ground

;Globals:
; Hull, Hull.3ds
; X#
; Y#
; Z#
; Ground, hightmap1.bmp, texture.bmp

;Types
; TankType

;================================================================================================]
;===========================================Begin Code===========================================]
;================================================================================================]

;Main Loop

AppTitle "Game"
Graphics3D 640,480
SetBuffer BackBuffer()

;Lights
Global Light = CreateLight()

;Create the camera
Global Camera = CreateCamera():PositionEntity Camera,64,100,64:RotateEntity Camera,90,0,0

;Keys
Const ESCKEY = 1, WKEY = 17, RKEY = 19, PKEY = 25, SKEY = 31, DKEY = 32, AKEY=30, ZKEY=44, LEFTKEY=203, RIGHTKEY=205, UPKEY=200, DOWNKEY=208, NKEY=49, MKEY=50, SPACEKEY=57

SeedRnd MilliSecs();don't put this in loop, repeats numbers for some reason.

;Collisions
ColTypObject = 1
ColTypShell  = 1
ColTypGround = 1
Collisions ColTypObject,ColTypGround,2,3
Collisions ColTypShell, ColTypGround,2,1
Collisions ColTypShell, ColTypObject,2,1

;Globals
Global Hull = CreateSphere();LoadMesh("Hull.3ds")
EntityType Hull, ColTypObject;What am i
EntityRadius Hull, 0.5;How close can other objects come
Global X#=0
Global Y#=0
Global Z#=0
;This creates the ground. Current scaled ground size is 128x128, so default should be 256 unless scaling acts wierd.
Global Ground = LoadTerrain("hightmap1.bmp");hightmap controls hight
EntityColor Ground,000,150,000
;Texture = LoadTexture ("texture.bmp");the texture we'll see
;EntityTexture Ground, Texture;put the texture on the ground
ScaleEntity Ground,.5,.5,.5;scaling
EntityType Ground, ColTypGround;What am i
EntityRadius Ground, 0.5;How close can other objects come
NameEntity(Ground,"GRO"+Str(Ground))

;Types
Type TankType ;set up the target type
  Field entityhandle ;Field to contain the handle of the target's mesh
  Field Health       ;Field for health'
  Field Side         ;IFF
End Type

;================================================================================================]
;===========================================Main Loop============================================]
;================================================================================================]
While Not KeyDown(1)
  If KeyHit(RKEY)
    Reset()
  EndIf
  MoveObjects()
  UpdateWorld
  RenderWorld
  Flip
Wend
End

;================================================================================================]
;===========================================Functions============================================]
;================================================================================================]

Function Reset()
  ;North
  For Counter = 1 To 10
    X# = Rand(5,128)
    Z# = Rand(108,127)
    Tank.Tanktype = New Tanktype				;create an object
    Tank\entityhandle = CopyEntity(Hull)		;create the object mesh
    Y#=TerrainY(Ground,x#,y#,z#)
    Y=Y/2;Needs this because ground is half-hight
    TranslateEntity Tank\entityhandle,X,Y+1,Z   ;place the object
    ResetEntity Tank\entityhandle				;otherwise object could hit bullet while moving from 0,0,0 to current position
    Tank\Health = 10
    Tank\Side = 1
    NameEntity(Tank\entityhandle,"TNK"+Str(Handle(Tank)))
  Next
  ;South
  For Counter = 1 To 10
    X# = Rand(5,128)
    Z# = Rand(1,20)
    Tank.Tanktype = New Tanktype				;create an object
    Tank\entityhandle = CopyEntity(Hull)		;create the object mesh
    Y#=TerrainY(Ground,x#,y#,z#)
    Y=Y/2;Needs this because ground is half-hight
    TranslateEntity Tank\entityhandle,X,Y+1,Z   ;place the object
    ResetEntity Tank\entityhandle				;otherwise object could hit bullet while moving from 0,0,0 to current position
    Tank\Health = 10
    Tank\Side = 0
    NameEntity(Tank\entityhandle,"TNK"+Str(Handle(Tank)))
  Next
End Function

Function MoveObjects()
  For thisTank.Tanktype = Each Tanktype ;iterate through all of the tanks
    MoveEntity thisTank\entityhandle,0,-.1,0
    If thisTank\Side = 1 And (EntityZ(thisTank\entityhandle, 1)) > 10
      MoveEntity thisTank\entityhandle,0,0,-.3
    ElseIf thisTank\Side = 0 And (EntityZ(thisTank\entityhandle, 1)) < 120
      MoveEntity thisTank\entityhandle,0,0,.3
    EndIf


    CC% = CountCollisions(thisTank\entityhandle)
    If(CC% > 0)
      CollidedCollidable = CollisionEntity(thisTank\entityhandle,1)
      If(CollidedCollidable <> 0)
       CollidedName$ = EntityName(CollidedCollidable)
       CollidedKind$ = Left(CollidedName,3)
       CollidedId% = Right(CollidedName,Len(CollidedName)-3)
       If(CollidedKind = "TNK")
         Tank.TankType = Object.TankType(CollidedId)
         ;EntityColor(Tank\entityhandle,Rnd(125,255),Rnd(125,255),Rnd(125,255))
         FreeEntity (Tank\entityhandle)
         Delete (Tank)
       EndIf
      EndIf
    CC = 0
    EndIf


  Next
End Function

Any idea what is causing this?

videz

(Posted 2015) [#2]

Apart from the error message you're getting, you should also see what line the cursor is located as that's your indication where you should check your code.

Matty

(Posted 2015) [#3]

I can see what is happening from your code.

Imagine one tank is involved in two collisions during an update world with two different tanks.

When you get to the first tank involved you delete the collided tank.
then when you get to the second tank involved you get an entity doesn't exist because you've just deleted the original tank.

The simple solution to this is to use a flag instead of deleting the entity. When you want to remove the entity set the flag. Then after the loop has finished run through a second loop - as the last step, and remove all entities that have the flag set.

As an aside....most likely not relevant here but....With blitz you can get away with creating objects and deleting them on the fly no problems....if you ever decide to move to coding for mobile this will not work (not well anyway) because (in the case of Android) the garbage collector will kick in due to the creation and destruction of objects and cause your game to stutter. The solution to that is to not create or delete anything at all inside your main loop...

Rrtaya_Tsamsiyu

(Posted 2015) [#4]

Thanks videz. i know what line it is, just didn't know what was causing it.

Thanks Matty, that makes sense. i'll make the change and test it again

Edit; Works now, thanks!

stayne

(Posted 2015) [#5]

A bit off topic but anyway here's a tip: When you get a bug and B3D stops, click OK, hold shift and arrow to the right a few times. It will begin to highlight the line the cursor is on. Sometimes the cursor is hard to see.