Entity Does Not Exist

Blitz3D Forums/Blitz3D Programming/Entity Does Not Exist

MajesticSpaceBen

(Posted 2013) [#1]

Graphics3D 800,600,32

SetBuffer BackBuffer()

;=============================================================================================

;types ;I will figure how these work eventually

Type Door
Field x
Field y
Field z
Field state
Field model
End Type


;=============================================================================================


;creates the camera
camera=CreateCamera()
CameraViewport camera,0,0,800,600

;loads the world mesh
sample=LoadMesh( "models/level_gravTest.3ds" ) ;loads the mesh into the variable 'sample'
PositionEntity sample,0,-40,0
tex=LoadTexture( "models/textures/testMap.jpg" )
EntityTexture sample, tex ;textures the world

;sets camera fog
CameraFogColor camera,000, 000 ,000
CameraFogRange camera,1, 2000
CameraFogMode camera,1

;creates a cube serving as the players bounding box
playerHull = CreateCube()
PositionEntity playerHull,0,0,0
testCube = CreateCube()
PositionEntity testCube,0,0,0
testCubeState = 1


EntityRadius playerhull, 3,40 ;sets the entity's collision radius
EntityAlpha playerHull, 0

;sounds
snd_step = LoadSound("sounds/step.wav")
SoundVolume snd_step,.2

;sets up and parents the camera to the bounding box
EntityParent camera, playerHull

;light
AmbientLight 50, 54, 70

;collision setup
type_player = 1
type_world = 2
type_monster = 3
Collisions type_player, type_World, 2, 2
EntityType sample, type_world
EntityType playerHull, type_player

;view bobbing
shoe_size#=5 ; Step speed
head_bang_X#=1 ;x range for view bobbing
head_bang_Y#=3 ;y range for view bobbing

HidePointer

;=============================================================================================

;functions

Function ToggleDoor()
	If testCubeState = 1
	
		testCubeState = 0
		MoveEntity testCube, 0, 10, 0
	
	Else
		testCubeState = 1
		MoveEntity testCube, 0, -10, 0
	EndIf
End Function




;=============================================================================================



;game loop
While Not KeyHit(1)

	A# = 2 ;movement speed
	
	;mouselook
	mxs# = mxs# + MouseXSpeed()/5
	mys# = mys# + MouseYSpeed()/5
	RotateEntity camera,mys#,0,0
	RotateEntity playerHull, 0, -mxs, 0
	MoveMouse 100,100
	
	If mxs# > 360 Then mxs# = 0 ;limits of y value of view
	If mxs# < 0 Then mxs# = 360 
	
	If mys# > 80 Then mys# = 80 ;limits of x value of vieww
	If mys# < -80 Then mys# = -80
	
	
	;movement commands
	If KeyDown(17)	Then ;forward movement
		MoveEntity playerHull,0,0,A#
		walking=1
	EndIf
	
	If KeyDown(31)	Then ;backwards movement
		MoveEntity playerHull,0,0,-A#
		walking=1
	EndIf
	
	If KeyDown(30) Then ;strafe left
		MoveEntity playerHull,-A#,0,0
		walking=1
	EndIf
	
	If KeyDown(32)	Then ;strafe right
		MoveEntity playerHull,A#,0,0
		walking=1
	EndIf
	
	;viewbobbing
	If walking=1
	a1#=(a1#+shoe_size) Mod 360
  	Else
  	;a1#=a1#*0.8
 	EndIf

    PositionEntity camera,Cos(a1#)*head_bang_X#,Sin(90+a1#*2)*head_bang_Y#,0,0

	;footsteps
 	If Sin(90+a1*2)<-.85
  		If  footstep_needed<>0
   			Color 255,255,255
   			PlaySound snd_step
   			footstep_needed=0
  		EndIf
 	Else
  	footstep_needed=1
 	EndIf
	
	MoveEntity playerhull, 0,-5,0
	walking = 0;

	UpdateWorld
   	RenderWorld
	
	If EntityDistance(playerHull, testCube) < 20
		Text 10,10,"You're Close Enough"
			If KeyDown(18)
				ToggleDoor() 
			EndIf
			
	EndIf
	
	Text 10,575,"Gravity Demo"
	
	Flip

Wend
End

I receive an "Entity does Not Exist" error when the ToggleDoor function is called, specifically when it tries to move the testCube. I cannot figure out why it's doing this.

Yasha

(Posted 2013) [#2]

You've got a case of scope confusion going on. The variable testCube in the main program is not the same as the variable testCube within the function - they just happen to have the same name. Functions create a new scope (set of names) with their own set of variables that "shadow" those outside; since testCube in the function is never assigned, its value will be 0 on every invocation. (Variables inside the function are also "reset" every time it is called, so you can't just move the CreateCube to inside the function as the cube will be lost when it returns.)

A very similar question to this received a wonderfully in-depth answer from Rob the Great, which you can read here: http://www.blitzbasic.com/Community/posts.php?topic=101520#1206238 , with some examples of how to resolve this situation.

(Important to note that this isn't a bug, introducing new scopes is an important part of what functions are supposed to do.)

Rob the Great

(Posted 2013) [#3]

I think scopes are the most under-explained concept in programming, next to object oriented programming. I didn't even know about the existence of scopes when I first started programming. It was only when I encountered similar problems as the one above that I asked others on this forum what was going on.

To me, it makes the most sense to think of a function as a separate, mini-program within your main program. Once you're inside a function, everything created inside is specific only to that function and has nothing to do with anything else outside of the function. Names are irrelevant, which is why you can have two variables named the same thing and holding different values. The only exceptions are with global variables, types and their fields, and passing local variables to and from that function.