YawToEntity Function

Blitz3D Forums/Blitz3D Beginners Area/YawToEntity Function

Aussie

(Posted 2012) [#1]

I am having some strange issues with this function.

If i move towards the enemy the enemy turns away from the player on the south side of the sphere. If i chase the enemy the enemy will eventually start to point towards the player.

I am wondering if it has something to do with the playing area being a sphere.

Here is the code.
If you hold down the up arrow straight away you will see what happens when the player gets close to the enemy.


; The number of logic updates per second.
Const C_LOGIC_FREQUENCY = 50

; The interval (in milliseconds) between logic updates.
Const C_LOGIC_INTERVAL# = 1000.0 / C_LOGIC_FREQUENCY ; Unused.

Const C_SMART_MISSILE_TEST_DISTANCE# = 10.0
Const C_SMART_MISSILE_TEST_ANGLE# = 60.0
Const C_SMART_MISSILE_NO_TURN_DISTANCE# = 15.0

Global timer = CreateTimer( C_LOGIC_FREQUENCY )



Graphics3D 1024,768,32,1

SetBuffer BackBuffer()


P_VEL#  = 0
P_YAW# = 0
	
light = CreateLight()
	RotateEntity light,180,0,0

camera = CreateCamera()
	CameraRange camera,.1,5000
	PositionEntity camera,0,0,0
	RotateEntity camera,090,0,0
	

masterpiv = CreatePivot()

sphere = CreateSphere(18)
	EntityColor sphere,0,150,255
	ScaleEntity sphere,550,550,550
	UpdateNormals sphere
	EntityPickMode sphere,2
	EntityRadius sphere,550



player = CreateCone()
	PositionEntity player,0,590,0
	RotateMesh player,90,0,0
	RotateEntity player,0,180,0
	ScaleEntity player,5,5,5
	EntityColor player,0,255,0
	
enemy = CreateCone()
	PositionEntity enemy,0,-590,0
	RotateMesh enemy,90,0,0
	RotateEntity enemy,180,0,0
	ScaleEntity enemy,5,5,5
	EntityColor enemy,255,0,0
	
	
	
campiv = CreatePivot()
	EntityParent campiv,player
	PositionEntity campiv,0,90,0
	pivx# = EntityX(campiv,True)
	pivy# = EntityY(campiv,True)
	pivz# = EntityZ(campiv,True)
	PositionEntity camera,pivx#,pivy#,pivz#

		
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
While Not KeyDown (1)



If KeyDown (203)
	P_YAW# = P_YAW# + .25
	ElseIf KeyDown (205)
	P_YAW# = P_YAW# - .25
End If

If P_YAW# > 4
	P_YAW# = 4
ElseIf P_YAW# < -4
	P_YAW# = -4
End If



				
If KeyDown (200)
	P_VEL# = P_VEL# + .5
	create_flame(player,Rnd(-.5,.5),0,-1,Rnd(10,20))
End If




If P_VEL# > 5 P_VEL# = 5


If P_VEL# > 0
P_VEL# = P_VEL# - .1
If P_VEL# < 0 P_VEL# = 0
End If


If P_YAW# > 0
   P_YAW# = P_YAW# - .05
  If P_YAW# < 0 P_YAW# = 0             
ElseIf P_YAW# < 0
   P_YAW# = P_YAW# + .05
  If P_YAW# > 0 P_YAW# = 0
ElseIf P_YAW# = 0
   P_YAW# = 0
End If


MoveEntity player,0,0,P_VEL#
TurnEntity player,0,P_YAW#,0


MoveEntity enemy,0,0,2
create_flame(enemy,Rnd(-.5,.5),0,-1,Rnd(10,20))

If EntityDistance (enemy,player) < 250	
	YawToEntity( enemy, player, 3 )	
End If

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;Tform & Picking;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

TFormVector 0,-90,0,player,0
EntityPickMode sphere,1
LinePick (EntityX(player,True),EntityY(player,True),EntityZ(player,True),TFormedX(),TFormedY(),TFormedZ())
AlignToVector player,PickedNX#(),PickedNY#(),PickedNZ#(),2,1

TFormVector 0,-90,0,enemy,0
LinePick (EntityX(enemy,True),EntityY(enemy,True),EntityZ(enemy,True),TFormedX(),TFormedY(),TFormedZ())
AlignToVector enemy,PickedNX#(),PickedNY#(),PickedNZ#(),2,1
EntityPickMode sphere,0


;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;


update_flame()



pivx# = EntityX(campiv,True)
pivy# = EntityY(campiv,True)
pivz# = EntityZ(campiv,True)
PositionEntity camera,pivx#,pivy#,pivz#

vx# = EntityX( player ) - EntityX( camera )
vy# = EntityY( player ) - EntityY( camera )
vz# = EntityZ( player ) - EntityZ( camera )

AlignToVector camera,vx,vy,vz,3,1

UpdateWorld


RenderWorld



Flip
LimitFrameRate(38)
Wend
End

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

Function LimitFrameRate(FPS = 65)
	If FrameTime = 0 Then
		Period = 1000 / FPS
		FrameTime = MilliSecs()
	EndIf

	While (FrameTime + Period) > MilliSecs()
			Delay 1
	Wend
	FrameTime = MilliSecs()
End Function 


Type flame
	Field life%
	Field scale#
	Field x#,y#,z#
	Field obj
	Field alpha#
	Field R#,G#,B#
End Type

Function create_flame(entity,x#,y#,z#,life#)
	f.flame = New flame
		f\obj = CreateSphere(10,entity)
		f\R# = 0
		f\G# = 155
		f\B# = 255
		EntityColor f\obj,f\R,f\G,f\B
		EntityFX f\obj,1
		EntityBlend f\obj,3
		f\scale# = Rand(1,4)
		f\alpha# = 1
		f\life = life#
	PositionEntity f\obj,x,y,z
	EntityParent f\obj,0
End Function

Function update_flame()
	For f.flame = Each flame
		f\G = f\G - Rand(0,10)
		EntityColor f\obj,f\R,f\G,f\B
		f\alpha = f\alpha - .1
		ScaleEntity f\obj,f\scale,f\scale,f\scale
		EntityAlpha f\obj,f\alpha
		f\life = f\life - 1
		If f\life < 0 Then
			FreeEntity f\obj
			Delete f
		End If
	Next
End Function

Function YawToEntity( src_entity, dest_entity, rate# )
; Turns 'src_entity' to point at 'dest_entity' at the rotation rate specified by 'rate#'.

	Local target_yaw# = DeltaYaw( src_entity, dest_entity )
	
	; If the required correction amount is less than the correction amount to be applied...
	If Abs( target_yaw# ) < rate#
		; Point 'src_entity' directly at 'dest_entity' to prevent jittering.
		TurnEntity src_entity, 0.0, target_yaw#, 0.0
	Else
		; Turn 'src_entity' gradually towards 'dest_entity'.
		TurnEntity src_entity, 0.0, rate# * Sgn(  target_yaw# ), 0.0
	EndIf
End Function

Last edited 2012

Floyd

(Posted 2012) [#2]

It's not entirely clear to me what should be happening. But you probably want to turn around the world Y axis, meaning set the global flag to True when you turn the enemy. Near the end of the code that would be

	; If the required correction amount is less than the correction amount to be applied...
	If Abs( target_yaw# ) < rate#
		; Point 'src_entity' directly at 'dest_entity' to prevent jittering.
		TurnEntity src_entity, 0.0, target_yaw#, 0.0, True
	Else
		; Turn 'src_entity' gradually towards 'dest_entity'.
		TurnEntity src_entity, 0.0, rate# * Sgn(  target_yaw# ), 0.0, True
	EndIf

You can find my description of DeltaYaw here.
That was four and a half years ago and I was just posting something I wrote many years earlier. So I don't remember much about it.

Aussie

(Posted 2012) [#3]

Hey there Floyd,
What should be happening is when the played gets close to the enemy the enemy should point at the player to give chase.
Zethrax pointed me to his Function YawToEntity http://www.blitzbasic.com/codearcs/codearcs.php?code=2258 in another thread.
I have set the global flag to true & i still get the same thing happening.

Floyd

(Posted 2012) [#4]

Okay, I hadn't really thought about the spherical world.

The correct approach is the opposite of what I was thinking. Instead of looking at this globally do it locally, from the point of view of the enemy. The only decision is which way to turn.

The enemy entity has his own coordinate system. Y+ is up, Z+ is forward and X+ and X- are right and left. We need only decide whether the target ( the player ) is to the right or left as seen by the enemy. The player is always at 0,0,0 in his own space so we transform that to the enemy's space. Then TFormedX() tells us which side the player is on. If this value is positive then the player is to the right of the enemy, and the enemy must turn clockwise as seen from above. That means a negative change to the Yaw angle. Thus the sign of the Yaw change is the opposite of the sign of TFormedX().

With that in mind the last part of YawToEntity becomes

		; Turn 'src_entity' gradually towards 'dest_entity'.
		TFormPoint 0,0,0,  dest_entity, src_entity
		TurnEntity src_entity, 0.0, rate# * -Sgn( TFormedX() ), 0.0

Last edited 2012

Kryzon

(Posted 2012) [#5]

The enemy entity has his own coordinate system. Y+ is up, Z+ is forward and X+ and X- are right and left. We need only decide whether the target ( the player ) is to the right or left as seen by the enemy.

Hi Floyd, I've implemented your suggestion as a simple AI following the player - link to post.