Chase Cam

Blitz3D Forums/Blitz3D Beginners Area/Chase Cam

Happy Llama

(Posted 2011) [#1]

Hi i am making a simple came where the camera follows the player. I have added a simple chase cam that follows the player but does not rotate with it. Please help!

Graphics3D 1000,700,64,3

Const gravity=0.3

sun=CreateLight()

playercam=CreateCamera()
RotateEntity playercam,30,0,0

ground=CreatePlane()
PositionEntity ground,0,-10,0
groundtex=LoadTexture("terrain-1.jpg")
EntityTexture ground, groundtex
ScaleTexture groundtex,50,50

player=CreateCube()
EntityColor player,0,255,0

While Not KeyDown (1)

If KeyDown(200) MoveEntity player,0,0,1
If KeyDown(208) MoveEntity player,0,0,-1
If KeyDown(203) TurnEntity player,0,3,0
If KeyDown(205) TurnEntity player,0,-3,0

PositionEntity playercam,EntityX(player),EntityY(player),EntityZ(player)
MoveEntity playercam,0,0,-5

UpdateWorld
RenderWorld

Flip

Wend

End

Thanks!

Last edited 2011

Rob the Great

(Posted 2011) [#2]

There are many ways to control a camera, but for what it sounds like you're trying to do, give one of these two examples a try. The first one positions the camera where you want it to be relative to the player, and then sets EntityParent camera,player so that it follows the player's movements:

Graphics3D 640,480,0,2

SetBuffer BackBuffer()

Global player = CreateCube()

Global camera = CreateCamera()
MoveEntity camera,0,0,-5
EntityParent camera,player

Global ground = CreatePlane()
EntityColor ground,0,255,0
MoveEntity ground,0,-1,0

While Not KeyDown(1)

   If KeyDown(200) Then MoveEntity player,0,0,1
   If KeyDown(208) Then MoveEntity player,0,0,-1
   If KeyDown(203) Then TurnEntity player,0,3,0
   If KeyDown(205) Then TurnEntity player,0,-3,0

   RenderWorld
   Flip

Wend

End

The other option is a little more complex. Basically, you create a camera pivot, make the camera pivot the parent entity of the camera, position the camera pivot where the player is at every logic loop, point the camera at the player every loop, rotate the camera pivot (orbiting the camera) if they push the A or D keys, and then move the camera closer or further to the camera pivot if they push the W or S keys and reparent to the pivot. This sounds complex, but it's not too bad. Just call UpdateCamera() every loop and you're set. Keep in mind that this is untested and is only meant for concept purposes. If you do wish to use this, make sure you add in actual scancodes in place of the KeyDown() letters in the UpdateCamera() function.

Graphics3D 640,480,0,2

SetBuffer BackBuffer()

Global player = CreateCube()

Global camera = CreateCamera()
MoveEntity camera,0,0,-5
Global camerapivot = CreatePivot()
EntityParent camera,camerapivot

Global ground = CreatePlane()
EntityColor ground,0,255,0
MoveEntity ground,0,-1,0

While Not KeyDown(1)

   If KeyDown(200) Then MoveEntity player,0,0,1
   If KeyDown(208) Then MoveEntity player,0,0,-1
   If KeyDown(203) Then TurnEntity player,0,3,0
   If KeyDown(205) Then TurnEntity player,0,-3,0

   UpdateCamera()

   RenderWorld
   Flip

Wend

Function UpdateCamera()

   PointEntity camera,player

   PositionEntity camerapivot,EntityX(player),EntityY(player),EntityZ(player)

   If KeyDown(A)
      TurnEntity camerapivot,0,1,0
   EndIf

   If KeyDown(D)
      TurnEntity camerapivot,0,-1,0
   EndIf

   If KeyDown(W)
      If EntityDistance(player,camera) > 3
         EntityParent camera,0
         PointEntity camera,player
         MoveEntity camera,0,0,1
         EntityParent camera,camerapivot
      EndIf
   EndIf

   If KeyDown(S)
      If EntityDistance(player,camera) < 10
         EntityParent camera,0
         PointEntity camera,player
         MoveEntity camera,0,0,-1
         EntityParent camera,camerapivot
      EndIf
   EndIf

End Function

End

Happy Llama

(Posted 2011) [#3]

The camera still wont rotate with the cube. Any ideas on how to do that?

Rob the Great

(Posted 2011) [#4]

I don't think I follow...That first example should do that. I might have done something wrong, it was all written on the fly.

What do you mean by "rotate with the cube"? Something more like the camera movement in the castle demo?

Krischan

(Posted 2011) [#5]

Hmm, do you want this effect (based on your code)?

Graphics3D 800,600,32,2

timer=CreateTimer(60)

sun=CreateLight()

player=CreateCube()
EntityColor player,0,255,0
PositionEntity player,0,1.5,0

playercam=CreateCamera(player)
PositionEntity playercam,0,3,-6
RotateEntity playercam,30,0,0

ground=CreateGrid()

While Not KeyDown (1)
	
	If KeyDown(200) Then MoveEntity player,0,0,1
	If KeyDown(208) Then MoveEntity player,0,0,-1
	If KeyDown(203) Then TurnEntity player,0,3,0
	If KeyDown(205) Then TurnEntity player,0,-3,0
	
	UpdateWorld
	RenderWorld
	
	WaitTimer timer
	
	Flip 0
	
Wend

End

; create a nice ground grid
Function CreateGrid()
	
	Local x%,y%
	
	Local plane%=CreatePlane()
	Local tex%=CreateTexture(512,512,8)
	
	SetBuffer TextureBuffer(tex)
	
	; texture background
	Color 0,0,64 : Rect 0,0,512,512,1
	
	; texture grid
	Color 255,255,255
	For x=0 To 511 Step 32
		For y=0 To 511 Step 32
			Rect x,y,32,32,0
		Next
	Next
	
	SetBuffer BackBuffer()
	
	EntityTexture plane,tex
	ScaleTexture tex,128,128
	EntityAlpha plane,0.5
	
	Local mirror=CreateMirror(plane)
	
	
End Function

My own Third/Chasecam code goes like that:

; changeable variables
Const ScreenWidth% = 800
Const ScreenHeight% = 600
Const PlayerMovespeed# = 10.0
Const PlayerSize# = 16.0
Const CameraDistance# = 100.0
Global PlayerTurnspeed# = 25.0
Global CameraFOV# = 90.0
Global Timer% = CreateTimer(60)

; scene objects
Global Player%,PlayerHead%,PlayerCenter%,PlayerPivot%,PlayerCone%,Camera%

; collision types
Const CCAM%=1
Const CWORLD%=2

Graphics3D ScreenWidth,ScreenHeight,32,2

InitScene()

While Not KeyHit(1)
	
	Local wf%,mwheel%
	
	; SPACE = Wireframe
	If KeyHit(57) Then wf=1-wf : WireFrame wf
	
	; Mousewheel: change FOV angle
	mwheel=MouseZSpeed()
	If mwheel<0 Then
		CameraFOV=CameraFOV+5
		If CameraFOV>150 Then CameraFOV=150
		CameraZoom Camera,SetFOV(CameraFOV)
	EndIf
	If mwheel>0 Then
		CameraFOV=CameraFOV-5
		If CameraFOV<30 Then CameraFOV=30
		CameraZoom Camera,SetFOV(CameraFOV)
	EndIf
	
	; RMB = reset FOV to 90°
	If MouseDown(2) Then
		CameraFOV=90
		CameraZoom Camera,SetFOV(CameraFOV)
	EndIf
	
	ThirdCam(PlayerSize*10)
		
	UpdateWorld
		
	RenderWorld
	
	WaitTimer Timer
	
	Flip 0
	
Wend

End

Function InitScene()
	
	; Create Plane and Mirror
	CreateGrid()
	
	; Create Player body
	Player=CreateCube()
	ScaleMesh Player,PlayerSize,PlayerSize,PlayerSize
	PositionEntity Player,0,PlayerSize,0
	EntityFX Player,1
	EntityColor Player,255,0,0
	
	; Create Player "nose"
	PlayerCone=CreateCone(32)
	RotateEntity PlayerCone,90,0,0
	ScaleMesh PlayerCone,PlayerSize,PlayerSize,PlayerSize
	PositionEntity PlayerCone,0,PlayerSize,PlayerSize*2
	EntityParent PlayerCone,Player
	EntityFX PlayerCone,1
	EntityColor PlayerCone,0,255,0
	
	; Create invisible Player Pivots
	PlayerHead=CreatePivot()
	EntityParent PlayerHead,Player,1
	PositionEntity PlayerHead,0,PlayerSize,0
	PlayerCenter=CreatePivot(Player)
	PlayerPivot=CreatePivot()
	EntityParent PlayerPivot,PlayerCenter,1
	PositionEntity PlayerPivot,0,CameraDistance,-CameraDistance
	
	; Create Camera
	Camera=CreateCamera()
	CameraRange Camera,0.1,1000
	CameraFogRange Camera,0.1,1000
	CameraFogMode Camera,True
	CameraClsColor Camera,150,200,255
	CameraFogColor Camera,150,200,255
	EntityType Camera,CCAM
	EntityRadius Camera,PlayerSize
	
	Collisions CCAM,CWORLD,2,3
	
	MoveMouse ScreenWidth/2,ScreenHeight/2
	
	HidePointer
	
End Function

; create a nice ground grid
Function CreateGrid()
	
	Local x%,y%
	
	Local plane%=CreatePlane()
	Local tex%=CreateTexture(512,512,8)
	
	SetBuffer TextureBuffer(tex)
	
	; texture background
	Color 0,0,64 : Rect 0,0,512,512,1
	
	; texture grid
	Color 255,255,255
	For x=0 To 511 Step 64
		For y=0 To 511 Step 64
			Rect x,y,64,64,0
		Next
	Next
	
	SetBuffer BackBuffer()
	
	EntityTexture plane,tex
	ScaleTexture tex,512,512
	EntityType plane,CWORLD
	EntityAlpha plane,0.5
	
	Local mirror=CreateMirror(plane)
	
End Function

; third cam logic
Function ThirdCam(maxdistance#=100)
	
	Local movex#,movez#,px#,py#,pz#
	
	; move and turn player input
	movex#=(KeyDown(203)-KeyDown(205))
	movez#=(KeyDown(200)-KeyDown(208))
	
	; increase turnspeed
	PlayerTurnspeed=PlayerTurnspeed+(movex*2.00)
	
	; limit turnspeed
	PlayerTurnspeed=PlayerTurnspeed*0.6
	If Abs(PlayerTurnspeed)<0.0100 Then PlayerTurnspeed=0
	
	; move player
	MoveEntity Player,0,0,movez*PlayerMovespeed
	
	; move around player
	TurnEntity PlayerCenter,0,-MouseXSpeed()/3.0,0
	MoveMouse ScreenWidth/2,LimitMouseY()
	
	; smart cam
	TurnEntity Player,0,PlayerTurnspeed,0
	px=EntityX(PlayerPivot)
	py=Normalize(((MouseY()-(ScreenHeight/2))*1.0/(ScreenHeight/2)),-1,1,0,maxdistance)
	pz=EntityZ(PlayerPivot)
	PositionEntity PlayerPivot,px,py,pz
	px=EntityX(PlayerPivot,1)
	py=EntityY(PlayerPivot,1)
	pz=EntityZ(PlayerPivot,1)
	PositionEntity Camera,px,py,pz
	PointEntity Camera,PlayerHead
	
End Function

; limits vertical cursor position to 10% / 90%
Function LimitMouseY()
	
	Local my%=MouseY()
	
	If my<(ScreenHeight*0.1) Then my=(ScreenHeight*0.1) Else If my>ScreenHeight*0.9 Then my=ScreenHeight*0.9
	
	Return my
	
End Function

; normalizes a value
Function Normalize#(value#=128.0,value_min#=0.0,value_max#=255.0,norm_min#=0.0,norm_max#=1.0)
	
	Return ((value#-value_min#)/(value_max#-value_min#))*(norm_max#-norm_min#)+norm_min#
	
End Function

; sets camera field of view to a given angle
Function SetFOV#(angle#)
	
	Return 1.0/Tan(angle/2.0)
	
End Function

Happy Llama

(Posted 2011) [#6]

Thanks I was trying to get an effect on where the camera always looks at the back of the character. Thanks Krischan, that is exactly what is was looking for.

Last edited 2011