Problem with Right Click Menu

Blitz3D Forums/Blitz3D Programming/Problem with Right Click Menu

Guy Fawkes

(Posted 2014) [#1]

Hi all. As I near completion of my project, I came across a stand-still. I need the code I made to do the following:

1) Pick the object and turn it transparent.
2) If the object IS transparent, THEN open up right click context menu.

I tried many different ways INCLUDING millisecond timers, but to no avail.

It should CLEARLY make the object transparent and THEN open up the menu.
Not the other way around.

Context_Menu.bb:

Function CM_Create() 
;============================================================================================================== 
; Create PopUp or SubMenu. Gives back a handle to add or insert items. 
;============================================================================================================== 

   Return cm_CreatePopupMenu() 

End Function 



Function CM_Open( hMenu, x=-1, y=-1 ) 
;============================================================================================================== 
; Opens the PopUp menu on the given X, Y position and tracks the user input. Gives back the choosen itemhandle 
; or 0 if the user cancel the menu. 
; 
; If x and y is specified, the menu opens on this position relative to the inside of the application window. 
; Without x any y the function opens the menu on the actual mouse position on the screen. 
;============================================================================================================== 
	
   Local hWnd = cm_GetActiveWindow()      ;--> get app window handle 
   Local hrec = CreateBank( 16 )         ;--> rect structure 
   Local hpnt = CreateBank(  8 )         ;--> pointer structure 

   ;--> use user position? 
   If x <> -1 And y <> -1 Then 
      cm_GetWindowRect( hWnd, hrec ) 
      hMsx = PeekInt( hrec, 0 ) + cm_GetSystemMetrics(7) + x 
      hMsy = PeekInt( hrec, 4 ) + cm_GetSystemMetrics(8) + cm_GetSystemMetrics(4) + y 
   Else 
      cm_GetCursorPos( hpnt ) 
      hMsx = PeekInt( hpnt, 0 ) 
      hMsy = PeekInt( hpnt, 4 ) 
   End If 

   FreeBank hrec 
   FreeBank hpnt 

   Return cm_TrackPopupMenu( hMenu, TPM_RETURNCMD, hMsx, hMsy, 0, hWnd, CreateBank(0) ) 

End Function 



Function CM_Delete( hMenu ) 
;============================================================================================================== 
; Deletes the whole menu. 
;============================================================================================================== 
    
   cm_DestroyMenu( hMenu ) 
    
End Function 



Function CM_Item_Add( hMenu, Item$="", hItem=0 ) 
;============================================================================================================== 
; Adds Item$ to the given hMenu. If Item$="-" a seperator will created, except if the Item opens a submenu. 
; hItem is a specific handle (int) or you give a submenu handle. Then Item$ will open the given submenu. 
;============================================================================================================== 

   ;--> empty strings not allowed 
   If Item$ = "" Then Item$ = " " 

   ;--> create seperator or Item? 
   If Item$ = "-" Then 
      cm_AppendMenu( hMenu, MF_SEPERATOR, 0, CreateBank(0) ) 
   Else 
      ;--> if hItem is a menu handle, then hItem opens a submenu 
      If cm_IsMenu( hItem ) Then 
         cm_AppendMenu( hMenu, MF_STRING Or MF_POPUP, hItem, CM_StringToBank( Item$ ) ) 
      Else 
         cm_AppendMenu( hMenu, MF_STRING, hItem, CM_StringToBank( Item$ ) ) 
      End If 
   End If 
    
End Function 



Function CM_Item_Insert( hMenu, hPos, Item$="", hItem=0 ) 
;============================================================================================================== 
; Inserts Item$ into the given hMenu. If Item$="-" a seperator will created, except if the Item opens a submenu 
; hItem is a specific handle (int) or you give a submenu handle. Then Item$ will open the given submenu. 
;============================================================================================================== 

   ;--> empty strings not allowed 
   If Item$ = "" Then Item$ = " " 

   ;--> create seperator or Item? 
   If Item$ = "-" Then 
      cm_InsertMenu( hMenu, hPos, MF_SEPERATOR, 0, CreateBank(0) ) 
   Else 
      ;--> if hItem is a menu handle, then hItem opens a submenu 
      If cm_IsMenu( hItem ) Then 
         cm_InsertMenu( hMenu, hPos, MF_STRING Or MF_POPUP, hItem, CM_StringToBank( Item$ ) ) 
      Else 
         cm_InsertMenu( hMenu, hPos, MF_STRING, hItem, CM_StringToBank( Item$ ) ) 
      End If 
   End If 
    
