How to skin a window the NON-slow way?

Blitz3D Forums/Blitz3D Programming/How to skin a window the NON-slow way?

Guy Fawkes

(Posted 2014) [#1]

Hi all. I found a code that can skin my window, but the problem is it is EXTREMELY slow. It takes 3 seconds to load which should only take half a second to a second to load.

Can someone please show an example of how to skin an "interface" PNG image to a regular window and the ability to use alpha# from 0 to 255 so that the window is not completely invisible but also not completely visible just like Windows Vista & up (Windows 7 preferably)?

Thanks alot guys & happy 4th of July!

Sincerely,

~GF

Guy Fawkes

(Posted 2014) [#2]

Can someone please assist?

Thank You so kindly!

Have a GREAT day!

Sincerely,

~GF

wmaass

(Posted 2014) [#3]

Notwithstanding other issues, 3 seconds to load seems reasonable IMHO. Are you trying to do a border-less, shaped window or something? What is this code you found?

Guy Fawkes

(Posted 2014) [#4]

I'm basically trying to skin my own window you know like with a transparent title, the ability to make the window lose the whole title bar, and the ability to make the app look sleek & clean. =)

wmaass

(Posted 2014) [#5]

I see. Can't really help there though I've done stuff with shaped/transparent windows with some C# WPF apps before. You might consider looking at AutoHotkey (http://www.autohotkey.com) which can manipulate windows in interesting ways.

Then again if you can live with 3 seconds to launch your app (I would) and it looks the way you want I would totally stick with that.

Rroff

(Posted 2014) [#6]

Doing that with B3D is quite advanced and requires fairly extensive knowledge of Windows UI programming even to do it in a language that supports it better.

Some people might know how to improve the code you have for performance but there won't be many people who have the time to create sample code for something like that from scratch unless they have extensive knowledge of it.

Guy Fawkes

(Posted 2014) [#7]

Ok, well here's the code:

; ==============================
; Skin Window
; ==============================

Global skin=SkinApp("interface.png",$FF00FF)

api_ShowWindow(SystemProperty$("AppHWND"), 1)

	Repeat
	
		If MouseHit(1)

			End

		EndIf
	
		;Draw skin
		Draw_Skin(skin, 0, 0)

			Color 0, 0, 0
	
				Text GraphicsWidth()/2, GraphicsHeight()/2, "Press ESC to Exit", 1, 1
				Text GraphicsWidth()/2, GraphicsHeight()/2+20, "or", 1, 1
				Text GraphicsWidth()/2, GraphicsHeight()/2+40, "Click window to exit", 1, 1
	
			Color 255, 255, 255
	
		Flip
	
	Until KeyHit(1)

End

; ==============================
; Function
; ==============================
Function SkinApp%(Image$,MaskColor%)
	Local app=api_GetActiveWindow()
	
	;size of cli area
	Local cli=LoadImage(Image$)
	ScaleImage(cli, 2, 2)
	Graphics3D(ImageWidth(cli),ImageHeight(cli), 0, 2)
	SetBuffer BackBuffer()

	api_ShowWindow app,2
	
	;remove all borders around the cli aera
	Local bmp=LoadImage(Image$)
	ScaleImage bmp, 2, 2
	Local x=api_GetSystemMetrics($07)
	Local y=api_GetSystemMetrics($08)+api_GetSystemMetrics($04)		
	Local region=api_CreateRectRgn(x,y,x+GraphicsWidth(),y+GraphicsHeight())	

	Local yoffset = -1-(api_GetSystemMetrics($4)+api_GetSystemMetrics($2E))
	Local xoffset = -1-api_GetSystemMetrics($2D)

	;fix visual problem on non-XP computer
	If Not Instr(SystemProperty("OS"),"XP",1)	
		x=x+xoffset
		y=y+yoffset
	EndIf 

	;remove all useless pixels 
	Local pixel,px,py,c
	For py=0 To ImageHeight(bmp)-1
		For px=0 To ImageWidth(bmp)-1
		
			c=ReadPixelFast(px,py,ImageBuffer(bmp))	And $00FFFFFF 		

			If c=MaskColor
				pixel=api_CreateRectRgn(x+px,y+py,x+px+1,y+py+1)
				api_CombineRgn region,region,pixel, 3
				api_DeleteObject pixel
			EndIf 
			
		Next
	Next
		
	;set visible region
	api_SetWindowRgn(app,region,True)

	api_ShowWindow app,1

	Return bmp
End Function

Function Draw_Skin(skin, x, y)

	DrawBlock skin, 0, 0

End Function

Here's the example interface I drew quickly on paint:

When downloading the image, rename it to: interface.png

To run this demo, you will need the following user32.decls commands, your user32.decls file should look something like this:

user32.decls:

.lib "user32.dll"
api_GetSystemMetrics% (nIndex%) : "GetSystemMetrics"
api_SetWindowRgn% (hWnd%, hRgn%, bRedraw%) : "SetWindowRgn"
api_ShowWindow% (hwnd%, nCmdShow%) : "ShowWindow"

You will also need the following gdi32.decls file:

gdi32.decls:

.lib "gdi32.dll"
api_CombineRgn% (hDestRgn%, hSrcRgn1%, hSrcRgn2%, nCombineMode%) : "CombineRgn"
api_CreateRectRgn% (X1%, Y1%, X2%, Y2%) : "CreateRectRgn"
api_DeleteObject% (hObject%) : "DeleteObject"

That should be all of it.

If you can't be bothered to add these to your user32.decls file & your gdi32.decls file, just make a backup of both files then recreate user32.decls with the correct functions from above & gdi32.decls with the correct functions from above. Just copy and paste.

Thanks, and have a GREAT morning everyone!

Sincerely,

~GF

Guy Fawkes

(Posted 2014) [#8]

Can someone please assist?

Thank you so kindly!

Have a GREAT evening! :)

Sincerely,

~GF

Yan	(Posted 2014) [#9]

I was about to rebuke you for not searching the forum as I posted a slightly faster version of the above code years ago. However, I searched and couldn't find in myself. ;o)

It probably got annihilated by 'The Purge'. so...

skin.png

;---------------------------------------------------------------------------------
; User32.decls
;==============
;
;.lib "user32.dll"
;
;FindWindow%(ClassName$, WindowName$)
;GetSystemMetrics%(nIndex%) : "GetSystemMetrics"
;SetWindowRgn%(hWnd%, hRgn%, bRedraw%) : "SetWindowRgn"
;ReleaseCapture%()
;SendMessage%(hWnd%, Msg%, wParam%, lParam%)
;
;---------------------------------------------------------------------------------
;
; Gdi32.decls
;=============
;
;.lib "Gdi32.dll"
;
;CreateRectRgn%(nLeftRect%, nTopRect%, nRightRect%, nBottomRect%)
;CombineRgn%(hrgnDest%, hrgnSrc1%, hrgnSrc2%, fnCombineMode%)
;DeleteObject%(hObject%)
;
;---------------------------------------------------------------------------------

Const SM_CYCAPTION  = 4
Const SM_CXDLGFRAME = 7
Const SM_CYDLGFRAME = 8

Const SW_HIDE = 0
Const SW_SHOW = 5

Const RGN_XOR = 3

t = MilliSecs() ;<<<<<<<<<<<<<<<<<<<<<<<<<<<

title$ = "test"
AppTitle title$
blitz_hnd = FindWindow("Blitz Runtime Class", title$) ; Find this window

img = LoadImage("skin.png")
window_w = ImageWidth(img)		
window_h = ImageHeight(img)
FreeImage img

Graphics3D window_w, window_h, 0, 2

ShowWindow(blitz_hnd, SW_HIDE)

x_off = GetSystemMetrics(SM_CXDLGFRAME)
y_off = GetSystemMetrics(SM_CYCAPTION) + GetSystemMetrics(SM_CYDLGFRAME)

rectrgn = CreateRectRgn(x_off, y_off, x_off + window_w, y_off + window_h)

img = LoadImage("skin.png")
img_w = ImageWidth(img) - 1
img_h = ImageHeight(img) - 1
img_buff = ImageBuffer(img)

LockBuffer img_buff

For pix_y=0 To img_h
	start_flag = 0
	start_x = 0
	For pix_x=0 To img_w
	
		c=ReadPixelFast(pix_x, pix_y, img_buff) And $F8F8F8 		

		If c=$F800F8 ; Mask Color - Magenta
			If start_flag = 0
				start_flag = 1
				start_x = pix_x
			EndIf
		Else
			If start_flag
				start_flag = 0
				mask_line = CreateRectRgn(x_off + start_x, y_off + pix_y, x_off + pix_x, y_off + pix_y + 1)
				CombineRgn(rectrgn, rectrgn, mask_line, RGN_XOR)
				DeleteObject(mask_line)
			EndIf
		EndIf 			
	Next
	If start_flag
		mask_line = CreateRectRgn(x_off + start_x, y_off + pix_y, x_off + pix_x, y_off + pix_y + 1)
		CombineRgn(rectrgn, rectrgn, mask_line, RGN_XOR)
		DeleteObject(mask_line)
	EndIf
Next

UnlockBuffer img_buff

SetWindowRgn(blitz_hnd, rectrgn, 1)

ShowWindow(blitz_hnd, SW_SHOW)

;-------------------------------------TEST---------------------------------------

tot = MilliSecs() - t ;<<<<<<<<<<<<<<<<<<<<<<<<<<

Repeat
	DrawBlock img, 0, 0
	
	If MouseDown(1)
		ReleaseCapture()
		SendMessage(blitz_hnd, $A1, 2, 0)
	EndIf
	
	Text MouseX(), MouseY(), tot
	
	Delay(1)
	Flip 0
Until KeyHit(1)

End

As for translucency...
http://msdn.microsoft.com/en-us/library/ms997507.aspx

A quick glance suggests that this may be a way to go for the whole thing.

Yan	(Posted 2014) [#10]

If you just want a 'border-less' window, which is what I think you're *really* after, there's always this...

http://www.blitzbasic.com/Community/post.php?topic=62470&post=698005

Again, you can use the info I posted above to make it translucent.

Guy Fawkes

(Posted 2014) [#11]

This is GREAT, thanks ALOT, Yan! :)

Sincerely,

~GF

Guy Fawkes

(Posted 2014) [#12]

Hey Yan. Mind if I turn it into a DLL in Purebasic, so it's even FASTER?

Thanks again! :)

Sincerely,

~GF