Beginner question

Blitz3D Forums/Blitz3D Beginners Area/Beginner question

TomShep

(Posted 2012) [#1]

Hello,

I am very new to blitz and programming in general - but try to make smallish games to help learning process-however - have come across something Im a bit stuck on.

Im trying to make a small game when blocks fall from the top of the screen and then land at the bottom of the screen, or on top of the blocks underneath (I suppose like tetris)

I have the blocks falling properly but getting only the relevant ones to stop is causing me problems, e.g

For b.block = Each block
DrawImage img_block,b\x,b\y
b\y = b\y + gravity
If b\y < 568 gravity = 0
Next

Obviously this stops all the blocks where they are at as soon as one hits the bottom, the line;

If b\y < 568 then b\y = 568 is fine for a bottom layer of blocks, but i can not get the blocks to land ontop of one another. Further, I cannot use the imagescolllide command to only refer to the actualy blocks colliding

Can anybody help? Any help at all would be greatlyappreciated.
Tom

Adam Novagen

(Posted 2012) [#2]

Well, the first part of your problem is easily solved: give each block its own gravity.

For b.block = Each block
    DrawImage img_block,b\x,b\y
    b\y = b\y + b\gravity
    If b\y < 568 b\gravity = 0
Next

For a more compact solution, reverse your problem. Rather than stopping gravity when a block reaches a certain height, only move the block if it hasn't reached its intended position yet, e.g.:

For b.block = Each block
    DrawImage img_block,b\x,b\y
    If b\y > 568 Then b\y = b\y + gravity
Next

Last edited 2012

Last edited 2012

Ross C

(Posted 2012) [#3]

If you are doing a tetris type game, I think you are better to create a container for your dropped blocks. An Array:


Dim Play_Area(6,20) ; 7 wide by 21 tall.

Anytime a block has fallen and is resting in position, place a 1 in the array slot. You can also use this to determine where to stop a block, and whether it will collide with a block. When your block is falling, assign it to a grid slot in the array.

When it moving between grid slots, check the grid slot underneath to see if it contains a 1:

If it does, the block cannot fall anymore. Leave that array slot with a 1 in it.

If it does not, then place a one in the new array slot, and delete the previous one (set it to zero)

Ross C

(Posted 2012) [#4]

Here is some example code to work from, when dealing with an array play area. It's very basic, and I have tried to comment the best I can. It doesn't use types for simplicity. Arrow keys DOWN, LEFT and RIGHT to operate:

Graphics 800,600
SetBuffer BackBuffer()


Global block_size = 16

; create an image of a block based on the above block size
Global block = CreateImage(block_size,block_size)
SetBuffer ImageBuffer(block)
Color 0,255,0
Rect 0,0,32,32
SetBuffer BackBuffer()

Color 255,255,255

Global play_area_x = 5
Global play_area_y = 20
Dim play_area(5,20) ; 6 by 21 play area




Global block_timer = MilliSecs()
Global block_time = 700 ; set the time the block takes to fall down 1 block to 700 millisecs (0.7 seconds)

Global block_x = 3
Global block_y = 0

Global draw_start_x = 100
Global draw_start_y = 100

While Not KeyHit(1)

	Cls

	If KeyHit(203) Then
		; ensure the block remains within the play area after being moved
		If block_x >0
			; ensure no block occupies the area being moved to
			If play_area(block_x - 1, block_y) = 0 Then
				block_x = block_x - 1
			End If
		End If
	ElseIf KeyHit(205) Then
		If block_x < play_area_x
			If play_area(block_x + 1, block_y) = 0 Then
				block_x = block_x + 1
			End If
		End If
	End If
	If KeyHit(208) Then
		block_timer = MilliSecs() ; reset the block timer
		move_block_down()
	End If

	If MilliSecs() > block_time + block_timer Then
		block_timer = MilliSecs() ; reset the block timer
		move_block_down()
	End If

	draw_everything()

	Flip

Wend
End


Function move_block_down()

	;increase the co-ords of the blocks position
	block_y = block_y + 1

	; first check to see if the block is out of bounds at the bottom of the play area.
	If block_y > 20 Then
		; if it is, set to previous position and set in the play area as it cannot collide with anything.
		block_y = block_y - 1
		play_area(block_x,block_y) = 1
		block_y = 0
		block_x = 3
		
	; ELSE if the block is still within the play area, then...
	Else
		;check to see if the current position the block occupies is taken
		If play_area(block_x,block_y) = 1 Then
			; if it is, move the block back 1 co-ord
			block_y = block_y - 1
	
			; now check to see if the block is out of bounds, since you have moved it back
			If block_y < 0 Then
				RuntimeError("You lose!")
			Else
				; if it isn't out of bounds, place a 1 in the array to indicate there is a block here.
				play_area(block_x,block_y) = 1
				; reset the falling blocks co-ords, essentially generating a new one.
				block_y = 0
				block_x = 3
			End If
		End If
	End If
	
End Function

Function draw_everything()

	Color 255,255,255
	Rect draw_start_x-1,draw_start_y-1,(play_area_x+1) * block_size + 2 , (play_area_y+1) * block_size + 2

	;draw the play area and the blocks that have fallen
	For loop_x = 0 To play_area_x
		For loop_y = 0 To play_area_y
		
			If play_area(loop_x,loop_y) = 1 Then
				DrawImage block, draw_start_x + (loop_x * block_size) , draw_start_y + (loop_y * block_size)
			End If
			
		Next
	Next
	
	;draw our block
	DrawImage block,draw_start_x + (block_x*block_size) , draw_start_y + (block_y*block_size)
	
End Function

Last edited 2012

Last edited 2012

TomShep

(Posted 2012) [#5]

Thanks you all for your comments and code pieces - I am hugely appreciative,

Tom