Extremely high triangle / poly count?

Blitz3D Forums/Blitz3D Programming/Extremely high triangle / poly count?

Guy Fawkes

(Posted 2014) [#1]

Hi all. I found a SWEET code in the code archives, courtesy of Rob Cummings that allows for an extreme amount of triangles / polys in a small area at once.

Is there a way to improve this code say allowing 1 - 33 million triangles that are relatively close by?

Here's the code (credit Rob Cummings):

World_Management.bb:

; World management - very large management of entities
;
; Using copyentity to reduce the amount of possible entities which
; in large scale games can kill performance - this code is a guide not a rule
; the fps counter is slow to update too (1 second increments)
; 
; by rob cummings (rob@...)
;
;

Global pos=100,mx#,my#,freecount,maxfreeperloop
Global fpsindex,fpstime,fpsfold_millisecs,fpsfps

; free entity entails a performance hit so lets kill em slow
; this needs To change depending on numbers, and can affect performance
maxfreeperloop=25

Type vistype
	Field entity,ball
End Type

Graphics3D 800, 600, 0, 2
camera=CreateCamera()
CameraRange camera,.001,10000
light=CreateLight()
worldpivot=CreatePivot()
ball=CreateSphere()

; massive amount here
For i=0 To 5000
	a=CreatePivot()
	PositionEntity a,Rnd(-pos,pos),Rnd(-pos,pos),Rnd(-pos,pos)
	addvis(a)
Next

	While Not KeyHit(1)
		mx#=MouseXSpeed()*0.5
		my#=MouseYSpeed()*0.5
		MoveMouse 320,240
		
		TurnEntity camera,my,-mx,0
	
		freecount=0
	
		For vis.vistype=Each vistype
			If EntityInView(vis\entity,camera)
				If vis\ball=0
					vis\ball=CopyEntity(ball,vis\entity)
					PositionEntity vis\ball,EntityX(vis\entity),EntityY(vis\entity),EntityZ(vis\entity),1
				EndIf
			Else 
				If vis\ball<>0 And freecount<maxfreeperloop
					FreeEntity vis\ball
					vis\ball=0
					freecount=freecount+1
				EndIf
			EndIf
		Next 
	
		UpdateWorld
		RenderWorld
	
		Text 0,0,fps()
		Text 0,16,TrisRendered()
	
		VWait 1
		Flip 0
		Delay 1
		
	Wend

End

Function addvis(ent)
	vis.vistype=New vistype
	vis\entity=ent
	EntityParent vis\entity,worldpivot
End Function


Function fps()
	fpsindex=fpsindex+1
	fpstime=fpstime+MilliSecs()-fpsfold_millisecs
	If fpstime=>1000
		fpsfps=fpsindex
		fpstime=0
		fpsindex=0
	EndIf
	fpsfold_millisecs=MilliSecs()
	Return fpsfps
End Function

EDIT: I only edited the "pos" variable, changed flip to flip 0 added a delay 1 after that and a vwait 1 before that, & nothing else.

Thank You so kindly!

Sincerely,

~GF

RemiD

(Posted 2014) [#2]

1 millions triangles is a lot of triangles !

What you have to understand is that a surface can only contain a limited number of vertices and triangles.
Because this limit depends on the hardware of the graphics card, to be safe i put no more than 32000 vertices or 32000 triangles in a surface.

So to hold 1000000 triangles you will need around 32 surfaces

But this is not smart to use only one mesh to hold all surfaces of a level because when a mesh (its bounding box) is not visible, it is automatically hidden and not rendered.

So i suggest to think about how you can split your level into separate meshes depending on their position and the space they occupy and for each mesh have the lowest number of surfaces possible by merging many separate surfaces in one surface.

Guy Fawkes

(Posted 2014) [#3]

Ok, well is there any way to improve this code to say 250,000 triangles or so? Something that can be used for alot of high poly models?

RemiD

(Posted 2014) [#4]

A little test :

Graphics3D(800,600,32,2)
SetBuffer(BackBuffer())

SeedRnd(MilliSecs())

Global Camera = CreateCamera()
CameraRange(Camera,0.1,100)
PositionEntity(Camera,0,1.65,0)

DLight = CreateLight(1)
LightColor(DLight,250,250,250)
PositionEntity(DLight,0,-1000,1000)
RotateEntity(DLight,45,0,0)

AmbientLight(050,050,050)

XMesh = CreateCube()
ScaleMesh(XMesh,1.0/2,1.0/2,1.0/2)
PositionMesh(XMesh,0,1.0/2,0)
HideEntity(XMesh)
DebugLog("SurfacesCount = "+CountSurfaces(XMesh))
DebugLog("VerticesCount = "+CountVertices(GetSurface(XMesh,1)))
DebugLog("TrianglesCount = "+CountTriangles(GetSurface(XMesh,1)))

MaxCountV% = Floor(32000.0/CountVertices(GetSurface(XMesh,1)))
DebugLog("MaxCountV = "+MaxCountV)

MaxCountT% = Floor(32000.0/CountTriangles(GetSurface(XMesh,1)))
DebugLog("MaxCountT = "+MaxCountT)

If(MaxCountV < MaxCountT)
 MaxCount% = MaxCountV
ElseIf(MaxCountT < MaxCountV)
 MaxCount% = MaxCountT
Else
 MaxCount% = MaxCountV
EndIf
DebugLog("MaxCount = "+MaxCount)

Global ThingsCount%
Dim ThingMesh(MaxCount)

Global AreaMesh = CreateMesh()

;test to display meshes with copymesh (separate meshes)
ThingsCount = 0
For i% = 1 To MaxCount
 ThingsCount = ThingsCount + 1
 Id% = ThingsCount
 ThingMesh(Id) = CopyMesh(XMesh)
 RotateMesh(ThingMesh(Id),0,Rnd(-180,180),0)
 PositionMesh(ThingMesh(Id),Rnd(-10,10),Rnd(-7.5,7.5),Rnd(15,100-0.51))
Next

RenderStart% = MilliSecs()
RenderWorld()
RenderTime% = MilliSecs() - RenderStart
Color(255,255,255)
Text(0,0,"Triangles = "+TrisRendered())
Text(0,20,"RenderTime with separate meshes = "+RenderTime)
Text(0,40,"Press any key to continue")
Flip()
WaitKey()

For Id% = 1 To ThingsCount
 FreeEntity(ThingMesh(Id))
 ThingMesh(Id) = 0
Next

;test to display meshes with copyentity (copies of a mesh)
ThingsCount = 0
For i% = 1 To MaxCount
 ThingsCount = ThingsCount + 1
 Id% = ThingsCount
 ThingMesh(Id) = CopyEntity(XMesh)
 RotateEntity(ThingMesh(Id),0,Rnd(-180,180),0)
 PositionEntity(ThingMesh(Id),Rnd(-10,10),Rnd(-7.5,7.5),Rnd(15,100-0.51))
Next

RenderStart% = MilliSecs()
RenderWorld()
RenderTime% = MilliSecs() - RenderStart
Color(255,255,255)
Text(0,0,"Triangles = "+TrisRendered())
Text(0,20,"RenderTime with copies of a mesh = "+RenderTime)
Text(0,40,"Press any key to continue")
Flip()
WaitKey()

For Id% = 1 To ThingsCount
 FreeEntity(ThingMesh(Id))
 ThingMesh(Id) = 0
Next

;test to display meshes with merged meshes merged surfaces (one mesh with one surface)
ThingsCount = 0
For i% = 1 To MaxCount
 ThingsCount = ThingsCount + 1
 Id% = ThingsCount
 TMesh = CopyMesh(XMesh)
 RotateMesh(TMesh,0,Rnd(-180,180),0)
 PositionMesh(TMesh,Rnd(-10,10),Rnd(-7.5,7.5),Rnd(15,100-0.51))
 AddMesh(TMesh,AreaMesh)
 FreeEntity(TMesh)
Next

RenderStart% = MilliSecs()
RenderWorld()
RenderTime% = MilliSecs() - RenderStart
Color(255,255,255)
Text(0,0,"Triangles = "+TrisRendered())
Text(0,20,"RenderTime with meshes merged in one mesh with one surface = "+RenderTime)
Text(0,40,"Press any key to continue")
Flip()
WaitKey()

FreeEntity(AreaMesh)
AreaMesh = 0

End()

I am surprised how copyentity can decrease rendertime compared to separate meshes, but limiting the number of meshes and of of surfaces is still the best approach.

Guy Fawkes

(Posted 2014) [#5]

NICE! :O AWESOME code, Remi! :D

RemiD

(Posted 2014) [#6]

I had a MAV at renderworld on one of my computer, i modified the code so that there are no more than 32000 triangles and no more than 32000 vertices per surface, now it works well.