End Function 



Function CM_Item_Modify( hMenu, hItem, Item$="" ) 
;============================================================================================================== 
; Modify item text. 
;============================================================================================================== 
    
   ;--> empty strings not allowed 
   If Item$ = "" Then Item$ = " " 

   cm_ModifyMenu( hMenu, hItem, MF_STRING, hItem, CM_StringToBank( Item$ ) ) 
    
End Function 



Function CM_Item_Delete( hMenu, hItem ) 
;============================================================================================================== 
; Deletes a item. 
;============================================================================================================== 

   cm_DeleteMenu( hMenu, hItem, 0 ) 

End Function 



Function CM_Item_Enable( hMenu, hItem ) 
;============================================================================================================== 
; Enables a item. 
;============================================================================================================== 

   cm_EnableMenuItem( hMenu, hItem, MF_ENABLED ) 

End Function 



Function CM_Item_Disable( hMenu, hItem ) 
;============================================================================================================== 
; Disables a item. 
;============================================================================================================== 

   cm_EnableMenuItem( hMenu, hItem, MF_GRAYED ) 

End Function 



Function CM_Item_IsEnabled( hMenu, hItem ) 
;============================================================================================================== 
; If item is enabled the function gives True, otherwise False. 
;============================================================================================================== 

   If ( cm_GetMenuState( hMenu, hItem, 0 ) And MF_GRAYED ) = MF_GRAYED Then Return False Else Return True 

End Function 



Function CM_Item_Checked( hMenu, hItem ) 
;============================================================================================================== 
; Check a item. 
;============================================================================================================== 

   cm_CheckMenuItem( hMenu, hItem, MF_CHECKED ) 

End Function 



Function CM_Item_Unchecked( hMenu, hItem ) 
;============================================================================================================== 
; Uncheck a item. 
;============================================================================================================== 

   cm_CheckMenuItem( hMenu, hItem, MF_UNCHECKED ) 

End Function 



Function CM_Item_IsChecked( hMenu, hItem ) 
;============================================================================================================== 
; If item is checked the function gives True, otherwise False. 
;============================================================================================================== 

   If ( cm_GetMenuState( hMenu, hItem, 0 ) And MF_CHECKED ) = MF_CHECKED Then Return True Else Return False 

End Function 



Function CM_Item_SetIcon( hMenu, hItem, hIcon1$, hIcon2$="" ) 
;============================================================================================================== 
; Adds 1 or 2 Icon(s) to the Item. You can use bmp or ico files. The resolution should be 13x13 Pixel. 
; Otherwise the image will be resized automaticly. White color will be transparent in bmp files. Transparancy 
; map in ico files will be ignored. If you use 2 icons, the second icon appears If the item is checked. 
;============================================================================================================== 
    
   Local bMap1 
   Local bMap2 
   Local hinfo = CreateBank( 20 )         ;--> iconinfo structure 
    
   ;--> File exists? 
   If FileType( hIcon1$ ) = 0 Then RuntimeError "File " + hIcon1$ + " not Found !" 
    
   ;--> BMP or ICO? 
   If Lower$( Right$( hIcon1$, 3 ) ) = "bmp" Then 
      bMap1 = cm_LoadImage( 0, hIcon1$, IMAGE_BITMAP, 13, 13, LR_LOADFROMFILE ) 
   Else 
      bMap1 = cm_LoadImage( 0, hIcon1$, IMAGE_ICON, 13, 13, LR_LOADFROMFILE ) 
      cm_GetIconInfo( bMap1, hinfo ) 
      bMap1 = PeekInt( hinfo, 16 ) 
   End If 
    
   ;--> second icon? 
   If hIcon2$ <> "" Then 
      ;--> BMP or ICO? 
      If Lower$( Right$( hIcon2$, 3 ) ) = "bmp" Then 
         bMap2 = cm_LoadImage( 0, hIcon2$, IMAGE_BITMAP, 13, 13, LR_LOADFROMFILE ) 
      Else 
         bMap2 = cm_LoadImage( 0, hIcon2$, IMAGE_ICON, 13, 13, LR_LOADFROMFILE ) 
         cm_GetIconInfo( bMap2, hinfo ) 
         bMap2 = PeekInt( hinfo, 16 ) 
      End If 
   End If 
    
   ;--> attach icon 
   cm_SetMenuItemBitmaps( hMenu, hItem, MF_BITMAP, bMap1, bMap2 ) 

