AI waypoint paths, Return to last node in path

Blitz3D Forums/Blitz3D Programming/AI waypoint paths, Return to last node in path

Aussie

(Posted 2014) [#1]

Hey there all, been a while since i posted here.

Got back into some coding again & have been playing around with some AI & waypoints. I have it working pretty much the way i want for now, but i seem to have had a brain fart & have lost the ability to figure out how to get this final piece of the waypoint following code working & could do with a different set of eyes to have a quick look at it.

I have created 2 separate paths for an enemy to follow. What i am trying to do is when the enemy changes paths, then back to the original path again is to have the enemy return to the active waypoint on that path then continue through the rest of the waypoints.

I have set up values to store the waypoint node that the enemy was on when the paths change but just can't figure out how to get it all working at the moment.

If someone could take a look that would be awesome.

It's under the Update_Objects function.

Graphics3D 800,600,0,2

SetBuffer BackBuffer()

Global AI_State = PATROL_WAYPOINTS
Global Next_Waypoint# = 1
Global Player.World_Objects = Create_Objects(PLAYER_CLASS)
Global Enemy.World_Objects = Create_Objects(ENEMY_CLASS)
Global Current_Waypoint_Path% = 1
Global Node_Count% = 0
Global WP.Waypoint

Global Temp_Node_Path1 = 1
Global Temp_Node_Path2 = 1

Const PLAYER_CLASS% = 1
Const ENEMY_CLASS% = 2

Const PATROL_WAYPOINTS% = 0
Const HEAD_TOWARDS_PLAYER% = 1
Const EVADE_COLLISION% = 2

camera = CreateCamera()
	PositionEntity camera,0,40,0
	RotateEntity camera,90,0,0
	
light = CreateLight()
	RotateEntity light,90,0,0
	
P1_N1.Waypoint = Create_Waypoint(1,1,35,0,-25)
P1_N2.Waypoint = Create_Waypoint(1,2,35,0,25)
P1_N3.Waypoint = Create_Waypoint(1,3,-35,0,25)
P1_N4.Waypoint = Create_Waypoint(1,4,-35,0,-25)
P1_N5.Waypoint = Create_Waypoint(1,5,0,0,0)

P2_N1.Waypoint = Create_Waypoint(2,1,10,0,-10)
P2_N2.Waypoint = Create_Waypoint(2,2,10,0,10)
P2_N3.Waypoint = Create_Waypoint(2,3,-10,0,10)
P2_N4.Waypoint = Create_Waypoint(2,4,-10,0,-10)

Count_Waypoint_Nodes()

FPS_Timer = CreateTimer(60)


While Not KeyDown (1)

	Update_Objects()
	WaitTimer(FPS_Timer)

UpdateWorld
RenderWorld

	Text 0,0,"Ai State: " + AI_State
	;Text 150,0, "Enemy distance: " + EntityDistance (Enemy\Mesh,Player\Mesh)
	Text 0,15, "Active waypoint path: " + Enemy\Waypoint_Path
	Text 0,30, "Active waypoint: " + Enemy\Waypoint_Node
	Text 0,45, "Waypoint nodes: " + Node_Count
	Text 0,75, "Temp waypoint path 1: " + Temp_Node_Path1
	Text 0,90, "Temp waypoint path 2: " + Temp_Node_Path2
	Text 0,560, "Use arrows to move player."
	Text 0,575, "Press 'Space' to change waypoint paths."
	
Flip
Wend
End



;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;



;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
Type Waypoint
	Field mesh
	Field Node_Number%
	Field Flag
	Field Path_Number%
End Type


Function Create_Waypoint.Waypoint(Waypoint_Path_Number%,Waypoint_Node_Number%,X#,Y#,Z#)
	WP.Waypoint = New waypoint
	WP\mesh = CreateCube()
		EntityColor WP\mesh,0,0,255
		ScaleEntity WP\Mesh,.5,.5,.5
	WP\Path_Number = Waypoint_Path_Number
	WP\Node_Number = Waypoint_Node_Number
	WP\Flag = False
	PositionEntity WP\mesh,X,Y,Z
	
	Return WP
End Function

Function Count_Waypoint_Nodes()
	Node_Count = 0 
	
	For WP.Waypoint = Each waypoint
		If WP\Path_Number = Enemy\Waypoint_Path Then
			Node_Count = Node_Count + 1
		End If
	Next
End Function


;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
Type World_Objects
	Field Class%
	Field Mesh%
	Field Waypoint_Path%
	Field Waypoint_Node%
End Type


Function Create_Objects.World_Objects(Class%)

	WO.World_Objects = New World_Objects
	WO\Class = Class
	
	Select Class
		Case PLAYER_CLASS
			WO\Mesh = CreateCone(8)
			PositionEntity WO\Mesh,-15,0,-10
			RotateMesh WO\Mesh,90,0,0
			ScaleEntity WO\Mesh,1,1,1.5
			EntityColor WO\Mesh,0,255,0
			
		Case ENEMY_CLASS
			WO\Mesh = CreateCone(8)
			PositionEntity WO\Mesh,15,0,10
			RotateMesh WO\Mesh,90,0,0
			ScaleEntity WO\Mesh,1,1,1.5
			RotateEntity WO\Mesh,0,180,0
			EntityColor WO\Mesh,255,0,0
			WO\Waypoint_Path = 1
			WO\Waypoint_Node = 1
	End Select
	
	Return WO
End Function

Function Update_Objects()

	For WO.World_Objects = Each World_Objects
		Select WO\Class
		
			Case PLAYER_CLASS
				If KeyDown(200) MoveEntity WO\Mesh,0,0,.15
				If KeyDown(205) TurnEntity WO\Mesh,0,-2,0
				If KeyDown(203) TurnEntity WO\Mesh,0,2,0
				
			Case ENEMY_CLASS
				If EntityDistance (Enemy\Mesh,Player\Mesh) > 20 Then AI_State = 0
				If Next_Waypoint > Node_Count Next_Waypoint = 1
				
				If KeyHit(57) ;Change waypoint paths & store temp waypoint node
					
					If WO\Waypoint_Path = 1 
						Temp_Node_Path1 = Next_Waypoint
					Else If WO\Waypoint_Path = 2
						Temp_Node_Path2 = Next_Waypoint
					End If
					
					WO\Waypoint_Path = WO\Waypoint_Path + 1
					
					If WO\Waypoint_Path > 2 Then WO\Waypoint_Path = 1
					 	
					Count_Waypoint_Nodes()
					
				End If
				
				If Next_Waypoint > Node_Count Next_Waypoint = 1
				WO\Waypoint_Node = Next_Waypoint	
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;Enemy AI;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
					Select AI_State
	
						Case PATROL_WAYPOINTS% ;patrol waypoints
							If EntityDistance (Enemy\Mesh,Player\Mesh) < 20 Then AI_State = HEAD_TOWARDS_PLAYER ;1
				
							For WP.Waypoint = Each Waypoint
							
							;If WP\Path_Number = WO\Waypoint_Path Then If WP\Node_Number <> Temp_Node_Path1
							;	WO\Waypoint_Node = Temp_Node_Path1
							;End If
								
								If WP\Path_Number = WO\Waypoint_Path Then If WP\Node_Number = WO\Waypoint_Node
									WP\Flag = True 
					 				YawToEntity(Enemy\Mesh,WP\mesh,2)
									EntityColor WP\mesh,0,255,255
								End If
					
								If EntityDistance (Enemy\Mesh,WP\mesh) < 2 And WP\Flag = True
									WP\Flag = False
									EntityColor WP\mesh,0,0,255
									Next_Waypoint = Next_Waypoint + 1	
								End If
								
								If WP\Path_Number <> WO\Waypoint_Path
									WP\Flag = False
									EntityColor WP\mesh,0,0,255
								End If

							Next
				
		
						Case HEAD_TOWARDS_PLAYER ;head towards player
							YawToEntity(Enemy\Mesh,Player\Mesh,2)
							If EntityDistance (Enemy\Mesh,Player\Mesh) < 8 Then AI_State = EVADE_COLLISION ;2
				
				
						Case EVADE_COLLISION ;Evade collission
							YawFromEntity(Enemy\Mesh,Player\Mesh,2)
							If EntityDistance (Enemy\Mesh,Player\Mesh) > 15 Then AI_State = HEAD_TOWARDS_PLAYER ;1
				
					End Select
				
				MoveEntity Enemy\Mesh,0,0,.1
				
			Case WHATEVER_CLASS

		End Select
		
	Next
End Function



;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
Function YawToEntity( src_entity, dest_entity, rate# )
; Turns 'src_entity' to point at 'dest_entity' at the rotation rate specified by 'rate#'.

	Local target_yaw# = DeltaYaw( src_entity, dest_entity )
	
	; If the required correction amount is less than the correction amount to be applied...
	If Abs( target_yaw# ) < rate#
		 ;Point 'src_entity' directly at 'dest_entity' To prevent jittering.
		TurnEntity src_entity, 0.0, target_yaw#, 0.0
	Else
		; Turn 'src_entity' gradually towards 'dest_entity'.
		TFormPoint 0,0,0,  dest_entity, src_entity
	    TurnEntity src_entity, 0.0, rate# * -Sgn( TFormedX() ), 0.0

	EndIf
End Function


Function YawFromEntity( src_entity, dest_entity, rate# )
; Turns 'src_entity' away frm 'dest_entity' at the rotation rate specified by 'rate#'.

	Local target_yaw# = DeltaYaw( src_entity, dest_entity )
	
	; If the required correction amount is less than the correction amount to be applied...
	If Abs( target_yaw# ) < rate#
		 ;Point 'src_entity' away from 'dest_entity' To prevent jittering.
		TurnEntity src_entity, 0.0, -target_yaw#, 0.0
	Else
		; Turn 'src_entity' gradually away from 'dest_entity'.
		TFormPoint 0,0,0,  dest_entity, src_entity
	    TurnEntity src_entity, 0.0, rate# * Sgn( TFormedX() ), 0.0
		
	EndIf
End Function

Aussie

(Posted 2014) [#2]

Had another look at it this morning with a fresh set of eyes & got it sorted. Here is the code if anyone wants to have a look at what i did or if anyone wants to offer some suggestions on better ways to do what i am doing.

Next up some more Ai states.

Graphics3D 800,600,0,2

SetBuffer BackBuffer()

Global AI_State = PATROL_WAYPOINTS
Global Next_Waypoint# = 1
Global Player.World_Objects = Create_Objects(PLAYER_CLASS)
Global Enemy.World_Objects = Create_Objects(ENEMY_CLASS)
Global Current_Waypoint_Path% = 1
Global Node_Count% = 0
Global WP.Waypoint
Global Path_Change = False

Global Temp_Node_Path1 = 1
Global Temp_Node_Path2 = 1

Const PLAYER_CLASS% = 1
Const ENEMY_CLASS% = 2

Const PATROL_WAYPOINTS% = 0
Const HEAD_TOWARDS_PLAYER% = 1
Const EVADE_COLLISION% = 2

camera = CreateCamera()
	PositionEntity camera,0,40,0
	RotateEntity camera,90,0,0
	
light = CreateLight()
	RotateEntity light,90,0,0
	
P1_N1.Waypoint = Create_Waypoint(1,1,35,0,-25)
P1_N2.Waypoint = Create_Waypoint(1,2,35,0,25)
P1_N3.Waypoint = Create_Waypoint(1,3,-35,0,25)
P1_N4.Waypoint = Create_Waypoint(1,4,-35,0,-25)
P1_N5.Waypoint = Create_Waypoint(1,5,0,0,0)

P2_N1.Waypoint = Create_Waypoint(2,1,10,0,-10)
P2_N2.Waypoint = Create_Waypoint(2,2,10,0,10)
P2_N3.Waypoint = Create_Waypoint(2,3,-10,0,10)
P2_N4.Waypoint = Create_Waypoint(2,4,-10,0,-10)

Count_Waypoint_Nodes()

FPS_Timer = CreateTimer(60)


While Not KeyDown (1)

	Update_Objects()
	WaitTimer(FPS_Timer)

UpdateWorld
RenderWorld

	Text 0,0,"Ai State: " + AI_State
	;Text 150,0, "Enemy distance: " + EntityDistance (Enemy\Mesh,Player\Mesh)
	Text 0,15, "Active waypoint path: " + Enemy\Waypoint_Path
	Text 0,30, "Active waypoint: " + Enemy\Waypoint_Node
	Text 0,45, "Waypoint nodes: " + Node_Count
	Text 0,75, "Temp waypoint path 1: " + Temp_Node_Path1
	Text 0,90, "Temp waypoint path 2: " + Temp_Node_Path2
	Text 0,560, "Use arrows to move player."
	Text 0,575, "Press 'Space' to change waypoint paths."
	
Flip
Wend
End



;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;



;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
Type Waypoint
	Field mesh
	Field Node_Number%
	Field Flag
	Field Path_Number%
End Type


Function Create_Waypoint.Waypoint(Waypoint_Path_Number%,Waypoint_Node_Number%,X#,Y#,Z#)
	WP.Waypoint = New waypoint
	WP\mesh = CreateCube()
		EntityColor WP\mesh,0,0,255
		ScaleEntity WP\Mesh,.5,.5,.5
	WP\Path_Number = Waypoint_Path_Number
	WP\Node_Number = Waypoint_Node_Number
	WP\Flag = False
	PositionEntity WP\mesh,X,Y,Z
	
	Return WP
End Function

Function Count_Waypoint_Nodes()
	Node_Count = 0 
	
	For WP.Waypoint = Each waypoint
		If WP\Path_Number = Enemy\Waypoint_Path Then
			Node_Count = Node_Count + 1
		End If
	Next
End Function


;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
Type World_Objects
	Field Class%
	Field Mesh%
	Field Waypoint_Path%
	Field Waypoint_Node%
End Type


Function Create_Objects.World_Objects(Class%)

	WO.World_Objects = New World_Objects
	WO\Class = Class
	
	Select Class
		Case PLAYER_CLASS
			WO\Mesh = CreateCone(8)
			PositionEntity WO\Mesh,-15,0,-10
			RotateMesh WO\Mesh,90,0,0
			ScaleEntity WO\Mesh,1,1,1.5
			EntityColor WO\Mesh,0,255,0
			
		Case ENEMY_CLASS
			WO\Mesh = CreateCone(8)
			PositionEntity WO\Mesh,15,0,10
			RotateMesh WO\Mesh,90,0,0
			ScaleEntity WO\Mesh,1,1,1.5
			RotateEntity WO\Mesh,0,180,0
			EntityColor WO\Mesh,255,0,0
			WO\Waypoint_Path = 1
			WO\Waypoint_Node = 1
	End Select
	
	Return WO
End Function

Function Update_Objects()

	For WO.World_Objects = Each World_Objects
		Select WO\Class
		
			Case PLAYER_CLASS
				If KeyDown(200) MoveEntity WO\Mesh,0,0,.15
				If KeyDown(205) TurnEntity WO\Mesh,0,-2,0
				If KeyDown(203) TurnEntity WO\Mesh,0,2,0
				
			Case ENEMY_CLASS
				If EntityDistance (Enemy\Mesh,Player\Mesh) > 20 Then AI_State = 0
				If Next_Waypoint > Node_Count Next_Waypoint = 1
				
				If KeyHit(57) ;Change waypoint paths & store temp waypoint node
					
					If WO\Waypoint_Path = 1 
						Temp_Node_Path1 = Next_Waypoint
					Else If WO\Waypoint_Path = 2
						Temp_Node_Path2 = Next_Waypoint
					End If
					
					WO\Waypoint_Path = WO\Waypoint_Path + 1
					
					If WO\Waypoint_Path > 2 Then WO\Waypoint_Path = 1
					 	
					Count_Waypoint_Nodes()
					Path_Change = True
					
				End If
				
				If Next_Waypoint > Node_Count Next_Waypoint = 1
				WO\Waypoint_Node = Next_Waypoint	
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;Enemy AI;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
					Select AI_State
	
						Case PATROL_WAYPOINTS% ;patrol waypoints
							If EntityDistance (Enemy\Mesh,Player\Mesh) < 20 Then AI_State = HEAD_TOWARDS_PLAYER ;1
				
							For WP.Waypoint = Each Waypoint
			;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;Return to last waypoint on previous path;;;;;;;;;;;;;;;;;;;;;;;; 
								If Path_Change = True  
									If WO\Waypoint_Path = 1
										WO\Waypoint_Node = Temp_Node_Path1
										Next_Waypoint = Temp_Node_Path1 
									Else If WO\Waypoint_Path = 2
										WO\Waypoint_Node = Temp_Node_Path2
										Next_Waypoint = Temp_Node_Path2 
									End If
									Path_Change = False
								End If
			;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;					
								If WP\Path_Number = WO\Waypoint_Path Then If WP\Node_Number = WO\Waypoint_Node
									WP\Flag = True 
					 				YawToEntity(Enemy\Mesh,WP\mesh,2)
									EntityColor WP\mesh,0,255,255
								End If
					
								If EntityDistance (Enemy\Mesh,WP\mesh) < 2 And WP\Flag = True
									WP\Flag = False
									EntityColor WP\mesh,0,0,255
									Next_Waypoint = Next_Waypoint + 1	
								End If
								
								If WP\Path_Number <> WO\Waypoint_Path
									WP\Flag = False
									EntityColor WP\mesh,0,0,255
								End If

							Next
				
		
						Case HEAD_TOWARDS_PLAYER ;head towards player
							YawToEntity(Enemy\Mesh,Player\Mesh,2)
							If EntityDistance (Enemy\Mesh,Player\Mesh) < 8 Then AI_State = EVADE_COLLISION ;2
				
				
						Case EVADE_COLLISION ;Evade collission
							YawFromEntity(Enemy\Mesh,Player\Mesh,2)
							If EntityDistance (Enemy\Mesh,Player\Mesh) > 15 Then AI_State = HEAD_TOWARDS_PLAYER ;1
				
					End Select
				
				MoveEntity Enemy\Mesh,0,0,.1
				
			Case WHATEVER_CLASS

		End Select
		
	Next
End Function



;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
Function YawToEntity( src_entity, dest_entity, rate# )
; Turns 'src_entity' to point at 'dest_entity' at the rotation rate specified by 'rate#'.

	Local target_yaw# = DeltaYaw( src_entity, dest_entity )
	
	; If the required correction amount is less than the correction amount to be applied...
	If Abs( target_yaw# ) < rate#
		 ;Point 'src_entity' directly at 'dest_entity' To prevent jittering.
		TurnEntity src_entity, 0.0, target_yaw#, 0.0
	Else
		; Turn 'src_entity' gradually towards 'dest_entity'.
		TFormPoint 0,0,0,  dest_entity, src_entity
	    TurnEntity src_entity, 0.0, rate# * -Sgn( TFormedX() ), 0.0

	EndIf
End Function


Function YawFromEntity( src_entity, dest_entity, rate# )
; Turns 'src_entity' away frm 'dest_entity' at the rotation rate specified by 'rate#'.

	Local target_yaw# = DeltaYaw( src_entity, dest_entity )
	
	; If the required correction amount is less than the correction amount to be applied...
	If Abs( target_yaw# ) < rate#
		 ;Point 'src_entity' away from 'dest_entity' To prevent jittering.
		TurnEntity src_entity, 0.0, -target_yaw#, 0.0
	Else
		; Turn 'src_entity' gradually away from 'dest_entity'.
		TFormPoint 0,0,0,  dest_entity, src_entity
	    TurnEntity src_entity, 0.0, rate# * Sgn( TFormedX() ), 0.0
		
	EndIf
End Function