How to make resolution setter pick highest?

Blitz3D Forums/Blitz3D Beginners Area/How to make resolution setter pick highest?

Kippykip

(Posted 2013) [#1]

In my 'fatty' game I want it to pick the highest res available, my PC supports 1080p so I want it to choose 1920x1080 but my bros is only supports 720p, so I want it to choose the uh... dunno the resolution but yeah..
[bbcode]
;MENU 1 bootup settings
resolutionAmount = CountGfxModes()
resX = 0
resY = 0
depth = 0
windowed = 1
choice = resolutionAmount
bootImage1=LoadImage("data\images\resolution.png")
bootImage2=LoadImage("data\images\windowed.png")
textColor = Rand(3)

;the resolution screen
While(menu = 1)
If(textColor = 1)
Color 255,0,0
EndIf
If(textColor = 2)
Color 0,255,0
EndIf
If(textColor = 3)
Color 0,0,255
EndIf
Text(0,0,"Choose resolution (use arrow keys and press enter to use)")
Text(200,10,"A game by kippykip (http://www.youtube.com/user/HAP3E)")
If(choice = resolutionAmount)
Text(550,0,"Recommended")
EndIf
If(choice = 1)
Text(0,10, " " + GfxModeWidth(choice)+"x"+GfxModeHeight(choice)+"x" + GfxModeDepth(choice) + "? >")
ElseIf(choice = resolutionAmount)
Text(0,10, "< " + GfxModeWidth(choice)+"x"+GfxModeHeight(choice)+"x" + GfxModeDepth(choice) + "? ")
Else
Text(0,10, "< " + GfxModeWidth(choice)+"x"+GfxModeHeight(choice)+"x" + GfxModeDepth(choice) + "? >")
EndIf

;changing through menus
If KeyHit(205)
If(choice < resolutionAmount)
textColor = Rand(3)
choice = choice + 1
Cls
EndIf
EndIf
If KeyHit(203)
If(choice > 1)
textColor = Rand(3)
choice = choice - 1
Cls
EndIf
EndIf
;if you press enter
If KeyHit(28)
Cls
resX = GfxModeWidth(choice)
resY = GfxModeHeight(choice)
depth = GfxModeDepth(choice)
textColor = Rand(3)
menu = 2
EndIf
;end the game
If KeyHit(1)
End
EndIf
DrawImage bootImage1,0,0
Flip
Wend
[/bbcode]

I want the choice variable to pick the highest number
help :D

Floyd

(Posted 2013) [#2]

Something like this, I suppose.

Graphics 600, 600, 0, 2
SetBuffer FrontBuffer()

Print " mode  width  height  depth"
Print

For m = 1 To CountGfxModes()
	Write RSet( m, 4)
	Write RSet( GfxModeWidth(m), 7 )
	Write RSet( GfxModeHeight(m), 7 )
	Print RSet( GfxModeDepth(m), 7 )
Next

Print
Print "Most detailed mode is " + MaxRezMode()
WaitKey


Function MaxRezMode()
	Local m, w, h, d, MaxW, MaxH, MaxD, mode
	For m = 1 To CountGfxModes()
		w = GfxModeWidth(m)
		h = GfxModeHeight(m)
		d = GfxModeDepth(m)
		If w >= MaxW
			MaxW = w
			If h >= MaxH
				MaxH = h
				If d >= MaxD
					MaxD = d
					mode = m
				End If
			End If
		End If
	Next
	Return mode
End Function

Kippykip

(Posted 2013) [#3]

Wow thanks that helped a lot :D

RGR	(Posted 2013) [#4]

Just use
[bbcode]Graphics3D 0,0,32,1[/bbcode]
and the highest possible resolution is used.

.

Kippykip

(Posted 2013) [#5]

RGR said...

Just use
Graphics3D 0,0,32,1

and the highest possible resolution is used.

Why didn't I think of that before.... that is... extremely helpful (haven't tested yet) but yeah... thanks a billion :) (If it works...)