Rotating Entity Child to another Entity Child

Blitz3D Forums/Blitz3D Programming/Rotating Entity Child to another Entity Child

Spike314

(Posted 2014) [#1]

Hi All

I'm trying to line up prefab entities with each other but it doesn't work all the time.

Each entity have children which are the points that require to be lined up by rotating the main entity only this is want I'm trying to achieve Bake Your Own 3D Dungeons With Procedural Recipes

This is the code I have to position and rotate the entity

	If New_Building= True
		B.Building = New Building

		B\M=CopyEntity(Junction(Rand(0,1)))	
		B\Typ = TYP_JUNCTION
		GetExits(B)

	Else
		B.Building =Last Building

		Loop_Count=Loop_Count+1
		
	EndIf

		If Loop_Count=>Max_loop Then Return
		
	For E=0 To B\Exit_Count-1

		If B\Exits_Used[E]=0

			yaw# = EntityYaw(B\Exits[E],1)
			x# = EntityX(B\Exits[E],1)
			y# = EntityY(B\Exits[E],1)
			z# = EntityZ(B\Exits[E],1)
			
			Select B\Typ
				Case TYP_JUNCTION

					NB.Building = New Building					
					NB\M=CopyEntity(Corridor(Rand(0,2)))									
					NB\Typ = TYP_CORRIDOR
					
				Case TYP_ROOM
				
				Case TYP_CORRIDOR

					NB.Building = New Building					
					NB\M=CopyEntity(Junction(Rand(0,1)))									
					NB\Typ = TYP_JUNCTION
				
			End Select

			GetExits(NB)
			ME = SelectExit(NB)			
			nyaw# = EntityYaw(NB\Exits[ME],1)
			nx# = EntityX(NB\Exits[ME],1)
			ny# = EntityY(NB\Exits[ME],1)
			nz# = EntityZ(NB\Exits[ME],1)
;THIS WERE THE PROBLEM IS
			TFormVector nx,ny,nz,0,B\Exits[E]		;<<			
			AlignToVector NB\M,TFormedX(),0,TFormedZ(),1,1;<<
			TurnEntity NB\M,0,DeltaYaw(NB\Exits[ME],NB\M)-90,0					;<<
					
			PositionEntity NB\M,x,y,z
			MoveEntity NB\M,-nx,-ny,-nz
					
			B\Exits_Used[E] = True
			NB\Exits_Used[ME] = True
			EntityParent NB\M,B\M
		;DEBUG INFO
			R=Rand(0,255):G=Rand(0,255):BL=Rand(0,255)
			EntityColor GetChild(B\Exits[E],1),R,G,BL
			EntityColor GetChild(NB\Exits[ME],1),R,G,BL			

			GenBuilding()
		EndIf
		
	Next

OK Ive converted some of the code on the page above but the angles still are not right.
Here is the code.

Function MatchExits(oldExit,newExit)
;		var newModule = newExit.transform.parent;
		newModule = GetParent(newExit)
;		var forwardVectorToMatch = -oldExit.transform.forward;
		forwardVectorToMatch = -EntityZ(oldExit,1)
;		var correctiveRotation = Azimuth(forwardVectorToMatch) - Azimuth(newExit.transform.forward);
		correctiveRotation# = Azimuth(EntityX(OldExit,1),EntityY(OldExit,1),forwardVectorToMatch)-Azimuth(EntityX(newExit,1),EntityY(newExit,1),EntityZ(newExit,1))						
;		newModule.RotateAround(newExit.transform.position, Vector3.up, correctiveRotation);
		RotateEntity newModule,0,correctiveRotation,0
;		var correctiveTranslation = oldExit.transform.position - newExit.transform.position;
		correctiveTranslationX# = EntityX(OldExit,1) - EntityX(newExit,1)
		correctiveTranslationY# = EntityY(OldExit,1) - EntityY(newExit,1)
		correctiveTranslationZ# = EntityZ(OldExit,1) - EntityZ(newExit,1)
;		newModule.transform.position += correctiveTranslation;
		PositionEntity newModule,correctiveTranslationX,correctiveTranslationY,correctiveTranslationZ
End Function

Function Azimuth#(x#,y#,z#)
		;Vector3.Angle(Vector3.forward, vector) * Mathf.Sign(vector.x);
		Return DotAngleBetween(TVector(0,0,1),TVector(x,y,z))*Sgn(z)
End Function

Kryzon

(Posted 2014) [#2]

It's difficult to grasp without a visualisation. Please post one or more screenshots.

Spike314

(Posted 2014) [#3]

Here is one using the top code.

The color cubes show the entities that are joined but the angle on most of them are wrong.

here is another one using the same code and most of them are fine and lined up correctly

Kryzon

(Posted 2014) [#4]

Thank you. It's easier to understand now.

It seems the problem lies with the alignment. After some reflecting, the world-space yaw rotation of an exit of a module is the world-space yaw rotation of the module plus the local yaw rotation that the exit has in relation to the module.
Therefore, to make the exit be aligned to some specific world-space yaw rotation, first we need to calculate that relative rotation of the exit and then rotate the module so it makes that exit align to what we want.
Then you can move the module to the target exit and offset the module by a certain amount so one exit is placed on the other.

If I'm not mistaken, the code should be the following:

;Consider module "A" and module "B."
;We want to move and align a certain exit of module A with a certain exit of module B.

;First, rotate the module A so that the exit from this module is 
;aligned (in the opposite direction) to the target exit from module B, in the yaw axis.
Local targetExitYaw# = EntityYaw( exitB, True ) + 180 ;World space, and opposite direction.
Local newModuleYaw# = EntityYaw( moduleA, True ) + ( targetExitYaw - EntityYaw( exitA, True ) )
RotateEntity( moduleA, 0, newModuleYaw, 0, True )

;Second, move the module A and offset it so that the exit from this module is on top of the target exit of module B.
PositionEntity( moduleA, EntityX( exitB, True ), EntityY( exitB, True ), EntityZ( exitB, True ), True )
Local offsetX# = EntityX( moduleA, True ) - EntityX( exitB, True )
Local offsetY# = EntityY( moduleA, True ) - EntityY( exitB, True )
Local offsetZ# = EntityZ( moduleA, True ) - EntityZ( exitB, True )
TranslateEntity( moduleA, offsetX, offsetY, offsetZ, True )

Spike314

(Posted 2014) [#5]

After changing this line

PositionEntity( moduleA, EntityX( exitB, True ), EntityY( exitB, True ), EntityZ( exitB, True ), True )

to this

PositionEntity( moduleA, EntityX( exitA, True ), EntityY( exitA, True ), EntityZ( exitA, True ), True )

I still get the same result maybe my prefab meshes are are wrong as each exit has its own yaw and always points out.

Like so

     0   
-90 -|- 90
    180

I will check all my prefab meshes to make sure all the angles a correct.

Ive checked all my Prefab meshes and all the angles on them are correct so its has to be code.

Ive uploaded my code and media files HERE

Spike314

(Posted 2014) [#6]

Ive re-write the code it works better but still get the same problem if anyone can help

Global FPS_Oldtime, FPS_Newtime, FPS_Ticks
Global FPS_Current,FPS_Final
Global FPS_SampleRate   = 5  ;Take a sample every N ticks
Global FPS_Samples      = 10 ;Samples to average (res of the average)
Global FPS_BufferIndex  = 1
Global FPS_Font
Dim FPS_Buffer(10)


Const TYP_JUNCTION	= 1
Const TYP_ROOM 		= 2
Const TYP_CORRIDOR	= 3

Dim Junction(2)
Dim Corridor(3)
Dim Room(2)

Graphics3D 800,600,32,2

SeedRnd(999)

Junction(0) = LoadAnimMesh("Media\Junction01.b3d"):HideEntity Junction(0)
Junction(1) = LoadAnimMesh("Media\Junction02.b3d"):HideEntity Junction(1)
Corridor(0) = LoadAnimMesh("Media\Corridor01.b3d"):HideEntity Corridor(0)
Corridor(1) = LoadAnimMesh("Media\Corridor02.b3d"):HideEntity Corridor(1)
Corridor(2) = LoadAnimMesh("Media\Corridor03.b3d"):HideEntity Corridor(2)
Room(0)= LoadAnimMesh("Media\Room01.b3d"):HideEntity Room(0)
Room(1) = LoadAnimMesh("Media\Room02.b3d"):HideEntity Room(1)

Global Max_loop=10
Global Loop_Count=0


cam=CreateCamera()

l=CreateLight()

;GenBuilding(True)

NewGen()

Repeat

If KeyDown(200) MoveEntity Cam,0,0,1
If KeyDown(208) MoveEntity Cam,0,0,-1
If KeyDown(205) MoveEntity Cam,1,0,0
If KeyDown(203) MoveEntity Cam,-1,0,0

If MouseDown(2)
	TurnEntity Cam,MouseYSpeed()/4,-MouseXSpeed()/4,0
	MoveMouse GraphicsWidth()/2,GraphicsHeight()/2
EndIf



	UpdateWorld	
	RenderWorld
	Get_FPS()
	Flip

Until KeyHit(1)

Type Building
	Field M
	Field Typ
	Field Exits[10]
	Field Exits_Used[10]
	Field Exit_Count
End Type

Function NewGen()
	B.Building = First Building

	If B=Null
		B.Building = New Building

		B\M=CopyEntity(Junction(Rand(0,1)))	
		B\Typ = TYP_JUNCTION
		GetExits(B)			
	EndIf
	
	For B.Building=Each Building
		For E=0 To B\Exit_Count-1
			If B\Exits_Used[E]=0

				Select B\Typ
					Case TYP_JUNCTION
	
						NB.Building = New Building					
						NB\M=CopyEntity(Corridor(Rand(0,2)))									
						NB\Typ = TYP_CORRIDOR
						
					Case TYP_ROOM

						NB.Building = New Building
						NB\M=CopyEntity(Corridor(Rand(0,2)))									
						NB\Typ = TYP_CORRIDOR
						
					Case TYP_CORRIDOR
						NB.Building = New Building					

						Choose = Rand(1,2)
						If Choose = 1
							NB\M=CopyEntity(Room(Rand(0,1)))									
							NB\Typ = TYP_ROOM						
						Else								
							NB\M=CopyEntity(Junction(Rand(0,1)))									
							NB\Typ = TYP_JUNCTION
						EndIf
					
				End Select
			
				GetExits(NB)
				ME = SelectExit(NB)
				
				MatchExits(B\Exits[E],NB\Exits[ME])
				
				B\Exits_Used[E] = True
				NB\Exits_Used[ME] = True
				EntityParent NB\M,B\M
			;DEBUG INFO
				R=Rand(0,255):G=Rand(0,255):BL=Rand(0,255)
				EntityColor GetChild(B\Exits[E],1),R,G,BL
				EntityColor GetChild(NB\Exits[ME],1),R,G,BL
			
			EndIf
		Next
		
		Loop_Count=Loop_Count+1
		If Loop_Count=>Max_loop Then Return
	Next
End Function

Function GenBuilding(New_Building=False)

	If New_Building= True
		B.Building = New Building

		B\M=CopyEntity(Junction(Rand(0,1)))	
		B\Typ = TYP_JUNCTION
		GetExits(B)

	Else
		B.Building =Last Building

		Loop_Count=Loop_Count+1
		
	EndIf

		If Loop_Count=>Max_loop Then Return
		
	For E=0 To B\Exit_Count-1

		If B\Exits_Used[E]=0

			yaw# = EntityYaw(B\Exits[E],1)
			x# = EntityX(B\Exits[E],1)
			y# = EntityY(B\Exits[E],1)
			z# = EntityZ(B\Exits[E],1)
			
			Select B\Typ
				Case TYP_JUNCTION

					NB.Building = New Building					
					NB\M=CopyEntity(Corridor(Rand(0,2)))									
					NB\Typ = TYP_CORRIDOR
					
				Case TYP_ROOM
				
				Case TYP_CORRIDOR

					NB.Building = New Building					
					NB\M=CopyEntity(Junction(Rand(0,1)))									
					NB\Typ = TYP_JUNCTION
				
			End Select

			GetExits(NB)
			ME = SelectExit(NB)			
			nyaw# = EntityYaw(NB\Exits[ME],1)
			nx# = EntityX(NB\Exits[ME],1)
			ny# = EntityY(NB\Exits[ME],1)
			nz# = EntityZ(NB\Exits[ME],1)
	
			MatchExits(B\Exits[E],NB\Exits[ME])
			
			B\Exits_Used[E] = True
			NB\Exits_Used[ME] = True
			EntityParent NB\M,B\M
		;DEBUG INFO
			R=Rand(0,255):G=Rand(0,255):BL=Rand(0,255)
			EntityColor GetChild(B\Exits[E],1),R,G,BL
			EntityColor GetChild(NB\Exits[ME],1),R,G,BL						
			GenBuilding()
		EndIf
		
	Next

End Function

Function GetExits(B.Building)
	Main=GetChild(B\M,1)
	For A=1 To CountChildren(Main)
		child = GetChild(Main,A)
		If Left(EntityName(Child),4)="Exit"
			B\Exits[B\Exit_Count]=Child
			B\Exit_Count=B\Exit_Count+1		
;DEBUG INFO			
			C=CreateCube()
			PositionEntity C,EntityX(Child,1),EntityY(Child,1)+1,EntityZ(Child,1)
			RotateEntity C,0,EntityYaw(Child,1),0
			EntityParent C,Child
			EntityFX C,1
		;	EntityAlpha C,0.5
			ScaleEntity C,.2,.2,.2
		
		EndIf
	Next
End Function

Function SelectExit(B.Building)
	Repeat
		E=Rand(0,B\Exit_Count)
		If E<B\Exit_Count
			If B\Exits_Used[E]=0 Then Return E
		EndIf
	Forever
End Function

Function MatchExits(ExitA,ExitB)

moduleA=GetParent (ExitB)
Local targetExitYaw# = EntityYaw( exitB, True ) + 180 ;World space, and opposite direction.
Local newModuleYaw# = EntityYaw( moduleA, True ) + ( targetExitYaw - EntityYaw( exitA, True ) )
RotateEntity( moduleA, 0, newModuleYaw, 0, True )

;Second, move the module A and offset it so that the exit from this module is on top of the target exit of module B.
PositionEntity( moduleA, EntityX( ExitA, True ), EntityY( ExitA, True ), EntityZ( ExitA, True ), True )
Local offsetX# = EntityX( moduleA, True ) - EntityX( exitB, True )
Local offsetY# = EntityY( moduleA, True ) - EntityY( exitB, True )
Local offsetZ# = EntityZ( moduleA, True ) - EntityZ( exitB, True )
TranslateEntity( moduleA, offsetX, offsetY, offsetZ, True )

End Function

Function Get_FPS(PosX#=10,PosY#=2)
         If FPS_Font = 0 Then
              FPS_Font=LoadFont("New Times Roman",14)
         EndIf
         FPS_Newtime = MilliSecs()
         FPS_Ticks = FPS_Ticks + 1
         If FPS_Ticks > FPS_SampleRate Then
            FPS_Current = FPS_Newtime - FPS_Oldtime
            If FPS_Current = 0 Then FPS_Current = 1000 Else FPS_Current = 1000/FPS_Current
            FPS_Buffer(FPS_BufferIndex) = FPS_Current
            FPS_BufferIndex = FPS_BufferIndex + 1
            If FPS_BufferIndex > FPS_Samples Then
                 For FPS_Count = 1 To FPS_Samples
                     FPS_Master = FPS_Master + FPS_Buffer(FPS_Count)                      
                 Next
                 FPS_Final = FPS_Master / FPS_Samples
                 FPS_BufferIndex = 1
            EndIf
            FPS_Ticks = 0
         EndIf
         FPS_Oldtime = MilliSecs()
         SetFont(FPS_Font)
         Text(PosX#,PosY#,"FPS:"+FPS_Final) 
         ;Return FPS_Final
End Function

_PJ_	(Posted 2014) [#7]

Admittedly, I only skimmed through the post here, but this may be of use I hope:

Assuming there's no transformations to the actual entity(ies)in question with regards to say, TFormPoint etc.

;Moves Entity by amount Distance# towards a point specified by XYZ coordinates.
Function MoveToPoint(hen_Entity,f_X#,f_Y#,f_Z#,f_Distance#=0.0,b_Global=True)
	Local f_EX#=f_X#-EntityX#(hen_Entity,b_Global);
	Local f_EY#=f_Y#-EntityY#(hen_Entity,b_Global);
	Local f_EZ#=f_Z#-EntityZ#(hen_Entity,b_Global);
	
	Local f_ActualDistance#=Sqr((f_EX*f_EX)+(f_EY*f_EY)+(f_EZ*f_EZ));
	
	If ((f_ActualDistance<(abs(f_Distance)))
		f_Distance=f_ActualDistance;
	End If;
	
	TranslateEntity hen_Entity,Sgn(f_EX#)*Distance,Sgn(f_EY#)*Distance,Sgn(f_EZ#)*f_Distance,b_Global;
End Function;

;Rotates an Entity to point directly at given global coordinates, or origin if parameter arguments omitted
Function PointAt(hen_Entity, f_X#=0,f_Y#=0,f_Z#=0)
	Local f_Xdiff# = EntityX(hen_Entity,True)-f_x#;
	Local f_Ydiff# = EntityY(hen_Entity,True)-f_y#;
	Local f_Zdiff# = EntityZ(hen_Entity,True)-f_z#;
	
	Local f_Dist#=Sqr#((f_Xdiff#*f_Xdiff#)+(f_Zdiff#*f_Zdiff#));
	Local f_Pitch# = ATan2(f_Ydiff#,f_Dist#);
	Local f_Yaw# = ATan2(f_Xdiff,0-f_Zdiff#);
	RotateEntity hen_Entity,f_Pitch#,f_Yaw#,0,True;
End Function;

Kryzon

(Posted 2014) [#8]

Once you have the delta vector you can use AlignToVector and spare the Sqr and ATan calls:

Function PointAt( entity, x# = 0.0, y# = 0.0, z# = 0.0 )
	Local deltaX# = x - EntityX( entity, True )
	Local deltaY# = y - EntityY( entity, True )
	Local deltaZ# = z - EntityZ( entity, True )

	AlignToVector( entity, deltaX, deltaY, deltaZ, 3 )
End Function