Movement around a sphere.

Blitz3D Forums/Blitz3D Beginners Area/Movement around a sphere.

Aussie

(Posted 2012) [#1]

Hey there all, been a while since I have posted here.
I have a sphere as a planet & have a player that orbits the planet.
I have used a pivot & parented the player to the pivot that is used to move the player around the planet.
I am trying to setup a system for an enemy to chase the player & am having problems regarding the best way to go about the enemy chasing system & aligning to the player correctly.

If someone could offer some advice or an example it would be greatly appreciated.

Here is what I have. Use the arrow keys to move the player.

Graphics3D 1024,768,32,1

SetBuffer BackBuffer()

P_VEL#  = 0
P_YAW# = 0
	
light = CreateLight()
	RotateEntity light,180,0,0

camera = CreateCamera()
	CameraRange camera,.1,5000
	

masterpiv = CreatePivot()

sphere = CreateSphere(18)
	EntityColor sphere,0,150,255
	ScaleEntity sphere,550,550,550


shippiv = CreatePivot()
	PositionEntity shippiv,0,0,0
	player = CreateCone()
		EntityParent player,shippiv
		;PositionEntity player,0,0,-590
		PositionEntity player,0,590,0
		RotateMesh player,90,0,0
		ScaleEntity player,5,5,5
		EntityColor player,0,255,0
		RotateEntity shippiv,-90,0,0
		
		
enemypiv = CreatePivot()
	PositionEntity enemypiv,0,0,0
	enemy = CreateCone()
		EntityParent enemy,enemypiv
		PositionEntity enemy,0,590,0
		RotateMesh enemy,90,0,0
		ScaleEntity enemy,5,5,5
		EntityColor enemy,255,0,0
		RotateEntity enemypiv,10,200,0

		
		
campiv = CreatePivot()
	EntityParent campiv,shippiv
	PositionEntity campiv,0,1000,0
	pivx# = EntityX(campiv,True)
	pivy# = EntityY(campiv,True)
	pivz# = EntityZ(campiv,True)
	PositionEntity camera,pivx#,pivy#,pivz#


;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
While Not KeyDown (1)


If KeyDown (203)
	P_YAW# = P_YAW# + .25
	ElseIf KeyDown (205)
	P_YAW# = P_YAW# - .25
End If

If P_YAW# > 4
	P_YAW# = 4
ElseIf P_YAW# < -4
	P_YAW# = -4
End If



				
If KeyDown (200)
	P_VEL# = P_VEL# + .01
	create_flame(player,Rnd(-.5,.5),0,0,Rnd(10,20))
End If




If P_VEL# > 1 P_VEL# = 1


If P_VEL# > 0
P_VEL# = P_VEL# - .005
If P_VEL# < 0 P_VEL# = 0
End If


If P_YAW# > 0
   P_YAW# = P_YAW# - .05
  If P_YAW# < 0 P_YAW# = 0             
ElseIf P_YAW# < 0
   P_YAW# = P_YAW# + .05
  If P_YAW# > 0 P_YAW# = 0
ElseIf P_YAW# = 0
   P_YAW# = 0
End If




;TurnEntity shippiv,PV#,0,P_YAW#

TurnEntity shippiv,P_VEL#,P_YAW#,0

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;HELP;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

If EntityDistance(enemy,player) < 150 
	PointEntity enemy,player
	;ex# = EntityX( enemy ) - EntityX( player )
	;ey# = EntityY( enemy ) - EntityY( player )
	;ez# = EntityZ( enemy ) - EntityZ( player )
	;AlignToVector enemypiv,ex,ey,ez,2,.5
	
	;RotateEntity enemypiv,0,ey#,0
	ey# = EntityYaw(enemy)
	
End If

TurnEntity enemypiv,.5,ey#,0 

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;






pivx# = EntityX(campiv,True)
pivy# = EntityY(campiv,True)
pivz# = EntityZ(campiv,True)
PositionEntity camera,pivx#,pivy#,pivz#



vx# = EntityX( shippiv ) - EntityX( camera )
vy# = EntityY( shippiv ) - EntityY( camera )
vz# = EntityZ( shippiv ) - EntityZ( camera )

AlignToVector camera,vx,vy,vz,3,1


update_flame()

UpdateWorld


RenderWorld



Flip
LimitFrameRate(38)
Wend
End

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

Function LimitFrameRate(FPS = 65)
	If FrameTime = 0 Then
		Period = 1000 / FPS
		FrameTime = MilliSecs()
	EndIf

	While (FrameTime + Period) > MilliSecs()
			Delay 1
	Wend
	FrameTime = MilliSecs()
End Function 


Type flame
	Field life%
	Field scale#
	Field x#,y#,z#
	Field obj
	Field alpha#
	Field R#,G#,B#
End Type

Function create_flame(entity,x#,y#,z#,life#)
	f.flame = New flame
		f\obj = CreateSphere(10,entity)
		f\R# = 0
		f\G# = 155
		f\B# = 255
		EntityColor f\obj,f\R,f\G,f\B
		EntityFX f\obj,1
		EntityBlend f\obj,3
		f\scale# = Rand(1,4)
		f\alpha# = 1
		f\life = life#
	PositionEntity f\obj,x,y,z
	EntityParent f\obj,0
End Function

Function update_flame()
	For f.flame = Each flame
		f\G = f\G - Rand(0,10)
		EntityColor f\obj,f\R,f\G,f\B
		f\alpha = f\alpha - .1
		ScaleEntity f\obj,f\scale,f\scale,f\scale
		EntityAlpha f\obj,f\alpha
		f\life = f\life - 1
		If f\life < 0 Then
			FreeEntity f\obj
			Delete f
		End If
	Next
End Function

Last edited 2012

Last edited 2012

RemiD

(Posted 2012) [#2]

I am trying to setup a system for an enemy to chase the player & am having problems regarding the best way to go about the enemy chasing system & aligning to the player correctly.

If you want the enemy to move around the planet, as the player does, and chase the player at this height, here what i would do :

1)Turn the enemy towards the player
2)Move the enemy forward (+Z)
3)Make your planet pickable
4)LinePick from above the enemy to below the enemy (from above because the enemy ship may be inside the planet at first)
5)Use the picked point coordinates to position the enemy on the planet at the desired height (if you want to add the ability to go up or down.)
6)Align the enemy to the ground of the planet with AlignToVector