End Function 



 Function CM_StringToBank( cm_str$ ) 
;============================================================================================================== 
; Puts the given string into a bank and gives back the handle to the bank. 
;============================================================================================================== 
    
   Local i 
   Local length = Len( cm_str$ ) 
   Local tbank 
    
   ;--> poke the string in the bank 
   tbank = CreateBank( length + 1) 
   For i = 1 To length 
      PokeByte tbank, i - 1, Asc( Mid$( cm_str$, i, 1 ) ) 
   Next 
    
   Return tbank 
    
End Function

Example_Context_Menu.bb:

Global Context_Menu
Global CM_Result
Global selected

Global picked
Global inpickmode

Global selectionchanged

Global type_obj = 1

Include "Context_Menu.bb"

Graphics3D(800, 600, 0, 2)

Global cam = CreateCamera()
PositionEntity cam, 0, 1, -2
CameraRange cam, .01, 10000.0

Global light = CreateLight()
RotateEntity light, 45, 30, 0

Collisions type_obj, type_obj, 2, 3

Global dwarf = LoadMesh("dwarf (1)/x/dwarf1.x")
EntityPickMode dwarf, 2, 1
EntityType dwarf, type_obj

PositionEntity dwarf, 0, -1, 10
RotateEntity dwarf, 0, 180, 0

Context_Menu = Initialize_Context_Menu()

Global object_yaw# = -1.0

