Types Problem

Blitz3D Forums/Blitz3D Beginners Area/Types Problem

Happy Llama

(Posted 2012) [#1]

When I try to run my code I get the error "Entity does not exist" and it highlights this line of code.


a\mesh = CopyEntity(snowball)

I don't know why. It was working before. Here's the rest if you need it:


Graphics3D 800,600,0,1
SetBuffer BackBuffer()

SeedRnd MilliSecs()

Global snowballtimer=MilliSecs()
countdowntimer=MilliSecs()

;variables
Global spacebar=57,escape=1,leftkey=208,rightkey=205
Global gravity=0.3
Global cam_y#=-3
Global cam_x#=0 
Global magazine=5
Global playerhealth=100
Global enemyhealth=1000
Global score = 0
Global enemyalive=0
Global collision_id
Global collision_entitiy
Global frametimer = 0
Global crouch=0
Global currentimage=3
Global pregame=0
Global startmenu=1

three=LoadImage("3.png")
MaskImage three,255,255,255
two=LoadImage("2.png") 
MaskImage two,255,255,255
one=LoadImage("1.png")
MaskImage one,255,255,255
go=LoadImage("go.png") 
MaskImage go,255,255,255



While pregame = 0
   If KeyDown(1) Then End ;this avoids getting locked in this loop
   Cls
   If MilliSecs() >= timer + 1000 ;If 1 second has passed...
      currentimage = currentimage - 1 ;Here's how you count down!
      timer = MilliSecs() ;reset the timer so that it will wait another second
   EndIf
   If currentimage = 3 ;If the current image is "3"
      DrawImage three,0,0
   EndIf
   If currentimage = 2 ;If the current image is "2"
      DrawImage two,0,0
   EndIf
   If currentimage = 1 ;If the current image is "1"
      DrawImage one,0,0
   EndIf
   If currentimage = 0 ;If the current image is "0"
      DrawImage go,0,0 ;Draw the go image
   EndIf
   If currentimage < 0 ;If the current image has already drawn "Go"
      pregame = 1 ;You're now ready to leave the mini loop and start the game
   EndIf
   Flip

Wend

HidePointer

Global ow=LoadSound("ow.wav")
SoundVolume ow, 0.2

;Types

Type snowball
	Field mesh	
	Field id	
	Field damage
	Field yspeed#
End Type

Const type_player=1
Const type_enemy=2
Const type_playersnowball=3
Const type_enemysnowball=4
Const type_1fort=5
Const type_2fort=6

AmbientLight 255,255,255

;Light
sun=CreateLight()


;Player
player=CreateCamera()
CameraFogRange player,0.1,400
CameraFogMode player,True
CameraClsColor player,100,130,150
CameraFogColor player,100,130,150
EntityRadius player,0.5
EntityType player,type_player

;Terrain
ground=CreatePlane()
PositionEntity ground,0,-5,0
EntityColor ground,200,200,200


;Sky
sky=CreatePlane()
PositionEntity sky,0,100,0
RotateEntity sky,-180,0,0
;Sky texture
skytex=LoadTexture("sky.jpg")
EntityTexture sky,skytex
ScaleTexture skytex,5,5
ScaleTexture skytex,500,500

;Load the enemy

enemy=LoadMesh("enemy.3ds")
PositionEntity enemy,0,-4,27
ScaleEntity enemy,0.4,0.4,0.4
EntityType enemy,type_enemy

;Create the bullets
snowball=CreateSphere()
ScaleEntity snowball,0.5,0.5,0.5
HideEntity snowball

;Make the snow forts:

;Fort 1
fort1=LoadMesh("snowfort.3ds")
PositionEntity fort1,0,-3.5,4
EntityColor fort1,255,255,255
ScaleEntity fort1,1,1,2.5
RotateEntity fort1,0,-90,0
EntityType fort1, type_fort1

;Fort 2
fort2=CreateCube()
PositionEntity fort2,0,-4,25
EntityColor fort2,255,255,255
ScaleEntity fort2,2,1,1
EntityType fort1, type_fort2

;aimer
aimer=LoadImage("Aimer.png")
MaskImage aimer,255,255,255
ScaleImage aimer,0.3,0.3
MidHandle aimer


;Making it snow!

;Dim snowflake(1000)

;For p=0 To 1000

;snowflake(p)=CreateSphere()

;ScaleEntity snowflake(p),0.05,0.05,0.05

;PositionEntity snowflake(p),Rnd(-50,50),Rnd(1,100),Rnd(-50,50)

;Next

Collisions type_playersnowball, type_enemy, 2,2
Collisions type_enemysnowball, type_player,1,2

;###############
;#  Main Loop  #
;###############
While Not KeyDown (escape)


;player snowballs
If MouseHit(1) And magazine > 0
	s.snowball = New snowball 		
	s\mesh = CopyEntity(snowball)		
	s\id = 1						
	s\damage = 5
	s\yspeed# = 0				
	PositionEntity s\mesh,EntityX(player),EntityY(player),EntityZ(player)			
	RotateEntity s\mesh, EntityPitch(player),EntityYaw(player),EntityRoll(player)
		
	magazine = magazine -1
	EntityType s\mesh,type_playersnowball
	EntityRadius s\mesh, 2			
End If 


For s.snowball = Each snowball	
	MoveEntity s\mesh,0,s\yspeed,1
	s\yspeed#=s\yspeed#-0.01	
	If Abs(EntityZ(s\mesh)) > 400 	
	    FreeEntity s\mesh			
		Delete s					
	End If
Next

If KeyHit(18) And magazine < 1 Then 
	magazine = 5
EndIf 

If magazine < 1 Then
	Text 100,100,"Press E to Reload"
EndIf  

;Enemy snowballs
ThrowSnowballs()

;Collisions:

psnowball_collisions()
esnowball_collisions()



;Duck 

If KeyDown(57) Then  
crouch=1
cam_y=-3.7
Else
crouch=0
cam_y=-3
EndIf

PositionEntity player,cam_x,cam_y,3

;Straffting  

If KeyDown(30) Then cam_x=cam_x-0.1

If KeyDown(32) Then cam_x=cam_x+0.1


If cam_x > 0.5 Then cam_x=0.5
If cam_x < -0.5 Then cam_x=-0.5 

;Point the enemy at the player
If enemyhealth > 0
	PointEntity enemy,player
End If 

;FPS Camera Stuff
mx#=mx#+MouseXSpeed()
my#=my#+MouseYSpeed()

If mx# > 100 Then mx# = 100
If mx# < -100 Then mx# = -100

If my# > 40 Then my# = 40
If my# < -80 Then my# = -80

RotateEntity player,my#,-mx#,0

;Check menus

If playerhealth <= 0 Or score > 20 Then
;Cls
gameover()
End If


RenderWorld

UpdateWorld 

Color 0,0,0

Rect 10,10,170,70,False

Text 20,20,"Snowballs left: "+ magazine
Text 20,40,"Health: "+ playerhealth
Text 20,60,"Score: " + score

DrawImage aimer,GraphicsWidth()/2,GraphicsHeight()/2

Flip




Wend



End


Function psnowball_collisions()	
	For s.snowball = Each snowball						
		For collision_id = 1 To CountCollisions(s\mesh)	
			collision_entity = CollisionEntity(s\mesh, collision_id)
				If GetEntityType(collision_entity) = type_enemy		
					enemyhealth = enemyhealth - s\damage				
						DebugLog "enemyhealth " + enemyhealth
						score = score + 1
						FreeEntity s\mesh	
						Delete s			
							If enemyhealth <= 0 Then FreeEntity enemy	
						Exit
				End If
		Next
	Next
End Function 


Function esnowball_collisions()	
	For a.snowball = Each snowball						
		For collision_id = 1 To CountCollisions(a\mesh)	
			collision_entity = CollisionEntity(a\mesh, collision_id)
				If GetEntityType(collision_entity) = type_player And crouch=0		
					enemyhealth = enemyhealth - a\damage				
						DebugLog "playerhealth " + playerhealth
						PlaySound ow
						playerhealth=playerhealth-a\damage
						FreeEntity a\mesh	
						Delete a				
						Exit
				End If
		Next
	Next
End Function 
				


Function ThrowSnowballs()

   If MilliSecs() >= snowballtimer + 1000 + Rnd(-500,+500)              
    snowballtimer = MilliSecs() 
    a.snowball = New snowball
	a\mesh = CopyEntity(snowball)
	a\id = 2
	a\damage = 10
	PositionEntity a\mesh,EntityX(enemy),EntityY(enemy),EntityZ(enemy)
	RotateEntity a\mesh, EntityPitch(enemy)-7,EntityYaw(enemy)+Rnd(-2,+2),EntityRoll(enemy)
	EntityType a\mesh,type_enemysnowball
   EndIf


End Function

Function gameover()
If score >= 19 Then
win=LoadImage("win.png")
MaskImage win,255,255,255  
DrawImage win,130,200
Flip
Delay 3000
End
End If

If playerhealth <= 0 Then 
loose=LoadImage("loose.png")
MaskImage loose,255,255,255
DrawImage loose,0,0
Flip
Delay 3000
End
End If

End Function

Matty

(Posted 2012) [#2]

In your function "ThrowSnowballs" you refer to the entity 'snowball' which is not defined in the scope of this function....you either need to pass the snowball handle to the function or make snowball a global variable.

Happy Llama

(Posted 2012) [#3]

Thank you!