CreateBank

Blitz3D Forums/Blitz3D Programming/CreateBank

Yue	(Posted 2014) [#1]

I never could understand a memory bank. can someone explain me the easiest possible way to work with memory banks please.

Floyd

(Posted 2014) [#2]

It is simply a block of empty memory. You can do whatever you want with it.

Common uses might be to load a file into memory and then process it in some way. Another use is with external programs ( DLLs ) which need access to memory within your program. You tell the DLL the address of the memory.

I once needed to examine the bits in a floating point number. I used something like this:

Graphics 600, 400, 0, 2

bank = CreateBank(4)

x# = 25

PokeFloat bank, 0, x       ; put 4-byte Float into bank
n = PeekInt( bank, 0 )     ; read it back as if it were an Int, so we can get at the bits

Print
Print " The floating point value: " + x
Print
Print "   Consists of these bits: " + Bin(n)

WaitKey

Charrua

(Posted 2014) [#3]

nice example.

they gives you the possibility of write floats, ints (32 bits each) and then read them back as bytes and vice versa

you may, for instance create a bank of 4 bytes as floyd did and store
alpha, red, green and blue in its corresponding offsets and then read the color back as integer to use in pixel handling funtions or read pixels
store on a bank and read individual color components... etc

there are many ways for doing tasks, banks gives you alternatives

(for handling colors you may use bit_shifs also, it's a matter of taste)

Krischan

(Posted 2014) [#4]

You can do cool things with banks, for example image manipulation (here: 8bit grayscale for heightmaps but could be extended easy to 16,24,32 bits). As far as I remember it is even faster than the lockbuffer/readpixel/writepixel commands.

; ----------------------------------------------------------------------------
; Load a RAW Imagebank
; ----------------------------------------------------------------------------
Function LoadBank(filename$,offset%=0)
	
	Local f%=OpenFile(filename$)
	
	If f Then
		
		Local size%=FileSize(filename)
		Local bank%=CreateBank(size)
		SeekFile f,offset
		ReadBytes(bank,f,0,size)
		CloseFile f
		Return bank
		
	Else
		
		Return False
		
	EndIf
	
End Function

; ----------------------------------------------------------------------------
; Save a RAW Imagebank
; ----------------------------------------------------------------------------
Function SaveBank(bank%,filename$)
	
	Local f%=WriteFile(filename)
	
	WriteBytes (bank,f,0,BankSize(bank))
	
	CloseFile f
	
End Function

; ----------------------------------------------------------------------------
; Create a greyscale Image from a RAW Imagebank
; ----------------------------------------------------------------------------
Function CreateImageFromBank(bank%,width%,height%)
	
	Local x%,y%,h%
	Local image%=CreateImage(width,height)
	Local buffer%=ImageBuffer(image)
	
	LockBuffer buffer
	
	For x=0 To width-1
		
		For y=0 To height-1
			
			h=GetBankPixel(bank,x,y,width)
			
			WritePixelFast x,y,CombineARGB(255,h,h,h),buffer
			
		Next
		
	Next
	
	UnlockBuffer buffer
	
	Return image
	
End Function

; ----------------------------------------------------------------------------
; Bilinear scale a RAW Imagebank to a different size using a ratio variable
; ----------------------------------------------------------------------------
Function ScaleBank(bank%,width%,height%,ratio#)
	
	Local x%,y%,c%
	Local ratio2w#=(ratio#*width-1)/(width-1.0)
	Local ratio2h#=(ratio#*height-1)/(height-1.0)
	
	Local newbank%=CreateBank((width*ratio)*(height*ratio))
	
	For y=0 To (height*ratio)-1
		
		For x=0 To (width*ratio)-1
			
			Local u# = x*1.0/ratio2w#
			Local v# = y*1.0/ratio2h#
			
			c%=Bilinear(bank,width,height,u,v)
			
			SetBankPixel(newbank,c,x,y,width*ratio)
			
		Next
		
	Next
	
	Return newbank
	
End Function

; ----------------------------------------------------------------------------
; Reads a RAW Imagebank Pixel at a given position
; ----------------------------------------------------------------------------
Function GetBankPixel(bank%,px%,py%,width%,offset%=0)
	
	Return PeekByte(bank,((py*width)+px+offset) Mod BankSize(bank))
	
End Function

; ----------------------------------------------------------------------------
; Writes a RAW Imagebank Pixel at a given position
; ----------------------------------------------------------------------------
Function SetBankPixel(bank%,value,px%,py%,width%)
	
	PokeByte(bank,(py*width)+px,value Mod BankSize(bank))
	
End Function

; ----------------------------------------------------------------------------
; Bilinear Scale Function
; ----------------------------------------------------------------------------
Function Bilinear#(bank%,width%,height%,x#,y#)
	
	Local x0#=Floor(x)
	Local y0#=Floor(y)
	Local x1#=Floor(x+1)
	Local y1#=Floor(y+1)
	Local dx#=x-x0
	Local dy#=y-y0
	
	Local x02x%=1
	Local x03x%=1
	Local y02x%=1
	Local y03x=1
	
	If x0<0 Then x02x=0
	If x1>width-1 Then x03x=0
	If y0<0 Then y02x=0
	If y1>height-1 Then y03x=0
	
	If x02x=0 Then x0=0
	If y02x=0 Then y0=0
	If x03x=0 Then x1=0
	If y03x=0 Then y1=0
	
	Local r0=GetBankPixel(bank,x0,y0,width)*x02x*y02x
	Local r1=GetBankPixel(bank,x1,y0,width)*x03x*y02x
	Local r2=GetBankPixel(bank,x1,y1,width)*x03x*y03x
	Local r3=GetBankPixel(bank,x0,y1,width)*x02x*y03x
	
	Return LinearInterpolate(LinearInterpolate(r0,r1,dx),LinearInterpolate(r3,r2,dx),dy)
	
End Function

; ----------------------------------------------------------------------------
; Linear Interpolation
; ----------------------------------------------------------------------------
Function LinearInterpolate#(x1#,x2#,mu#=0.5)
	
	Return (x1*(1.0-mu)+x2*mu)
	
End Function

Yue	(Posted 2014) [#5]

Ok, thank you all.

Every time I see the work of Christian, I feel a kick in the balls, I'm very far from doing that, and I realize that the problem is not the tools, but users.

Krischan

(Posted 2014) [#6]

Thanks. If I'd have more free time and even important: more motivation (!) I think I could write even cooler stuff than BlitzTiles or PlanetCreator. I'm still dreaming of my own spaceflight game but I'm afraid to fail in this as it would be much, much larger and more complex than anything I wrote the last years and beside that I'm a perfectionist. So I stand in my own way.

But self-awareness is the first step towards self-improvement.

Hotshot2005

(Posted 2014) [#7]

I remember Amiga Amos used to have bank where load image from memory :)

RemiD

(Posted 2014) [#8]

About banks, you may want to take a look at these posts :
http://www.blitzbasic.com/Community/posts.php?topic=101694
http://www.blitzbasic.com/Community/posts.php?topic=101699