World Editor woes

Blitz3D Forums/Blitz3D Beginners Area/World Editor woes

Aussie

(Posted 2013) [#1]

Hey there everyone, I am working away on my world editor & have run into problems with moving selected objects.
I am using the same structure code that I use to move the camera around but when it comes to moving a selected object it doesn’t want to work & I can’t figure out why.
If someone take a look at the code & see what’s going on it would be greatly appreciated.
Cheers :)

Graphics3D 800,600,0,2

SetBuffer BackBuffer()

Scale# = 0 

Global mouse_down_3 = 0, shift_down = 0, mouse_X, mouse_Y, entity, mouse_state = 0
Global X_down = 0, Y_down = 0, Z_down = 0
Global c.cube


Global camera = CreateCamera()
		PositionEntity camera,0,0,-25
	
	light = CreateLight()
		RotateEntity light,90,0,0
		
	;cube = CreateCube()
	;	RotateEntity cube,0,45,45
	;	EntityAlpha cube,.75
		;Axis = LoadMesh("mediaaxis.b3d",cube)
		;	ScaleEntity Axis,.5,.5,.5
		
;Global	widget = LoadMesh("mediawidget.b3d")


Global widget = CreateSphere()
	ScaleEntity widget,.25,.25,.25
Global Yaxis = CreateCone(10)
	EntityColor Yaxis,0,255,0
	ScaleEntity Yaxis,.2,1,.2
	PositionEntity Yaxis,0,1,0
	EntityParent Yaxis,widget
Global Xaxis = CreateCone(10)
	EntityColor Xaxis,255,0,0
	ScaleEntity Xaxis,1,.2,.2
	RotateMesh Xaxis,0,0,90
	PositionEntity Xaxis,-1,0,0
	EntityParent Xaxis,widget
Global Zaxis = CreateCone(10)
	EntityColor Zaxis,0,0,255
	ScaleEntity Zaxis,.2,.2,1
	RotateMesh Zaxis,-90,0,0	
	PositionEntity Zaxis,0,0,-1
	EntityParent Zaxis,widget



		
create_cubes()	
		
	
While Not KeyDown (1)


control_camera()

		
		
	
;TurnEntity cube,.25,.25,.25
update_cubes()

Scale = EntityDistance(camera,widget)*.025

;MoveEntity camera,0,0,MouseZSpeed()*.2
ScaleEntity widget,scale,scale,scale

DebugLog "Entity picked= " + entity +  " |Mouse State= " + mouse_state + " |Mouse= "+ MouseYSpeed()

RenderWorld


Text 0,0,"Mouse wheel down & move mouse to rotate camera. Roll wheel to move camera Zaxis"
Text 0,15, "Left shift down & move mouse to move camera x & y."
Text 0,30, "Left click to select a cube"
Text 0,45, "Hold X Y or Z while moving the mouse to move cube while selected"
Text 0,60, "Right click to deselect cube"
Flip
LimitFrameRate(60)
Wend

End




;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
Function LimitFrameRate(FPS = 65)
	If FrameTime = 0 Then
		Period = 1000 / FPS
		FrameTime = MilliSecs()
	EndIf

	While (FrameTime + Period) > MilliSecs()
			Delay 1
	Wend
	FrameTime = MilliSecs()
End Function



;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;Camera control;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

Function control_camera()


If MouseDown(3)
	If mouse_down_3 = 0 Then
			mouse_down_3 = 1
			Mouse_X = MouseX()
			mouse_Y = MouseY()
			MoveMouse mouse_X,mouse_Y
	EndIf
		RotateEntity camera,EntityPitch(camera,True)+(MouseYSpeed()*0.2),EntityYaw(camera,True)+(MouseXSpeed()*-0.2),0
 		MoveMouse mouse_X, mouse_Y
	Else
		mouse_down_3 = 0
End If

If KeyDown(42)
	If shift_down = 0 Then
		shift_down = 1
		mouse_X = MouseX()
		mouse_Y = MouseY()
		MoveMouse mouse_X,mouse_Y
	EndIf
		MoveEntity camera,MouseXSpeed()*.025,MouseYSpeed()*-.025,0
		MoveMouse mouse_X, mouse_Y
	Else
		shift_down = 0