`api_ShowWindow(SystemProperty$("AppHWND"), 1)

	Repeat

		Update_ContextMenu(Context_Menu)
	
		TurnEntity dwarf, 0, object_yaw#, 0

		UpdateWorld
		RenderWorld
		
		VWait 1
		Flip 0
		Delay 1
	
	Until KeyDown(1)
	
	FreeEntity(cam)
	FreeEntity(light)
	FreeEntity(dwarf)

End

Function Initialize_Context_Menu()

	Context_Menu = CM_Create()               ;--> Create the Context Menu Root 
	
	CM_Item_Add( Context_Menu, "Menu 1"+Chr(9)+"Ctrl+A", 1 )        ;--> create a menu entry 
	CM_Item_Add( Context_Menu, "Menu 2"+Chr(9)+"Ctrl+B", 2 )        ;--> create a menu entry 
	CM_Item_Add( Context_Menu, "Menu 3"+Chr(9)+"Ctrl+C", 3 )		;--> create a menu entry
		
	CM_Item_Add( Context_Menu, "Menu 4"+Chr(9)+"Ctrl+D", 4 )        ;--> create a menu entry 
	CM_Item_Add( Context_Menu, "Menu 5"+Chr(9)+"Ctrl+E", 5 )        ;--> create a menu entry 
        CM_Item_Add( Context_Menu, "Menu 6"+Chr(9)+"Ctrl+F", 6 )		;--> create a menu entry

	Return Context_Menu

End Function

Function Update_Context_Menu(Context_Menu)

	;--> open menu if "right mouse" or "contextmenu key" hit 
	If (MouseHit(2) Or KeyHit(221))

		picked = Auto_Select_Object(cam)
		CM_Result = CM_Open( Context_Menu )
		
	EndIf

	Return CM_Result

End Function

Function Update_ContextMenu(Context_Menu)
		
	CM_Result = Update_Context_Menu(Context_Menu)

		If CM_Result = 1 Then End
		If CM_Result = 2 Then End
		If CM_Result = 3 Then End

		If CM_Result = 4 Then End
		If CM_Result = 5 Then End
		If CM_Result = 6 Then End

	CM_Result = 0
	
End Function

Function Auto_Select_Object(camera)

	picked = CameraPick(camera, MouseX(), MouseY())
	
	If picked

		inpickmode = 1
	
		If picked = dwarf
	
			selected=1-selected
			EntityAlpha dwarf, 0.75
			EntityFX dwarf, 1

			selectionchanged = True
	
		EndIf
	
		If selected = 1
	
			EntityAlpha dwarf, 0.75
			EntityFX dwarf, 1
	
			selectionchanged = True

		ElseIf selected = 0
	
			EntityAlpha dwarf, 1.0
			EntityColor dwarf, 255, 255, 255
			EntityFX dwarf, 0

			selectionchanged = False
	
		EndIf

	Else
	
		If dwarf
	
			EntityAlpha dwarf, 1.0
			EntityColor dwarf, 255, 255, 255
			EntityFX dwarf, 0
				
			selectionchanged = False

		EndIf
	
		selected = 0
		inpickmode = 0
		selectionchanged = False

	EndIf

	Return inpickmode
	
End Function

--=EDIT=--

Note 1: Make sure to change the location of your 3D model (*.x) file, to the correct directory in which your 3D model exists.

Thanks all & have a GREAT afternoon! :)

Sincerely,

~GF

Guy Fawkes

(Posted 2014) [#2]

Can someone please assist?

Thank You so kindly! :)

Have a GREAT day! :)

Sincerely,

~GF

RemiD

(Posted 2014) [#3]

I need the code I made to do the following

Which means : provide code for my game/app.
But i won't do that because if i do that you will not improve your understanding and skills and you will keep asking the same questions again and again.

1) Pick the object and turn it transparent.

Set the meshes you want to be able to select as pickable
EntityPickMode(Mesh,2)
Also name each of your pickable meshes with a different name or with a listname and an id/handle
NameEntity(Mesh,"dwarf")
or
NameEntity(Mesh,"LISTX"+str(Id))

for each pickable mesh you can store its selection state by having a variable 'SelectionState" which can be true or false

if a key is pressed
Reset all "SelectionState" variables of all pickable meshes to false (except if you need multi selection)
Throw a ray in the world with linepick or camerapick
Check if a pickable mesh has been picked
PickedPickable = PickedEntity()
If(PickedPickable <> 0)
Retrieve the pickable mesh name
PickableName$ = EntityName(PickedPickable)
With its name you can retrieve the list and its id/handle
Knowing the list and its id/handle you can modify the "SelectionState" variable to true
Endif

2) If the object IS transparent, THEN open up right click context menu.

For this you can analyze each entity of the list and if the "SelectionState" variable of a wanted entity is true, display your menu.

To display a menu or any window or any GUI element, i would have a variable "DisplayState" which can be true or false

Depending on the user input you update the different windows and GUI elements and their "DisplayState"

Then when it is time to draw the windows and the GUI elements, depending on the "DisplayState" of each window/GUI element, you know which windows and which GUI elements to draw or not.

Note that i have talked about having a list in case you need to be able to have different meshes in the world, but this will work well with only one mesh too.

2 examples to understand how to set some meshes as pickable and pick them and retrieve the list and the id/handle of a picked pickable :
with types
http://www.blitzbasic.com/codearcs/codearcs.php?code=3095
with arrays :
http://www.blitzbasic.com/codearcs/codearcs.php?code=3094

Guy Fawkes

(Posted 2014) [#4]

Thanks RemiD! I will test it tomorrow when I'm not so tired! =)

Cheers! :D

Sincerely,

~GF