I suggest you also use the same method for the movement of the player ship, so that you will be able to adjust the height you want.

This is probably not the best technique, your planet being a sphere it may be easier to do it with maths. But i can't help with this.

Last edited 2012

Aussie

(Posted 2012) [#3]

Thanks RemiD,

I probably should have said the reason i have been using the pivots & positioning the enemy & player offset from the pivots is because i'm not to keen on going down the path of using linepicks.

This is just a test to get a system of the enemy being able to chase the player correctly & eventually i will be having a fair few enemies/objects around the planet & if i use a heap of linepicks it will probably cause to much of a slowdown.

I had thought maybe there was a way to do it with maths but i am not that great at using maths for this kind of a system. I am tipping it would use Sin, Cos, Tan but i could never really get my head around it.

Thanks for the help anyway.

Actually,
dose anyone know how much of a slowdown linepicks cause? I remember reading that to many will cause a slowdown & eventually there could be up to 100 or so objects around the planet.

RemiD

(Posted 2012) [#4]

Linepick and Collisions are calculated very fast if used properly.

The best way i have found to make it fast :
At the begining of each loop, delete all colliders and disable all pickmode.

Before you do a check, set only the collider or the pickmode of the colliders you need.

If you use meshes for colliders and pickable entities, make sure these meshes have the fewest tris possible, just to approximate the shape of the collider / pickable entity.

This way you check if a collision or a pick happens on only a few colliders / pickable entities and they are low tris so it is very fast !

You can use linepick for many things and it won't slow down your game if you follow the advices mentioned above.

Of course for a planet being made of a perfect sphere, i think will be better with maths...
Edit : corrections
Maybe you can add vectors :
The vector of movement of the ship (+Z locally)
+
The vector of the difference of the distance from the ship to the center of the sphere minus the radius of the sphere, this will give you a length that is the distance from the ship to the ground of the planet after the movement of the ship.

And with this you will be able to position the ship.

Try it it should work.

Last edited 2012

Zethrax

(Posted 2012) [#5]

Not sure what you're after exactly, but here's some smart missile code I wrote at one point that sound like what you're requesting.

http://www.blitzbasic.com/codearcs/codearcs.php?code=2258

Aussie

(Posted 2012) [#6]

Thanks guys

@ RemiD
I never thought of doing that with linepicks & collisions i will have to try it out.

With the vector

The vector of movement of the ship (+Z locally)

Are you talking velocity or Z coordinates?
Like i was saying, i'm not that great with maths when it comes to dealing with circles or spheres. :)

@ Zethrax
What you have there is the kind of thing i am trying to achieve, the difference is that the missile would be orbiting a planet & chasing other objects in the same orbit. Hope that explains what i am trying to achieve.

I will have a play around & see what i can come up with.

Last edited 2012

Aussie

(Posted 2012) [#7]

Ok i am struggling with this.
I decided to try & use the linepick method instead of using pivots & i can't get the player to align with the sphere using the aligntovector. Here is what i have, if some one could let me know what i am doing wrong it would be greatly appreciated.

Graphics3D 1024,768,32,1

SetBuffer BackBuffer()

P_VEL#  = 0
P_YAW# = 0
	
light = CreateLight()
	RotateEntity light,180,0,0

camera = CreateCamera()
	CameraRange camera,.1,5000
	PositionEntity camera,0,1000,0
	RotateEntity camera,090,0,0
	

masterpiv = CreatePivot()

sphere = CreateSphere(18)
	EntityColor sphere,0,150,255
	ScaleEntity sphere,550,550,550
	UpdateNormals sphere
	EntityPickMode sphere,2



player = CreateCone()
	
	PositionEntity player,0,590,0
	RotateMesh player,90,0,0
	ScaleEntity player,5,5,5
	EntityColor player,0,255,0

		
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
While Not KeyDown (1)

TFormVector 0,-50,0,player,0

LinePick (EntityX(player,True),EntityY(player,True),EntityZ(player,True),TFormedX(),TFormedY(),TFormedZ())
AlignToVector player,PickedNX#,PickedNY#,PickedNZ#,2,1

If KeyDown (203)
	P_YAW# = P_YAW# + .25
	ElseIf KeyDown (205)
	P_YAW# = P_YAW# - .25
End If

If P_YAW# > 4
	P_YAW# = 4
ElseIf P_YAW# < -4
	P_YAW# = -4
End If



				
If KeyDown (200)
	P_VEL# = P_VEL# + .5
	create_flame(player,Rnd(-.5,.5),0,0,Rnd(10,20))
End If




If P_VEL# > 5 P_VEL# = 5


If P_VEL# > 0
P_VEL# = P_VEL# - .1
If P_VEL# < 0 P_VEL# = 0
End If


If P_YAW# > 0
   P_YAW# = P_YAW# - .05
  If P_YAW# < 0 P_YAW# = 0             
ElseIf P_YAW# < 0
   P_YAW# = P_YAW# + .05
  If P_YAW# > 0 P_YAW# = 0
ElseIf P_YAW# = 0
   P_YAW# = 0
End If


MoveEntity player,0,0,P_VEL#
TurnEntity player,0,P_YAW#,0


update_flame()

UpdateWorld


RenderWorld



Flip
LimitFrameRate(38)
Wend
End

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

Function LimitFrameRate(FPS = 65)
	If FrameTime = 0 Then
		Period = 1000 / FPS
		FrameTime = MilliSecs()
	EndIf

	While (FrameTime + Period) > MilliSecs()
			Delay 1
	Wend
	FrameTime = MilliSecs()
End Function 


Type flame
	Field life%
	Field scale#
	Field x#,y#,z#
	Field obj
	Field alpha#
	Field R#,G#,B#
End Type

Function create_flame(entity,x#,y#,z#,life#)
	f.flame = New flame
		f\obj = CreateSphere(10,entity)
		f\R# = 0
		f\G# = 155
		f\B# = 255
		EntityColor f\obj,f\R,f\G,f\B
		EntityFX f\obj,1
		EntityBlend f\obj,3
		f\scale# = Rand(1,4)
		f\alpha# = 1
		f\life = life#
	PositionEntity f\obj,x,y,z
	EntityParent f\obj,0
End Function

Function update_flame()
	For f.flame = Each flame
		f\G = f\G - Rand(0,10)
		EntityColor f\obj,f\R,f\G,f\B
		f\alpha = f\alpha - .1
		ScaleEntity f\obj,f\scale,f\scale,f\scale
		EntityAlpha f\obj,f\alpha
		f\life = f\life - 1
		If f\life < 0 Then
			FreeEntity f\obj
			Delete f
		End If
	Next
End Function

I have also been trying to figure out how to use the vectors for doing this kind of a control system with no luck. I did do some looking around for a spherical coordinate system & information on how they work & it is way over my head.
If i can get the linepick & aligntovector to work i think i should be able to get the enemy to chase the player properly.

Stevie G

(Posted 2012) [#8]

The PickedNX, NY and NZ commands are functions which return values so should always be used with open/close brackets,i.e:

[bbcode]
AlignToVector player,PickedNX(),PickedNY(),PickedNZ(),2,1
[/bbcode]

This seems to be your only issue.

Stevie

Aussie

(Posted 2012) [#9]

Thanks heaps Stevie G

It has been driving me nuts not being able to figure out what was going wrong. I looked at other examples & didn't even notice the ().
Works great now.

RemiD

(Posted 2012) [#10]

Aussie>>This works well and Linepick seems to be fast enough for now.
Here are some suggestions :
->First turn your ship and move it, and then do the linepick calculation in order to correct the position and orientation.
->You should use a collider with less tris for the sphere, or if it is faster, use a combination of EntityPickMode sphere with EntityRadius()

Edit: i have added the EntityPickMode(1) with EntityRadius(), it is really fast !

Here is your code with some suggestions :
Also i have added the routine with vectors in words, maybe somebody can help you find the math formula, i can't help sorry.

Graphics3D 1024,768,32,2
HidePointer()
SetBuffer BackBuffer()

P_VEL#  = 0
P_YAW# = 0
	
light = CreateLight()
	RotateEntity light,180,0,0

camera = CreateCamera()
	CameraRange camera,.1,5000
	PositionEntity camera,0,1000,0
	RotateEntity camera,090,0,0
	

masterpiv = CreatePivot()

sphere = CreateSphere(16)
	EntityColor sphere,0,150,255
	ScaleEntity sphere,550,550,550
	UpdateNormals sphere
;SphereCollider = CreateSphere(8)
;ScaleEntity SphereCollider,550,550,550
;EntityAlpha(SphereCollider,0)
SphereCollider = CreatePivot()
EntityRadius(SphereCollider,550)

player = CreateCone()
	
	PositionEntity player,0,590,0
	RotateMesh player,90,0,0
	ScaleEntity player,5,5,5
	EntityColor player,0,255,0

Const Pick% = 1
Const Vectors% = 2
RoutineMode% = Pick
		
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
While Not KeyDown (1)

If KeyDown (203)
	P_YAW# = P_YAW# + .25
	ElseIf KeyDown (205)
	P_YAW# = P_YAW# - .25
End If

If P_YAW# > 4
	P_YAW# = 4
ElseIf P_YAW# < -4
	P_YAW# = -4
End If
				
If KeyDown (200)
	P_VEL# = P_VEL# + .5
	create_flame(player,Rnd(-.5,.5),0,0,Rnd(10,20))
End If

If P_VEL# > 5 P_VEL# = 5

If P_VEL# > 0
P_VEL# = P_VEL# - .1
If P_VEL# < 0 P_VEL# = 0
End If

If P_YAW# > 0
   P_YAW# = P_YAW# - .05
  If P_YAW# < 0 P_YAW# = 0             
ElseIf P_YAW# < 0
   P_YAW# = P_YAW# + .05
  If P_YAW# > 0 P_YAW# = 0
ElseIf P_YAW# = 0
   P_YAW# = 0
End If

MoveEntity player,0,0,P_VEL#
TurnEntity player,0,P_YAW#,0

If(RoutineMode = Pick)
 LinePickStart# = MilliSecs()
 ;You want to remove the For Next loop, it is just to see if it is faster with EntityPickMode(1) or EntityPickMode(2), EntityPickMode(1) is faster.
 For i% = 1 To 1000
  ;EntityPickMode(SphereCollider,2)
  EntityPickMode(SphereCollider,1)
  TFormVector 0,-50,0,player,0
  LinePick (EntityX(player,True),EntityY(player,True),EntityZ(player,True),TFormedX(),TFormedY(),TFormedZ())
  EntityPickMode(SphereCollider,0)
 Next
 LinePickTime# = (Float(MilliSecs()) - LinePickStart)/i
 AlignToVector player,PickedNX(),PickedNY(),PickedNZ(),2,1
ElseIf(RoutineMode = Vectors)
 ;Calculates the distance from the ship to the center of the sphere
 ;VLengthSC# =
 ;Calculates the distance from the ground to the center of the sphere (its radius...)
 ;VLengthGC# =
 ;Calculates the distance from the ship to the ground
 ;VLengthSG# = VLengthSC - VLengthGC
 ;Moves the ship  at the level of the ground + add some height so that the ship is flying above the ground 
 MoveEntity(Player,0,-VLengthSG#+1,0)
 ;Aligns the ship to the ground of the sphere at this specific location
 ;Here you want to calculate an angle with several vectors (but i don't know the formula)
 ;The vector that starts from the center of the sphere and ends at the ship
 ;The vector of movement of the ship
 ;A vector that is perpendicular to the first vector and goes in the same "direction" (except on one axis) than the second vector.
 ;The angle between the third vector and the second vector should be the angle that the ship needs to turn in order to be aligned to the ground
EndIf

update_flame()

RenderWorld()

Text(0,0,"LinePickTime = "+LinePickTime+" ms")

Flip()

LimitFrameRate(38)

Wend

End

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

Function LimitFrameRate(FPS = 65)
	If FrameTime = 0 Then
		Period = 1000 / FPS
		FrameTime = MilliSecs()
	EndIf

	While (FrameTime + Period) > MilliSecs()
			Delay 1
	Wend
	FrameTime = MilliSecs()
End Function 

Type flame
	Field life%
	Field scale#
	Field x#,y#,z#
	Field obj
	Field alpha#
	Field R#,G#,B#
End Type

Function create_flame(entity,x#,y#,z#,life#)
	f.flame = New flame
		f\obj = CreateSphere(10,entity)
		f\R# = 0
		f\G# = 155
		f\B# = 255
		EntityColor f\obj,f\R,f\G,f\B
		EntityFX f\obj,1
		EntityBlend f\obj,3
		f\scale# = Rand(1,4)
		f\alpha# = 1
		f\life = life#
	PositionEntity f\obj,x,y,z
	EntityParent f\obj,0
End Function

Function update_flame()
	For f.flame = Each flame
		f\G = f\G - Rand(0,10)
		EntityColor f\obj,f\R,f\G,f\B
		f\alpha = f\alpha - .1
		ScaleEntity f\obj,f\scale,f\scale,f\scale
		EntityAlpha f\obj,f\alpha
		f\life = f\life - 1
		If f\life < 0 Then
			FreeEntity f\obj
			Delete f
		End If
	Next
End Function

Last edited 2012

Aussie

(Posted 2012) [#11]

Thanks for the help RemiD.
Very much appreciated. I would be interested in trying to use vectors but way over my head with the formulas.

Kryzon

(Posted 2012) [#12]

The best way i have found to make it fast :
At the begining of each loop, delete all colliders and disable all pickmode.

Before you do a check, set only the collider or the pickmode of the colliders you need.

Cool idea; I hadn't thought of that before.
Changing pickmodes is merely setting values in memory internally, so it should be much faster than having every redundant but potentially pickable entity be tested.

Anyway, I played with the code a bit, changed [a lot of] things... and filled the vector math routine. Took a while.
Seems to work ok; it's definitely much faster. Just copy and paste:

; Vector-math adaptation by Rafael "Kryzon".

Graphics3D 1024,768,0,2
HidePointer()
SetBuffer BackBuffer()

Const BENCHMARK_PASSES% = 1000 ;Try 10k to see a bigger difference. Vector-math is much faster.

Const MOVE_INCREMENT# = 0.25
Const MOVE_DECAY# = 0.1
Const TURN_INCREMENT# = 0.1

Const PICK_ROUTINE% = 1
Const VECTOR_ROUTINE% = 2

Const PLAYER_CLASS% = 1
Const ENEMY_CLASS% = 2
Const NEUTRAL_CLASS% = 3

Global RoutineMode% = PICK_ROUTINE

Global FPSTimer% = CreateTimer(60)
Global performanceTime#


AmbientLight 130,70,40
light = CreateLight()
	RotateEntity light,150,-45,0
	  
Global camera = CreateCamera()
	CameraRange camera,1,2000
	PositionEntity camera,0,1000,0
	RotateEntity camera,90,0,0
	
Global planet = CreateSphere(64)
	EntityColor planet,25,150,250
	;Radius of planet is '550'. Distance from ship to planet is 20, so a 'real' radius of 570.
	ScaleEntity planet,550,550,550 
	;If using the Sphere pickmode the 'collider pivot' is no longer necessary. Linepick will still use the same fast spherical 
	;representation of the entity even if it's a complex mesh.
	EntityRadius(planet,550)
	EntityPickMode(planet,1)

Global player.starShip = CreateShip(PLAYER_CLASS)

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
While Not KeyDown (1)
	WaitTimer(FPSTimer)

	UpdateWorld()
	UpdateScene()

	RenderWorld()
	Render2D()

	Flip()
Wend

End
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;


Type flame
	Field life%
	Field scale#
	Field x#,y#,z#
	Field obj
	Field alpha#
	Field R#,G#,B#
End Type


Type starShip
	Field mesh%
	Field flamePoint%
	Field flameLight%
	Field vector.movementVector
	
	Field class% 
End Type


Type movementVector ;A vector in the X ~ Z plane.
	Field x#
	Field y#
End Type


Function CreateShip.starShip(class%)
	s.starShip = New starShip
	s\vector = New movementVector
	s\class = class
	s\flamePoint = CreatePivot()

	Select class
		Case PLAYER_CLASS
			s\mesh = CreateCone()
			PositionEntity s\mesh,0,570,0
			RotateMesh s\mesh,90,0,0
			ScaleEntity s\mesh,8,8,12
			EntityColor s\mesh,0,255,0
			EntityParent s\flamePoint,s\mesh,False
			MoveEntity s\flamePoint,0,0,-1
			
			s\flameLight = CreateLight(2)
			EntityParent s\flameLight,s\flamePoint,False
			MoveEntity s\flameLight,0,0,-1
			LightRange s\flameLight,0.1
		
		Case ENEMY_CLASS
			;Different visuals, settings etc.
		
		Case NEUTRAL_CLASS
			;Different visuals, settings etc.
	End Select
	
	Return s
End Function


Function CreateFlame(entity,x#,y#,z#,life#)	
	f.flame = New flame
		f\obj = CreateSphere(10,entity)
		f\R# = 0
		f\G# = 155
		f\B# = 255
		EntityColor f\obj,f\R,f\G,f\B
		EntityFX f\obj,1
		EntityBlend f\obj,3
		f\scale# = Rand(1,4)
		f\alpha# = 1
		f\life = life#
	PositionEntity f\obj,x,y,z
	EntityParent f\obj,0
End Function


Function UpdateFlame()
	For f.flame = Each flame
		f\G = f\G - Rand(0,10)
		EntityColor f\obj,f\R,f\G,f\B
		f\alpha = f\alpha - .075
		ScaleEntity f\obj,f\scale,f\scale,f\scale
		EntityAlpha f\obj,f\alpha
		f\life = f\life - 1
		If f\life < 0 Then
			FreeEntity f\obj
			Delete f
		End If
	Next
End Function


Function UpdateScene()
	UpdateShips()
   ;UpdateProps()
   ;[...]
   
	UpdateFlame()
End Function


Function UpdateShips()
	;Update each class of ship based on specific logic.
	For s.starShip = Each starShip
		Select s\class
			Case PLAYER_CLASS
				UpdatePlayer(s)
			Case ENEMY_CLASS
				;UpdateEnemy(s)
			Case NEUTRAL_CLASS
				;UpdateNeutral(s)
		End Select
		
		MoveShip(s)
	Next
End Function


Function UpdatePlayer(p.starShip)	
	Local kLEFT = KeyDown(203)
	Local kRIGHT = KeyDown(205)
	Local kUP = KeyDown(200)
	Local kDOWN = KeyDown(208)
	If KeyHit(57) Then RoutineMode = 3 - RoutineMode ;Toggles between '1' and '2'.
	
	;Left, Right.
	p\vector\x = p\vector\x - (TURN_INCREMENT * kLEFT) + (TURN_INCREMENT * kRIGHT)
	If (kLEFT + kRIGHT <> 1) Then p\vector\x = 0 ;If pressing both keys or none at all, do not turn the ship.
	
	If p\vector\x > 1 Then p\vector\x = 1
	If p\vector\x < -1 Then p\vector\x = -1
		
	;Up, Down.
	p\vector\y = p\vector\y + (MOVE_INCREMENT * kUP) - (MOVE_INCREMENT * kDOWN) 
	
	p\vector\y = p\vector\y - MOVE_DECAY
	If p\vector\y > 5 Then p\vector\y = 5
	If p\vector\y < 0 Then p\vector\y = 0
	
	;Special FX.
	If kUP Then CreateFlame(p\flamePoint,Rnd(-.75,.75),0,0,Rnd(75,200))
	LightRange(p\flameLight, (30*(p\vector\y / 5)^2 + 0.1) )
End Function


Function MoveShip(s.starShip)
	performanceTime = MilliSecs()

	Select RoutineMode			
		Case PICK_ROUTINE
			For benchmark = 1 To BENCHMARK_PASSES
				TFormVector 0,-100,0,s\mesh,0
				LinePick (EntityX(s\mesh,True),EntityY(s\mesh,True),EntityZ(s\mesh,True),TFormedX(),TFormedY(),TFormedZ())
			Next 
				
			PositionEntity s\mesh,PickedX(),PickedY(),PickedZ()
			AlignToVector s\mesh,PickedNX(),PickedNY(),PickedNZ(),2			  
			
			MoveEntity s\mesh,0,20,s\vector\y
			
			If s\vector\y > 0 Then ;If the ship is moving at all then allow turning.
				TFormVector s\vector\x * (s\vector\y / 5),0,s\vector\y,s\mesh,0 ;Get the motion vector in world coordinates. Note the use of the X ~ Z plane.
				AlignToVector s\mesh,TFormedX(),TFormedY(),TFormedZ(),3
			EndIf 			
			
			performanceTime = (MilliSecs() - performanceTime)
		
		Case VECTOR_ROUTINE
			For benchmark = 1 To BENCHMARK_PASSES
				TFormPoint s\vector\x,0,s\vector\y,s\mesh,0
				;Distance from the target direction to the center of the planet:
				Local pointLength# = Sqr(TFormedX()*TFormedX() + TFormedY()*TFormedY() + TFormedZ()*TFormedZ())
				pointLength = 570.0 / pointLength
			
				Local vx#,vy#,vz# 
				vx = TFormedX()*pointLength
				vy = TFormedY()*pointLength
				vz = TFormedZ()*pointLength
			Next
			
			MoveEntity s\mesh,0,0,s\vector\y
				
			If s\vector\y > 0 Then
				AlignToVector s\mesh,(vx - EntityX(s\mesh,True)),(vy - EntityY(s\mesh,True)),(vz - EntityZ(s\mesh,True)),3,(s\vector\y / 5)			
			EndIf 
									
			performanceTime = (MilliSecs() - performanceTime)			
	End Select
End Function


Function Render2D()
	Local tempX#,tempY#
	
	;Neat bit, showing indicator for the occluded player ship so you have some sense where you're at.
	If EntityDistance(camera, player\mesh) > 1000 Then
		CameraProject camera,EntityX(player\mesh,True),EntityY(player\mesh,True),EntityZ(player\mesh,True)
		Rect ProjectedX()-2,ProjectedY()-2,4,4,0
		tempX = ProjectedX() : tempY = ProjectedY()
		TFormPoint player\vector\x,0,player\vector\y,player\mesh,0
		CameraProject camera,TFormedX(),TFormedY(),TFormedZ()
		Line tempX,tempY,ProjectedX(),ProjectedY()
	EndIf 

	;Performance information.
	Select RoutineMode
		Case PICK_ROUTINE
			Text(0,8," LinePick performance: "+performanceTime+" ms")
		Case VECTOR_ROUTINE
			Text(0,8," Vector-math performance: "+performanceTime+" ms")
	End Select
	
	Local msg$ = "Press SPACE to change movement logic. "
	Text GraphicsWidth()-StringWidth(msg),8,msg
End Function

Last edited 2012

Aussie

(Posted 2012) [#13]

Cool.
Thanks heaps Kryzon.
Love the effect of the light on the surface of the planet.

Kryzon

(Posted 2012) [#14]

� Added a single enemy following the player.

When you want to add more features to your program you notice how important modularity and structure are. Generic setup functions, generic types\classes, sensible frameworking.
It made it all that much easier knowing where to add the new code, or change some parts (like the behind-the-planet 2D indicators).

; Vector-math adaptation 2.0 - Includes simple AI.

Graphics3D 1024,768,0,2
HidePointer()
SetBuffer BackBuffer()

Const BENCHMARK_PASSES% = 1 ;Try 10k to see a bigger difference. Vector-math is much faster.

Const MOVE_INCREMENT# = 0.25
Const MOVE_DECAY# = 0.1
Const TURN_INCREMENT# = 0.1

Const PICK_ROUTINE% = 1
Const VECTOR_ROUTINE% = 2

Const PLAYER_CLASS% = 1
Const ENEMY_CLASS% = 2
Const NEUTRAL_CLASS% = 3

Global RoutineMode% = PICK_ROUTINE

Global FPSTimer% = CreateTimer(60)
Global performanceTime#


AmbientLight 130,70,40
light = CreateLight()
	RotateEntity light,150,-45,0
	  
Global camera = CreateCamera()
	CameraRange camera,1,2000
	PositionEntity camera,0,1000,0
	RotateEntity camera,90,0,0
	
Global planet = CreateSphere(64)
	EntityColor planet,25,150,250
	ScaleEntity planet,550,550,550 ;Radius of planet is '550'. Distance from ship to planet is 20, so a 'real' radius of 570.
	;If using the Sphere pickmode the 'collider pivot' is no longer necessary. Linepick will still use the same fast spherical 
	;representation of the entity even if it's a complex mesh.
	EntityRadius(planet,550)
	EntityPickMode(planet,1)

Global player.starShip = CreateShip(PLAYER_CLASS)
Global enemy1.starShip = CreateShip(ENEMY_CLASS)

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
While Not KeyDown (1)
	WaitTimer(FPSTimer)

	UpdateWorld()
	UpdateScene()

	RenderWorld()
	Render2D()

	Flip()
Wend

End
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;


Type flame
	Field life%
	Field scale#
	Field x#,y#,z#
	Field obj
	Field alpha#
	Field R#,G#,B#
End Type


Type starShip
	Field mesh%
	Field flamePoint%
	Field flameLight%
	Field vector.movementVector
	
	Field class% 
End Type


Type movementVector ;A vector on the X ~ Z plane.
	Field x#
	Field y#
End Type


Function CreateShip.starShip(class%)
	;Generic setup for all ships.
	s.starShip = New starShip
	s\vector = New movementVector
	s\class = class
	s\flamePoint = CreatePivot()
	
	;Class-specific setup.
	Select class
		Case PLAYER_CLASS
			s\mesh = CreateCone()
			PositionEntity s\mesh,0,570,0
			RotateMesh s\mesh,90,0,0
			ScaleEntity s\mesh,8,8,12
			EntityColor s\mesh,0,255,0
			EntityParent s\flamePoint,s\mesh,False
			MoveEntity s\flamePoint,0,0,-1
			
			s\flameLight = CreateLight(2)
			EntityParent s\flameLight,s\flamePoint,False
			MoveEntity s\flameLight,0,0,-1
			LightRange s\flameLight,0.1
		
		Case ENEMY_CLASS
			;Different visuals, settings etc.
			s\mesh = CreateCone()
			PositionEntity s\mesh,0,-570,0
			
			TurnEntity s\mesh,0,180,180 ;Necessary to setup the enemy behind the planet, and coming from behind.
			
			ScaleEntity s\mesh,8,8,12
			RotateMesh s\mesh,90,0,0
			EntityColor s\mesh,255,100,0
			EntityParent s\flamePoint,s\mesh,False
			MoveEntity s\flamePoint,0,0,-1
			
			s\flameLight = CreateLight(2)
			LightColor s\flameLight,255,200,-100
			EntityParent s\flameLight,s\flamePoint,False
			MoveEntity s\flameLight,0,0,-1
			LightRange s\flameLight,0.1
					
		Case NEUTRAL_CLASS
			;Different visuals, settings etc.
			
	End Select
	
	Return s
End Function


Function CreateFlame(entity,x#,y#,z#,life#,class%=PLAYER_CLASS)	
	f.flame = New flame
		f\obj = CreateSphere(10,entity)
		
		Select class
			Case PLAYER_CLASS
				f\R# = 0
				f\G# = 155
				f\B# = 255
			Case ENEMY_CLASS
				f\R# = 255
				f\G# = 180
				f\B# = 70
			Case NEUTRAL_CLASS
		End Select
		 
		EntityColor f\obj,f\R,f\G,f\B
		EntityFX f\obj,1
		EntityBlend f\obj,3
		f\scale# = Rand(1,4)
		f\alpha# = 1
		f\life = life#
	PositionEntity f\obj,x,y,z
	EntityParent f\obj,0
End Function


Function UpdateFlame()
	For f.flame = Each flame
		f\G = f\G - Rand(0,10)
		EntityColor f\obj,f\R,f\G,f\B
		f\alpha = f\alpha - .075
		ScaleEntity f\obj,f\scale,f\scale,f\scale
		EntityAlpha f\obj,f\alpha
		f\life = f\life - 1
		If f\life < 0 Then
			FreeEntity f\obj
			Delete f
		End If
	Next
End Function


Function UpdateScene()
	UpdateShips()
   ;UpdateProps()
   ;[...]
   
	UpdateFlame()
End Function


Function UpdateShips()
	;Update each class of ship based on specific logic.
	For s.starShip = Each starShip
		Select s\class
			Case PLAYER_CLASS
				UpdatePlayer(s)
			Case ENEMY_CLASS
				UpdateEnemies(s)
			Case NEUTRAL_CLASS
				;UpdateNeutral(s)
		End Select
		
		MoveShip(s)
	Next
End Function


Function UpdatePlayer(p.starShip)	
	Local kLEFT = KeyDown(203)
	Local kRIGHT = KeyDown(205)
	Local kUP = KeyDown(200)
	Local kDOWN = KeyDown(208)
	If KeyHit(57) Then RoutineMode = 3 - RoutineMode ;Toggles between '1' and '2'.
	
	;Left, Right.
	p\vector\x = p\vector\x - (TURN_INCREMENT * kLEFT) + (TURN_INCREMENT * kRIGHT)
	If (kLEFT + kRIGHT <> 1) Then p\vector\x = 0 ;If pressing both keys or none at all, do not turn the ship.
	
	If p\vector\x > 1 Then p\vector\x = 1
	If p\vector\x < -1 Then p\vector\x = -1
		
	;Up, Down.
	p\vector\y = p\vector\y + (MOVE_INCREMENT * kUP) - (MOVE_INCREMENT * kDOWN) 
	
	p\vector\y = p\vector\y - MOVE_DECAY
	If p\vector\y > 5 Then p\vector\y = 5
	If p\vector\y < 0 Then p\vector\y = 0
	
	;Special FX.
	If kUP Then CreateFlame(p\flamePoint,Rnd(-.75,.75),0,0,Rnd(75,200),PLAYER_CLASS)
	LightRange(p\flameLight, (30*(p\vector\y / 5)^2 + 0.1) )
End Function


Function UpdateEnemies(e.starShip)
	;Floyd's TFormPoint suggestion!
	
	;Transform player's world position to enemy's local space, aligned with the enemy's local axes.
	TFormPoint EntityX(player\mesh,True),EntityY(player\mesh,True),EntityZ(player\mesh,True),0,e\mesh
	
	;Steer the enemy based on the player's X position in the enemy's space.
	If Abs(TFormedX()) > 10.0 Then 
		e\vector\x = e\vector\x + Sgn(TFormedX())*TURN_INCREMENT
	Else 
		e\vector\x = TFormedX()/10.0 ;Smooth-out the steering the more the enemy faces the player.
	EndIf 
	
	If e\vector\x > 1 Then e\vector\x = 1
	If e\vector\x < -1 Then e\vector\x = -1
	
	;Move the enemy towards the player, but just so much as to reach out behind him (around 109 units distant).
	Local tempDistance# = EntityDistance(e\mesh, player\mesh)
	e\vector\y = e\vector\y + ((tempDistance > 125)*MOVE_INCREMENT)
	
	e\vector\y = e\vector\y - MOVE_DECAY
	If e\vector\y > 4 Then e\vector\y = 4 ;Note the enemy's speed is 4, instead of player's 5.
	If e\vector\y < 0 Then e\vector\y = 0
	
	;Special FX.
	If tempDistance > 125 Then CreateFlame(e\flamePoint,Rnd(-.75,.75),0,0,Rnd(75,200),ENEMY_CLASS)
	LightRange(e\flameLight, (30*(e\vector\y / 4)^2 + 0.1) )
End Function


Function MoveShip(s.starShip)
	performanceTime = MilliSecs()

	Select RoutineMode			
		Case PICK_ROUTINE
			For benchmark = 1 To BENCHMARK_PASSES
				TFormVector 0,-100,0,s\mesh,0
				LinePick (EntityX(s\mesh,True),EntityY(s\mesh,True),EntityZ(s\mesh,True),TFormedX(),TFormedY(),TFormedZ())
			Next 
				
			PositionEntity s\mesh,PickedX(),PickedY(),PickedZ()
			AlignToVector s\mesh,PickedNX(),PickedNY(),PickedNZ(),2			  
			
			MoveEntity s\mesh,0,20,s\vector\y
			
			If s\vector\y > 0 Then ;If the ship is moving at all then allow turning.
				TFormVector s\vector\x * (s\vector\y / 5),0,s\vector\y,s\mesh,0 ;Get the motion vector in world coordinates. Note the use of the X ~ Z plane.
				AlignToVector s\mesh,TFormedX(),TFormedY(),TFormedZ(),3
			EndIf 			
			
			performanceTime = (MilliSecs() - performanceTime)
		
		Case VECTOR_ROUTINE
			For benchmark = 1 To BENCHMARK_PASSES
				TFormPoint s\vector\x,0,s\vector\y,s\mesh,0
				;Distance from the target direction to the center of the planet:
				Local pointLength# = Sqr(TFormedX()*TFormedX() + TFormedY()*TFormedY() + TFormedZ()*TFormedZ())
				pointLength = 570.0 / pointLength
			
				Local vx#,vy#,vz# 
				vx = TFormedX()*pointLength
				vy = TFormedY()*pointLength
				vz = TFormedZ()*pointLength
			Next
			
			MoveEntity s\mesh,0,0,s\vector\y
				
			If s\vector\y > 0 Then
				AlignToVector s\mesh,(vx - EntityX(s\mesh,True)),(vy - EntityY(s\mesh,True)),(vz - EntityZ(s\mesh,True)),3,(s\vector\y / 5)			
			EndIf 
									
			performanceTime = (MilliSecs() - performanceTime)			
	End Select
End Function


Function Render2D()
	
	
	;Neat bit, showing indicator for the occluded player ship so you have some sense where you're at.
	Local tempX#,tempY#
	
	For s.starShip = Each starShip
		If EntityDistance(camera, s\mesh) > 1000 Then
			CameraProject camera,EntityX(s\mesh,True),EntityY(s\mesh,True),EntityZ(s\mesh,True)
			Rect ProjectedX()-2,ProjectedY()-2,4,4,0
			tempX = ProjectedX() : tempY = ProjectedY()
			TFormPoint s\vector\x,0,s\vector\y,s\mesh,0
			CameraProject camera,TFormedX(),TFormedY(),TFormedZ()
			Line tempX,tempY,ProjectedX(),ProjectedY()
		EndIf
	Next 

	;Performance information.
	Select RoutineMode
		Case PICK_ROUTINE
			Text(0,8," LinePick performance: "+performanceTime+" ms")
		Case VECTOR_ROUTINE
			Text(0,8," Vector-math performance: "+performanceTime+" ms")
	End Select
	
	Local msg$ = "Press SPACE to change movement logic. "
	Text GraphicsWidth()-StringWidth(msg),8,msg
End Function

Aussie

(Posted 2012) [#15]

Thanks again Kryzon.

I'm not at my computer at the moment so i am unable to see what you have done & probably won�t get much of a chance until the weekend.

When you want to add more features to your program you notice how important modularity and structure are. Generic setup functions, generic types\classes, sensible frameworking.

I agree completely. Whenever i get the chance to have a go at coding & play with ideas it always starts off a bit mix & match until i get things starting to work. Once i get things tested & working i then go through & start organising things into functions & types. One thing i do need to do is start commenting my code more as i go, i have some bits & pieces of code from when i first started coding & if i haven�t been able to code for a while it takes a fair bit time to catch up on what i was doing.

Thanks again.