End If

MoveEntity camera,0,0,MouseZSpeed()*.2



;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;Pick & mouse_state;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

Select mouse_state
	Case 0
		HideEntity widget
		If MouseHit(1) Then
			CameraPick(camera,MouseX(),MouseY())
			entity = PickedEntity()
		End If
		
		If entity <> 0 Then 
			mouse_state = 1
		End If
		FlushMouse 
		
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;Move widget problem here;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
	Case 1
		ShowEntity widget
		If KeyDown(45) 
			If X_down = 0 Then
				X_down = 1
				mouse_X = MouseX()
				mouse_Y = MouseY()
			End If
				MoveEntity widget,EntityX(entity)+MouseXSpeed()*.025,0,0
				MoveMouse mouse_X,mouse_Y	
			Else
			X_down = 0
		End If
		
		If KeyDown(21) 
			If Y_down = 0 Then
				Y_down = 1
				mouse_X = MouseX()
				mouse_Y = MouseY()
			End If
				MoveEntity widget,0,EntityY(entity)+MouseYSpeed()*-.025,0
				MoveMouse mouse_X,mouse_Y
			Else 
			Y_down = 0
		End If
			
		If KeyDown(44)
			If Z_down = 0 Then
				Z_down = 1
				mouse_X = MouseX()
				mouse_Y = MouseY()
			End If
				MoveEntity widget,0,0,EntityY(entity)+MouseYSpeed()*.025
				MoveMouse mouse_X,mouse_Y
			Else
			Z_down = 0
		End If
		
		;If KeyDown(203) Then
		;	MoveEntity widget,-.5,0,0
		
		If MouseHit(2) Then 
			mouse_state = 0
			entity = 0
		End If
		FlushMouse
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
End Select

End Function




;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;Type;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

Type cube
	Field Mesh
	Field X#,Y#,Z#
	Field Picked
	Field Alpha#
	Field Name 
End Type

Function create_cubes()

For x = 0 To 9
 c.cube = New cube
	cMesh = CreateCube()
	cX = Rnd(-25,25)
	cY = Rnd(-25,25)
	cZ = Rnd(-25,25)
	cpicked = 0
	calpha = 1
	
	EntityPickMode cmesh,2
	PositionEntity cmesh,cX,cY,cZ
	EntityAlpha cmesh,calpha
	cname = EntityName(cMesh)
	cubename$ = cname
Next

End Function

Function update_cubes()

	For c.cube = Each cube
		If cmesh = entity Then
			cpicked = 1
			
				If cpicked = 1 Then
				calpha = .75
				EntityPickMode cmesh,0
				PositionEntity widget,EntityX(entity),EntityY(entity),EntityZ(entity)
				cpicked = 2
				
					If cpicked = 2 Then
					PositionEntity entity,EntityX(widget),EntityY(widget),EntityZ(widget)
					
				End If				
			End If
		Else cpicked = 0
		calpha = 1
		EntityPickMode cmesh,2
		
		
	End If
 
	EntityAlpha cmesh,calpha
	
	Next
	
End Function

Last edited 2013

Last edited 2013

Aussie

