change center of object help please:|

Blitz3D Forums/Blitz3D Beginners Area/change center of object help please:|

shepherd

(Posted 2012) [#1]

please help me i want to change center of my 3d model how please... i use a pivot but still not working i want to post image to help u understand but i dont know how to upload a pic can u say me...

Aussie

(Posted 2012) [#2]

Here is a quick example of how to do it using a pivot then parenting the object to a pivot.

Use left & right to turn the pivot
Use A & D to turn the cube

Graphics3D 800,600,0,2

SetBuffer BackBuffer()




Light= CreateLight()
	RotateEntity light,90,0,0
camera = CreateCamera()
	PositionEntity camera,0,0,-10
	

cube = CreateCube() ;creates the cube with it's center at 0,0,0
	
pivot = CreatePivot() ;Creates the pivot
	PositionEntity pivot,1,0,0 ;Positions the pivot at 1,0,0. Play around with the x position (1) to change where the cube will rotate around
	EntityParent cube,pivot ;Parents the cube to the pivot
	
While Not KeyDown (1)


	If KeyDown(203) TurnEntity pivot,0,-1,0 ;Turns the pivot the cube is parented, moving the cube off center
	If KeyDown(205) TurnEntity pivot,0,1,0	;Turns the pivot the cube is parented, moving the cube off center

	
	If KeyDown(30) TurnEntity cube,0,-1,0 ;Turns the cube around it's center
	If KeyDown(32) TurnEntity cube,0,1,0 ;Turns the cube around it's center

	
UpdateWorld
RenderWorld
Flip
Wend

End

Hope this helps. :)

The other way to change the center of you model is in a 3d modeling program. What are you using?

shepherd

(Posted 2012) [#3]

i already did this......but i will try your above method again thx....
i made my model in some software called blender(i think).......
thanks for the help:)

Aussie

(Posted 2012) [#4]

If you are using blender.

Open your .blend file with the model in it.
Go to Edit mode & select the Vertices option.
Select all of the Vertices on your model by hitting "A" until they are all selected.
Now grab them all & move them around until you have re positioned the mesh around where you want the center of your model to be.

This is the way i do it, there may be better ways but this way works for me. :)

RemiD

(Posted 2012) [#5]

I agree with Aussie, i think it is better to position the mesh with the vertices at the correct position in your modeling software, so then you only have to load it in Blitz3d.

If you absolutely want to reposition it, rerotate it in Blitz3d you can use PositionMesh() and RotateMesh(), these commands will move all vertices of the mesh.

Bobysait

(Posted 2012) [#6]

If you want "pure code" stuff, you need to get the bouding box, else there is no build-in blitz command to achieve such a thing according to the specific models.

Here is a sample of how to do it (support animmesh/scenes)

Global InitBounds = False
Global BoundX# = 0.0
Global BoundY# = 0.0
Global BoundZ# = 0.0
Global BoundW# = 0.0
Global BoundH# = 0.0
Global BoundD# = 0.0

Function GetSubBounds ( Root, Mesh, recursive%=False )
	
	If EntityClass(Mesh)="Mesh"
		Local x#, y#, z#
		Local is=0, s=0, nbs=CountSurfaces(Mesh)
		For is = 1 To nbs
			s = GetSurface(Mesh,is)
			Local nv = CountVertices(s)-1, v=0
			If nv>-1
				For v = 0 To nv
					TFormPoint VertexX(s,v),VertexY(s,v),VertexZ(s,v), Mesh,Root
					x = TFormedX() : y = TFormedY() : z = TFormedZ()
					If InitBounds=False
						InitBounds = True
						BoundX=x : BoundY=y : BoundZ=z
						BoundW=x : BoundH=y : BoundD=z
					Else
						If x<BoundX Then BoundX = x
						If y<BoundY Then BoundY = y
						If z<BoundZ Then BoundZ = z
						If x>BoundW Then BoundW = x
						If y>BoundH Then BoundH = y
						If z>BoundD Then BoundD = z
					EndIf
				Next
			EndIf
		Next
	EndIf
	
	If recursive
		Local ic, nbc = CountChildren(Mesh)
		For ic=1 To nbc
			GetSubBounds(Root,GetChild(Mesh,ic),True)
		Next
	EndIf
	
End Function

Function GetBounds(Mesh, recursive%=False)
	; initialize/reset bounds
	BoundX = 0.0 : BoundY = 0.0 : BoundZ = 0.0
	BoundW = 0.0 : BoundH = 0.0 : BoundD = 0.0
	GetSubBounds(Mesh,Mesh,recursive)
	; calculate sizes
	BoundW = BoundW-BoundX
	BoundH = BoundH-BoundY
	BoundD = BoundD-BoundZ
End Function



Graphics3D 800,600,0,2
SetBuffer BackBuffer()

Local Entity = CreatePivot()
Local Model = LoadAnimMesh("MyMesh.b3d",Entity) / LoadMesh("MyMesh.b3d",Entity)
GetBounds(Model, True)

; center Model
PositionEntity Model, -BoundX-BoundW*.5, -BoundY-BoundH*.5, -BoundZ-BoundD*.5, False

Last edited 2012

Ross C

(Posted 2012) [#7]

Fitmesh is the best way to centre the mesh quickly, if it's not animated.

John Blackledge

(Posted 2013) [#8]

This is a piece of code I wrote some years ago to cope with centring/placing of models created in any modeller (AutoCad creates models miles away from the origin point).
http://www.blitzbasic.co.nz/codearcs/codearcs.php?code=1785