(Posted 2013) [#2]

Sorry guys for some reason every time i post the code it removes the "slash" from the types.

Last edited 2013

Bobysait

(Posted 2013) [#3]

(sorry for this post, the forum double-post it)

Last edited 2013

Bobysait

(Posted 2013) [#4]

(same bug, see post above)

Last edited 2013

Bobysait

(Posted 2013) [#5]

Lots of errors in your code

(I replaced the slach with a dot just for convinience)

in your function Update_cubes, you make some checking for "if c.picked = 1" etc ... but you set it to "1" previously, so your checkings will always be true.

in "create_cubes()"

c.Name = EntityName(c.Mesh)

you catch the name when you never use NameEntity, so c.name$ will always be null

in "control_camera", you should position the widget at the "entity" coords, then move it relatively to its current position (MoveEntity widget, MouseXSpeed()*.025,0,0)

so here is a solution to fix some of the bugs

Graphics3D 800,600,0,2

SetBuffer BackBuffer()

Local Scale# = 0 

Global mouse_down_3	=	0
Global shift_down	=	0
Global mouse_X		=	0
Global mouse_Y		=	0
Global entity		=	0
Global mouse_state	=	0
Global X_down		=	0
Global Y_down		=	0
Global Z_down		=	0
Global c.cube		=	Null


Global camera = CreateCamera()
		PositionEntity camera,0,0,-25
	
Local light = CreateLight()
		RotateEntity light,90,0,0
		
	;cube = CreateCube()
	;	RotateEntity cube,0,45,45
	;	EntityAlpha cube,.75
		;Axis = LoadMesh("mediaaxis.b3d",cube)
		;	ScaleEntity Axis,.5,.5,.5
		
;Global	widget = LoadMesh("mediawidget.b3d")


Global widget = CreateSphere()
	ScaleEntity widget,.25,.25,.25
Global Yaxis = CreateCone(10)
	EntityColor Yaxis,0,255,0
	ScaleEntity Yaxis,.2,1,.2
	PositionEntity Yaxis,0,1,0
	EntityParent Yaxis,widget
Global Xaxis = CreateCone(10)
	EntityColor Xaxis,255,0,0
	ScaleEntity Xaxis,1,.2,.2
	RotateMesh Xaxis,0,0,90
	PositionEntity Xaxis,-1,0,0
	EntityParent Xaxis,widget
Global Zaxis = CreateCone(10)
	EntityColor Zaxis,0,0,255
	ScaleEntity Zaxis,.2,.2,1
	RotateMesh Zaxis,-90,0,0	
	PositionEntity Zaxis,0,0,-1
	EntityParent Zaxis,widget


create_cubes()	


While Not KeyDown (1)
		
		control_camera()
		
		;TurnEntity cube,.25,.25,.25
		update_cubes()
		
		Scale = EntityDistance(camera,widget)*.025
		;MoveEntity camera,0,0,MouseZSpeed()*.2
		ScaleEntity widget,Scale,Scale,Scale
		
;		DebugLog "Entity picked= " + entity +  " |Mouse State= " + mouse_state + " |Mouse= "+ MouseYSpeed()
		
	RenderWorld
		
		Text 0,0,"Mouse wheel down & move mouse to rotate camera. Roll wheel to move camera Zaxis"
		Text 0,15, "Left shift down & move mouse to move camera x & y."
		Text 0,30, "Left click to select a cube"
		Text 0,45, "Hold X Y or Z while moving the mouse to move cube while selected"
		Text 0,60, "Right click to deselect cube"
		Text 0,550, "picked:"+entity
	Flip
	
	LimitFrameRate(60)
	
Wend

End




;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
Function LimitFrameRate(FPS = 65)
	If FrameTime = 0 Then
		Period = 1000 / FPS
		FrameTime = MilliSecs()
	EndIf

	While (FrameTime + Period) > MilliSecs()
			Delay 1
	Wend
	FrameTime = MilliSecs()
End Function



;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;Camera control;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

Function control_camera()

	Local msx# = MouseXSpeed()
	Local msy# = MouseYSpeed()
	Local msz# = MouseZSpeed()
	
	If MouseDown(3)
		If mouse_down_3 = 0
			mouse_down_3 = 1
			mouse_X = MouseX()
			mouse_Y = MouseY()
			MoveMouse mouse_X,mouse_Y
		EndIf
		RotateEntity camera,EntityPitch(camera,True)+(msy*0.2),EntityYaw(camera,True)+(msx*-0.2),0
		MoveMouse mouse_X, mouse_Y
	Else
		mouse_down_3 = 0
	End If
	
	If KeyDown(42)
		If shift_down = 0
			shift_down = 1
			mouse_X = MouseX()
			mouse_Y = MouseY()
			MoveMouse mouse_X,mouse_Y
		EndIf
		MoveEntity camera,msx*.025,msy*-.025,0
		MoveMouse mouse_X, mouse_Y
	Else
		shift_down = 0
	End If
	
	MoveEntity camera,0,0,msz*.2
	
	;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;Pick & mouse_state;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
	
	Select mouse_state
		
		Case 0
			
			HideEntity widget
			
			If MouseHit(1)
				entity = CameraPick(camera,MouseX(),MouseY())
				mouse_state = (entity<>0)
			End If
			
	;;;;;;;;;;;;;;;;;;;;;;;;;;;;;Move widget problem here;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
		Case 1
			
			ShowEntity widget
			PositionEntity widget, EntityX(entity), EntityY(entity), EntityZ(entity)
			
			If KeyDown(45)
				If X_down = 0 Then
					X_down = 1
					mouse_X = MouseX()
					mouse_Y = MouseY()
				End If
				MoveEntity widget, msx*.025,0,0
				MoveMouse mouse_X,mouse_Y
			Else
				X_down = 0
			End If
			
			If KeyDown(21) 
				If Y_down = 0 Then
					Y_down = 1
					mouse_X = MouseX()
					mouse_Y = MouseY()
				End If
				MoveEntity widget,0,-msy*.025,0
				MoveMouse mouse_X,mouse_Y
			Else 
				Y_down = 0
			End If
				
			If KeyDown(44)
				If Z_down = 0 Then
					Z_down = 1
					mouse_X = MouseX()
					mouse_Y = MouseY()
				End If
				MoveEntity widget,0,0,msy*.025
				MoveMouse mouse_X,mouse_Y
			Else
				Z_down = 0
			End If
			
			If MouseHit(2) Then 
				mouse_state = 0
				entity = 0
			End If
			FlushMouse
	;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
	End Select

End Function




;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;Type;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

Type cube
	Field Mesh
	Field X#,Y#,Z#
	Field Picked
	Field Alpha#
	Field Name 
End Type

Function create_cubes()
	
	Local x
	For x = 0 To 9
	 c.cube = New cube
		c[/]Mesh = CreateCube()
		c[/]x = Rnd(-25,25)
		c[/]Y = Rnd(-25,25)
		c[/]Z = Rnd(-25,25)
		c[/]Picked = 0
		c[/]Alpha = 1
		
		EntityPickMode c[/]Mesh,2
		PositionEntity c[/]Mesh,c[/]x,c[/]Y,c[/]Z
		EntityAlpha c[/]Mesh,c[/]Alpha
		c[/]Name = EntityName(c[/]Mesh)
		cubename$ = c[/]Name
	Next
	
End Function

Function update_cubes()

	For c.cube = Each cube
		
		If c[/]Mesh = entity
			
			If c[/]Picked <> 2
				
				c[/]Alpha = .75
				EntityPickMode c[/]Mesh,0
				PositionEntity widget,EntityX(entity),EntityY(entity),EntityZ(entity)
				c[/]Picked = 2
				
			Else c[/]Picked = 2
				
				PositionEntity entity,EntityX(widget),EntityY(widget),EntityZ(widget)
				
			End If
			
		Else
			
			c[/]Picked = 0
			c[/]Alpha = 1
			EntityPickMode c[/]Mesh,2
			
		End If
		
		EntityAlpha c[/]Mesh,c[/]Alpha
		
	Next
	
End Function

Just replace all the "[/]" with a backslash

Last edited 2013

Last edited 2013

Aussie

(Posted 2013) [#6]

Thanks heaps for that Bobysait.

Yeah the

c.Name = EntityName(c.Mesh)

I meant to remove it as i never ended up using it, i was trying to figure out how to get the selected cube into the type so i could then use it, i then found the pickedentity() function while searching around on how to do it & went with that. :)

psychicbottle

(Posted 2013) [#7]

Yeah I was working on a World Editor about the time you joined, it's actually quite far now and I'm gonna start working on it again thanks to this post which kinda rebooted my adrenaline for the project :D

Guy Fawkes

(Posted 2013) [#8]

It would be better if you can hold control to select OR deselect multiple objects. I made my own level editor a few years ago :)