Calling graphics3d multiple times?

Blitz3D Forums/Blitz3D Beginners Area/Calling graphics3d multiple times?

Jaydubeww

(Posted 2010) [#1]

Upon coding, I realized I was going to be calling graphics3D twice (possibly more) during my game. I was wondering if this is a bad thing and I should avoid it? I'm calling it twice because my program flow is like this:

graphics3d...
variable declarations
variable initialization (which include creating and pivoting the player, this is why I have to call graphics3d already)
load ini (which has the user graphics settings)
set graphics3d accordingly
main loop

I guess I could have the initialization AFTER the second graphics3d, but I like having declarations and initializations close to each other..

Thanks!

Jaydubeww

(Posted 2010) [#2]

Sorry, but on a side note, my program runs perfectly in debug compile, but when I compile it normally, it gives me an error: unable to set graphics mode. Any thoughts?

Robert Cummings

(Posted 2010) [#3]

I don't think calling Graphics3D multiple times will give you an issue. Can you post code so we can see what the problem might be (no thoughts spring to mind as Blitz3D is stable).

Jaydubeww

(Posted 2010) [#4]

Ok, here it is. All it's supposed to do is print the FPS. Also, include a file named "ini.xml" with the following content in the same folder:

<?xml version="1.0" ?>
<ini>
	<graphics x="1024" y="768" depth="16" mode="2" fps="60">
		<antialiasing enable="1"/>
		<hwmultitextureing enable="1"/>
		<dithering enable="1"/>
		<wbuffering enable="1"/>
	</graphics>
</ini>

Alright, I also eliminated the includes. The last section of code is "blitzXML" functions. Hopefully the author wont be mad that I added them. There not my functions, if your interested in them, check the link I gave right above them.

Here's the code:


;=========================================================================
;		Start the good stuff - Graphicss Initilization

;[Block] - Graphics Initilization (basic) / Includes
	Graphics3D 400,300,16,0
	
;	Include ".\lib\BlitzXML.bb"
;	Include ".\lib\rlx.bb"
	
;[End Block]
	
;=========================================================================
;		Declaring / Initializing Variables

;[Block] Constants, Globals, Types, Arrays
	Global FPS%,ticks%
	
	;[Block] 	Collision type values
	
	;[End Block]
	
	;[Block] 	Frame Limiting - Required Var's
		Type FrameRate
			Field TargetFPS#	
			Field SpeedFactor#
			Field FPS#	
			Field TicksPerSecond	
			Field CurrentTicks	
			Field FrameDelay	
		End Type

		Global FL.FrameRate = New FrameRate
	;[End Block]
	
	;[Block] 	FPS - Required Var's
		Type objFPS
			Field Array[129]
			Field Total
			Field Index
			Field LastTime
			Field LastIndex
		End Type
	;[End Block]
	
	;[Block]	System Var's
		Type SystemObj
			Field o_width%
			Field o_height%
			Field o_depth%
			Field o_mode%
			
			Field o_debug, o_wire	; Used for debug stuff, check the function.
			Field o_fps%			; FPS that you want
		End Type
		
		Global sys.SystemObj = New SystemObj
		
		sys\o_width = 400
		sys\o_height = 300
		sys\o_depth = 16
		sys\o_mode = 1
		
		sys\o_debug = True : sys\o_wire = False
		sys\o_fps = 60
	;[End Block]

	;[Block] 	Create Player Obj
		Type PlayerObj
			; Next 7 needed for Camera wobbling
			Field sp#			; Main walking speed (not connected with wobbling)
			Field shoe_size#	; Stepspeed for wobbling camera (eg. 7=running, 4=walking)
			Field head_bang_X#	; Amount of wobbling
			Field head_bang_Y#
			Field walking		; Walking state (eg. 0=standing, 1=moving)
			Field a1#
			Field footstep_needed%
			
			Field pivot			; Players pivot (holds all of player's entities)
			Field camera		; Players camera
			Field current_level	
			Field x, y, z			; X,Y,Z, position
		End Type
		
		Global p.PlayerObj = New PlayerObj
			p\sp#=.05
			p\shoe_size# = 7.0
			p\head_bang_X# = 0.1
			p\head_bang_Y# = 0.1
			p\walking% = 0
			p\a1# = 0.0
			p\footstep_needed = 0
			
			; Creates a "player", give him a stomach, give him collisions!
			p\pivot = CreatePivot()
			EntityRadius p\pivot,.9
			EntityType p\pivot,TYPE_PLAYER
			
			; Creates a camera for the player, attaches the cam to player
			p\camera = CreateCamera(p\pivot)
			TranslateEntity p\pivot,0,0,.9
			CameraRange p\camera,.1,200
			CameraClsMode p\camera,False,True
			
			p\current_level = 1
			p\x = 0 : p\y = 0 : p\z = 0
	;[End Block]
	
	;[Block]	World - Obj (level)
		Type WorldObj
			Field pivot				; Holds ALL of level 1, just needed to "FreeEntity level1\pivot"
			Field map				; Holds the actual model
			Field x,y,z				; X,Y,Z position
			Field al_r,al_g,al_b	; AmbientLight red,green,blue
			Field light				; Levels main light source, used with ambientLight
			; Also land: gets height map, ground: gets texture, water: its a plane with a tex, sky: a skybox
		End Type
		
		Global lvlTest.WorldObj = New WorldObj
	;[End Block]

	;[Block]	Collision Types and Collisions
		; Collision Types
			; Player
			Const TYPE_PLAYER=1, TYPE_BULLET=2
			; World
			Const TYPE_TERRAIN=50
			; Enemies
			
			
		; Collisions
		Collisions TYPE_PLAYER,TYPE_TERRAIN,2,3
		
	;[End Block]

;[End Block] 

	If FileType("ini.xml") = 0 Then 
		RuntimeError "'ini.xml' not found. Please run 'setup.exe'." 
	Else
		ReadIni()
	EndIf
	Graphics3D sys\o_width,sys\o_height,sys\o_depth,sys\o_mode

	AppTitle "Gametitle"
	SetBuffer BackBuffer()
	AutoMidHandle True
	HidePointer	

;=========================================================================
;		Start Visualization

;[Block] Title screen
	; Has a function to change the Graphics3D setting.
	; Ability to change the control settings.
	; Choose level
	; Load / save
;[End Block]

	;LoadLevel(p\current_level)

;=========================================================================
;		Main Loop

;[Block] Main Loop
	While Not KeyHit(1)
		
		FrameLimitInit(sys\o_fps)
		UpdateGame()
		UpdateWorld
		RenderWorld
		
		; 2D HUD
		; Debug HUD
		If KeyDown(29)And KeyHit(88) Then sys\o_debug = Not sys\o_debug	; Toggle debug ON/OFF
		If sys\o_debug Then DebugInfo()
		
		; Pause menu
		
		SetSpeedFactor()
		Flip
	Wend
	
	End
;[End Block]

;=========================================================================
;		Functions
	
Function FrameLimitInit(target_FPS#)
	FL\TargetFPS# = target_FPS#
	FL\TicksPerSecond = 1000 	
	FL\FrameDelay = MilliSecs()
End Function

Function SetSpeedFactor()
	FL\CurrentTicks = MilliSecs()
	FL\SpeedFactor = (FL\CurrentTicks - FL\FrameDelay) / (FL\TicksPerSecond / FL\TargetFPS) 
	FL\FPS = FL\TargetFPS / FL\SpeedFactor    
	FL\FrameDelay = FL\CurrentTicks 
End Function

Function GetFPS()
	Local This.objFPS, ThisTime#
	This=First objFPS
	If This = Null Then 
		This.objFPS = New objFPS 
		This\Index=0
		This\LastIndex=1
	EndIf
	This\Index 			= (This\Index  Shr 0 And 127 Shl 0) + 1
	This\LastIndex 			= (This\LastIndex  Shr 0 And 127 Shl 0) + 1
	This\Array[This\Index] 	= MilliSecs() - This\LastTime 
	This\LastTime 			= MilliSecs()
	This\Total 			= This\Total + This\Array[This\Index] - This\Array[This\LastIndex]
	ThisTime# 			= Float(This\Total) / 128.0
	If ThisTime = 0 Then
		Return(1000)
	Else
		Return(1000.0 / ThisTime)
	EndIf
End Function

Function UpdateGame() ; Actual "Main Loop" 
	Cls 
	;Check Collision
	;Update entities (like player and enemies)
		;Player controls
		;Physics
End Function

Function DebugInfo()
	Text 10,10,"FPS:" + GetFPS()								; Display Frames per Second
	If KeyHit(88) Then sys\o_wire = Not sys\o_wire : WireFrame sys\o_wire	; Display wireframe if F12 key hit
End Function

Function LoadLevel(level)
	; Used to load the correct level
;	Select level
;		Case 1
;			;LoadLevel1()
;		Default
;			DebugLog "No level to load! Level = " + p\level
;	End Select
	
; have user choose xml file to load, there for, user skips the select structure
	p\x = 0
	p\y = 0
	p\z = 0
	Select level
		Case 1
;			 Player info
;				p\x = 0
;				p\y = 0
;				p\z = 0
;			 level info
;				lvlTest\map = LoadMesh("./models/test1.3ds",lvlTest\pivot)
;				TerrainDetail False
;				TerrainShading False
;				PositionEntity 
;				AmbientLight 255,255,255	
		Default
			DebugLog "No level to load! Level = " + level
	End Select
End Function	

Function FreeMap()
	; Used to free the current level
	; Gets ready to load the next level
;	FreeEntity level1\pivot ; will free level1, "pivot" holds ALL of level 1 models and entities
;	Delete level1
;	p\level = p\level + 1
;	LoadLevel(p\level)
End Function

Function ReadIni()
	Local rootnode,graphicsNode,childCount%,node,temp,i%
	
	rootnode = rlx_Parse("ini.xml")
	
	graphicsNode = xmlNodeFind("graphics", rootnode)	; Handle for the "graphics" node.
	childCount = xmlNodeChildCount(graphicsNode)			; Get graphics node child count.
	
	; Read And apply _child_ nodes of the _graphics_ node
	For i=0 To childCount
		node = xmlNodeChild(graphicsNode,i)
		If node = "antialiasing" Then 
			temp = xmlNodeAttributeValueGet(graphicsNode,"enable")
			AntiAlias temp
		EndIf
		
		If node = "hwmultitextureing" Then
			temp = xmlNodeAttributeValueGet(graphicsNode,"enable")
			HWMultiTex temp
			HWMultiTex xmlNodeAttributeValueGet(graphicsNode,"enable")
		EndIf 
		
		If node = "dithering' Then 
			temp = xmlNodeAttributeValueGet(graphicsNode,"enable")
			Dither temp
		EndIf
		
		If node = "wbuffering" Then
			temp = xmlNodeAttributeValueGet(graphicsNode,"enable")
			WBuffer temp
		EndIf
	Next 
	
	; Read and apply the _attributes_ of the _graphics_ node
	sys\o_fps = xmlNodeAttributeValueGet(graphicsNode, "fps")
	sys\o_width = xmlNodeAttributeValueGet(graphicsNode, "x")
	sys\o_height = xmlNodeAttributeValueGet(graphicsNode, "y")
	sys\o_depth = xmlNodeAttributeValueGet(graphicsNode, "depth")
	sys\o_mode = xmlNodeAttributeValueGet(graphicsNode, "mode")
	
	xmlNodeDelete(rootnode)
End Function






;! ________________________________
;!
Const gameTitle$ = "GameTitle"		; Game title
Const errorLog$ = "errorLog.xml"	; Errorlog file name
Global errors = False				; Used to tell if there are errors

Dim errMsg$(100)
	; Light error messages
	errMsg(0) = "Attributes 'innerAngle' And 'outerAngle' are both required when a 'light' node has an attribute 'Type' of 3."
	
	
Type SceneObj
	Field o_handle
	Field o_pivot
	
	Field o_light.LightObj
End Type
 
Type LightObj
	Field o_type%		; Type of light 1,2,3
	
	; For LightConeAngles, For light type 3
	Field o_innerAngle#
	Field o_outerAngle#
End Type

Global Scene.SceneObj = New SceneObj

;!=========================================================================
;!		~ Load Scene Functions ~
;!
;! These functions will load the Scene from your 
;!   level.xml.
;!

Function rlx_Create_Light(node, parentEntity,file$)
	Scene\o_light.LightObj = New LightObj
	Scene\o_light\o_type = xmlNodeAttributeValueGet(node,"type")
	
	;	If light type = 3, make sure it has BOTH of them.
	If Scene\o_light\o_type = 3 Then
		Scene\o_light\o_innerAngle = xmlNodeAttributeValueGet(node,"innerAngle")
		Scene\o_light\o_outerAngle = xmlNodeAttributeValueGet(node,"outerAngle")
		
		If Scene\o_light\o_innerAngle = "" Or Scene\o_light\o_outerAngle = "" Then
			rlx_Add_Error(file,errMsg(0))
			errors = True
		End If
	End If
End Function

;!=========================================================================
;!		~ Extra BlitzXML functions ~
;!

; Checks to see if there is an 'errorlog.xml'.
; If not, it creates one with basic _Elements_
; If there is, it will delete it then check to see 
;   if it's still there.
; It then creates the file if it is NOT there.
; Will return error if it is there, then EXITS the program.
Function rlx_CheckFor_Create_ErrorLog(fileName$)
	If FileType(fileName) = 0 Then
		rlx_Create_ErrorLog(fileName,gameTitle)
	Else
		DeleteFile(fileName)
		If FileType(fileName) = 1 Then
			RuntimeError "ERROR: " + fileName + " must be deleted before continuing."; Please close any open files which may contain it And try again.
			End
		Else 
			rlx_Create_ErrorLog(fileName,gameTitle)
		End If
	EndIf
End Function

; Parses desired XML file for errors. 
; If any are found, they are printed in the debuglog.
; If there are no errors, the root node handle is returned using xmlload()
; Use like so: rootNode = xmlParse_returnErrors("level1.xml")
Function rlx_Parse(file$)
	Local ms#,rootnode,parsetime,errs%,i%
	
	ms = MilliSecs()
	rootnode = xmlLoad(file)
	parsetime = MilliSecs()-ms
	DebugLog "Parse time: "+ parsetime +" millisecs"
	
	; Display any errors
	errs = xmlErrorCount()
	If errs > 0 Then
		Print "Errors have occurred while parsing the xml file:"
		Print 
		For i = 1 To errs
			Print "Byte #"+xmlErrorPosition(i)+": "+xmlError(i)
		Next
		Print 
		Print "Press any key to attempt to continue"
		WaitKey()
	End If
	Return rootnode
End Function

;!=========================================================================
;!		~ Internal Functions ~
;!
;! They are called by other functions the user / programmer
;!   calls.
;! Should not be called anywhere other 
;!   than functions inside 'rlx.bb'.
;!

; Creates error log file and
;   adds defualt _elements_ and 
;   Node _Children_
Function rlx_Create_ErrorLog(fileName$,gameTitle$)
	xmlNodeAdd(0, "errorLog")
		xmlNodeAdd(1, "info")
			xmlNodeAdd(2, "title")
				xmlNodeDataSet("gameTitle",gameTitle)
			xmlNodeAdd(2, "file")
				xmlNodeDataSet("file", fileName)
			xmlNodeAdd(2, "dateCreated")
				xmlNodeDataSet("dateCreated",Get_Date())
			xmlNodeAdd(2, "timeCreated")
				xmlNodeDataSet("timeCreated",Get_Time())
	xmlSave(fileName,1)
End Function

; Adds an error Node and its _Children_ and a reason
;	 to the end of the errorLog.xml
Function rlx_Add_Error(file$,desc$)
	xmlNodeAdd(1, "error")
		xmlNodeAdd(2, "location")
			xmlNodeDataSet("location", FilePos(file) + 1)
;		xmlNodeAdd(2, "node")
;			xmlNodeDataSet("node", node)
		xmlNodeAdd(2, "desc")
			xmlNodeDataSet("desc", desc)
End Function

;!=========================================================================
;!		Extra functions used
;!

; Returns the current system time in the form 
;   of "hour:minutes:seconds (pm/am)" ie. 1:43:51 am
Function Get_Time$()
	Local tempTime$ = CurrentTime$(), ampm$ = " am"
	Local hr% = Mid$(tempTime,1,2)
	
	If hr > 12 Then 
		hr = hr - 12 
		ampm = " pm"
	EndIf
	
	If hr = 0 Then hr = 12
	Local min$ = Mid$(tempTime,4,2)
	Local sec$ = Mid(tempTime,7,2)
	
	Local time$ = hr + ":" + min + ":" + sec + ampm
	
	Return time
End Function

; Returns the current date in the form 
;   of "month day, year" ie. May 15, 1991
Function Get_Date$()
	Local tempDate$ = CurrentDate$()
	Local day$ = Mid$(tempDate,1,2)
	Local month$ = Mid$(tempDate,4,4)
	Local year$ = Mid$(tempDate,8,11)
	
	Local date$ = month + day +", " + year
	
	Return date
End Function












;! BlitzXML Functions
;! Found here: <a href="http://www.blitzbasic.com/Community/posts.php?topic=46647" target="_blank">http://www.blitzbasic.com/Community/posts.php?topic=46647</a>
;============================= BlitzXML =================================
;Copyright (C) 2005 John Judnich

;BlitzXML is an XML (eXtendable Markup Language) function library for
;blitz. You don't even need to have any knowledge of the syntax of XML
;to use BlitzXML, although an understanding of the terms and structure
;is helpful.

;At the user's (programmer's) point of view,
;BlitzXML is a way of storing bits of data similar to the way folders
;are stored on a hard drive. For example an node (item) named "inventory" may contain
;child nodes (sub-items) such as, "key". Each node may have an unlimited
;amount of sub-nodes, and each sub-node may have sub-sub-nodes, etc.
;Each node may have a name, and a number of attributes. Nodes may
;contain both sub-nodes (called children), and text data. To get a
;better idea how xml works, look at "example.xml".

;When a data structure is constructed with BltizXML, it may be saved
;to a file using XML syntax, which is really just a more strict form of
;HTML. XML files may also be loaded and parsed into BlitzXML just as
;easily. Due to the flexibility of XML, this library should be very
;useful for level editors, games that load levels from XML files,
;or any program requiring structured Or
;complex data to be saved to and loaded from a file.

;========================================================================



;**** Constant Declarations =============================================

Const MAX_ATTRIBUTES = 32	;The maximum number of attributes a xmlNode may have
Const MAX_ERRORS = 64		;The maximum number of errors and warnings that will be processed until the xml parser aborts the operation
Const PARSER_RECURSE = 1024 ;The maximum number of virtually "recursive" steps for the parser.
Global XML_INDENTATION$ = Chr$(9)	;The character(s) used to indent when saving files

;**** Type Declarations =================================================

;xmlNode Type - This is the main building block of BlitzXML. All xml data
;is stored with this Type, which gets manipulated by the user. The xml data
;can then be loaded from and saved to files.
Type xmlNode
	Field Name$								;The name of the node
	Field AttributeCount					;The number of attributes for the node
	Field AttributeName$[MAX_ATTRIBUTES]	;The attribute name array
	Field AttributeValue$[MAX_ATTRIBUTES]	;The attribute value array
	Field Contents$							;The data contents of the node
	Field Parent.xmlNode					;This node's parent node. If this is set to Null, then this node is the "root" node
	Field Level								;This is the node's level
	
	;These fields are manipulated by xml_RegisterChild(), xml_GetChild(), and xml_UnregisterChild()
	Field ChildCount						;The number of the node's children
	Field ChildBank							;A memory bank of handles to the node's children
End Type


;**** Global Declarations ===============================================

Global xml_Error$[MAX_ERRORS]
Global xml_ErrorPos[MAX_ERRORS]
Global xml_ErrorCount


;**** Interface Functions ===============================================
;Interface functions are the functions the user (the programmer) uses
;in their program, unlike the internal functions, which are only called
;by these functions.

;This function returns the level the node is at. If the node is the
;root node, it is at level 0. If it is a child of the root node,
;the level will be 1. If it is a child of a child of the root node,
;the level of 2 will be returned, etc.
Function xmlNodeLevel(Node)
	this.xmlNode = Object.xmlNode(Node)
	Return this\Level
End Function

;This returns a node's parent node. If the node has no parent (if it's
;the root node), 0 will be returned.
Function xmlNodeParent(Node)
	this.xmlNode = Object.xmlNode(Node)
	If this\Parent = Null Then Return 0
	Return Handle(this\Parent)
End Function

;This returns the number of children the node has. In many cases,
;the node will contain no children, therefore returning 0.
Function xmlNodeChildCount(Node)
	this.xmlNode = Object.xmlNode(Node)
	Return this\ChildCount
End Function

;This returns one of the node's children, specified by ChildIndex.
;ChildIndex may be set anywhere from 1 to the amount of children
;the node has, which can be obtained from the xmlNodeChildCount()
;function.
Function xmlNodeChild(Node, ChildIndex)
	this.xmlNode = Object.xmlNode(Node)
	Return Handle(xml_GetChild(this, ChildIndex))
End Function

;This function will search for the first node matching the specified
;name and parent. Specifying a parent (optional) will only search
;nodes that are children of the specified parent node. If you only want
;to find a direct child of this node (not sub-childs), set Recurse to False.
Function xmlNodeFind(Name$, Parent, Recurse = True)
	parentnode.xmlNode = Object.xmlNode(Parent)
	For this.xmlNode = Each xmlNode
		If this\Parent = parentnode Then
			If Lower(this\Name) = Lower(Name) Then
				Return Handle(this)
			End If
			If Recurse = True And this\ChildCount > 0 Then
				ret = xmlNodeFind(Name, Handle(this), True)
				If ret <> 0 Then Return ret
			End If
		End If
	Next
End Function

;This function adds a new node to the "tree" of existing xml nodes. Set
;ParentNode to the node you would like this to be a child of, or set it
;to 0 if this is the "root" node. Note: only one root node is allowed.
;Optionally, Name$ can be set to a name the node will initially be given,
;although the node can be renamed later with xmlNodeNameSet()
Function xmlNodeAdd(ParentNode, Name$="NewNode")
	this.xmlNode = New xmlNode
	parent.xmlNode = Object.xmlNode(ParentNode)
	
	this\Parent = parent
	If parent = Null Then
		this\Level = 0
	Else
		top.xmlNode = parent
		If parent\ChildCount = 0 Then
			top.xmlNode = parent
		Else
			top.xmlNode = Object.xmlNode( xmlNodeChild(ParentNode, 1) )
		End If
		Insert this After top
		this\Level = parent\Level + 1
		xml_RegisterChild(parent, this)
	End If
	
	this\Name = Name
	Return Handle(this)
End Function

;This function deletes the given node, including all of it's children
;(sub-nodes), if there are any. Ignore the ChildIndex variable, as it
;is used internally when recursively deleting the node's children.
;This can be used to delete an entire XML file in memory by deleting it's
;handle (root node)
Function xmlNodeDelete(Node, ChildIndex = 0)
	this.xmlNode = Object.xmlNode(Node)
	
	For i = 1 To this\ChildCount
		xmlNodeDelete(Handle(xml_GetChild(this, 1)), 1) ;The index is always 1 because the list will keep getting smaller while they are getting deleted - (just like holding down the delete key at the beginning of a document)
	Next
	
	If this\Parent <> Null Then
		If ChildIndex = 0 Then
			For i = 1 To this\Parent\ChildCount
				If xml_GetChild(this\Parent, i) = this Then ChildIndex = i:Exit
			Next
		End If
		xml_UnregisterChild(this\Parent, ChildIndex)
	End If
	
	FreeBank this\ChildBank
	Delete this
End Function

;This sets a node's name. Note: A node's name must not be a blank string
Function xmlNodeNameSet(Node, Name$)
	this.xmlNode = Object.xmlNode(Node)
	this\Name = Name
End Function

;This returns the name of a node
Function xmlNodeNameGet$(Node)
	this.xmlNode = Object.xmlNode(Node)
	Return this\Name
End Function

;This sets the value of an attribute of a node. If the attribute does
;not exist, it will be created. The attribute's value may be any valid
;string of characters, not including double quotes. The value is allowed
;to be a blank string.
;Example:
;xmlNodeAttributeSet(node, "alpha", "0.7")
Function xmlNodeAttributeValueSet(Node, Attribute$, Value$)
	this.xmlNode = Object.xmlNode(Node)
	
	;Check if the attribute exists or not
	indx = 0
	For i = 1 To this\AttributeCount
		If Attribute = this\AttributeName[i] Then indx = i:Exit
	Next
	
	;Create a new attribute if it doesn't exist
	If indx = 0 Then
		this\AttributeCount = this\AttributeCount + 1
		this\AttributeName[this\AttributeCount] = Attribute
		indx = this\AttributeCount
	End If
	
	;Set the attribute's value
	this\AttributeValue[indx] = Value
End Function

;This returns the value of the specified attribute, if it exists. If it
;doesn't exist, a blank string will be returned.
;Example:
;EntityAlpha Entity\Mesh, xmlNodeAttributeGet(Entity\Node, "alpha")
Function xmlNodeAttributeValueGet$(Node, Attribute$)
	this.xmlNode = Object.xmlNode(Node)
	
	;Find the attribute
	indx=0
	For i = 1 To this\AttributeCount
		If Attribute = this\AttributeName[i] Then indx = i:Exit
	Next
	
	;If the attribute exists, return it's value. If not, return a blank string
	If indx = 0 Then
		Return ""
	Else
		Return this\AttributeValue[indx]
	End If
End Function

;This sets the name of an attribute (NOT it's value). Note: attribute
;names are case sensitive
;Example:
;xmlNodeAttributeNameSet(node,"pitch","Xang")
Function xmlNodeAttributeNameSet(Node, Attribute$, NewName$)
	this.xmlNode = Object.xmlNode(Node)
	
	;Find the attribute
	indx = 0
	For i = 1 To this\AttributeCount
		If Attribute = this\AttributeName[i] Then indx = i:Exit
	Next

	;If the attribute exists, rename it
	If indx <> 0 Then
		this\AttributeName[indx] = NewName
	End If
End Function

;This deletes an attribute. Once a new attribute is created when
;using the xmlNodeAttributeSet() function, it will continue to
;reside in memory, and be saved to a file even if it's value is 
;blank. To remove an un-used (or used) attribute of a node, use
;this function.
;Example:
;xmlNodeAttributeDelete(node, "hidden")
Function xmlNodeAttributeDelete(Node, Attribute$)
	this.xmlNode = Object.xmlNode(Node)
	
	;Find the attribute
	indx = 0
	For i = 1 To this\AttributeCount
		If Attribute = this\AttributeName[i] Then indx = i:Exit
	Next
	
	;Delete the attribute, if it exists
	If indx <> 0 Then
		this\AttributeName[indx] = this\AttributeName[this\AttributeCount]
		this\AttributeValue[indx] = this\AttributeValue[this\AttributeCount]
		this\AttributeCount = this\AttributeCount - 1
	End If
End Function

;This sets a node's data string. A node's data is a string of
;text contained within the opening and closing node tags.
;Example:
;xmlNodeDataSet(titlenode, "BlitzXML")
Function xmlNodeDataSet(Node, NodeData$)
	this.xmlNode = Object.xmlNode(Node)
	this\Contents = NodeData
End Function

;This returns a node's data string. A node's data is a string
;of text contained within the opening and closing node tags.
Function xmlNodeDataGet$(Node)
	this.xmlNode = Object.xmlNode(Node)
	Return this\Contents
End Function

;This function saves all XML nodes to the specified file.
;If any errors occur, false will be returned, if not, true
;will be returned.
Function xmlSave(FileName$, Node)
	this.xmlNode = Object.xmlNode(Node)

	file = WriteFile(FileName)
	If file = 0 Then xml_AddError("Error writing XML file (possibly, file is in use, or is the folder/drive/file is write protected).", 0):Return
	
	WriteLine file, "<?xml version="+Chr(34)+"1.0"+Chr(34)+" ?>"
	xml_WriteNode(file, this)
	
	CloseFile file
End Function

Function xml_WriteNode(File, Node.xmlNode)
	Local NodeContents$, Indent$, Indent2$
	
	NodeContents = Node\Name
	For i = 1 To Node\AttributeCount
		NodeContents = NodeContents + " " + Node\AttributeName[i] + "=" + Chr$(34) + Node\AttributeValue[i] + Chr$(34)
	Next
	
	Indent = String$(XML_INDENTATION$, Node\Level)
	Indent2 = String$(XML_INDENTATION$, Node\Level+1)
	
	If Node\ChildCount = 0 Then
		If Node\Contents = "" Then
			WriteLine File, Indent + "<" + NodeContents + "/>" 
		Else
		    WriteLine File, Indent + "<" + NodeContents + ">" + Node\Contents + "</" + Node\Name + ">"
		End If
	Else
		WriteLine File, Indent + "<" + NodeContents + ">"
		If Node\Contents <> "" Then WriteLine File, Indent2 + Node\Contents
		
		For i = 1 To Node\ChildCount
			xml_WriteNode(File, Object.xmlNode(xmlNodeChild(Handle(Node), i)))
		Next
		
		WriteLine File, Indent + "</" + Node\Name + ">"
	End If
End Function

;This function loads and parses XML nodes from the specified XML file.
;Note: This (BlitzXML's xml parser) only supports xml files with standard
;xml tags and attributes with values enclosed in quotes. If the file
;is loaded successfully with no errors, a handle to the root node of the file
;will be returned. If not, 0 will be returned.
;Errors can be accessed using the xmlError$() and xmlErrorCount() functions.
Function xmlLoad(FileName$)
	Local attribute$[MAX_ATTRIBUTES]
	Local value$[MAX_ATTRIBUTES]
	Local nodestack[PARSER_RECURSE]
	Local rootnode
	
	DebugLog "Loading XML file: " + FileName
	xml_ClearErrors()
	begintime = MilliSecs()
	
	;Open the file
	file = ReadFile(FileName)
	If file = False Then
		xml_AddError("Error opening XML file: File does not exist.", 0)
		Return 0
	End If
	If Eof(file) = -1 Then
		xml_AddError("Error opening XML file: File is already in use by another program.", 0)
		Return 0
	End If
	
	;Read in all tags
	stacklevel = 0
	While Eof(file) = False
		;Get the next tag or data section
		tag$ = xml_NextItem(file)
		
		If tag$ <> "" Then 
		
			If xml_ItemType = 2 Then
				;Node contents
				xmlNodeDataSet(nodestack[stacklevel - 1], Trim(Trim(xmlNodeDataGet(nodestack[stacklevel - 1])) + " " + Trim(tag)))
			Else
				;Check if it's a closing tag, opening tag, or stand-alone tag
				If Left(tag,1) = "/" Then
					;Closing tag
					stacklevel = stacklevel - 1
					
					tmp.xmlNode = Object.xmlNode(nodestack[stacklevel])
					If tag <> "/" + tmp\Name Then xml_AddError("Unclosed tag (found <"+tag+">, expected </"+tmp\Name+">", FilePos(file))
				Else
					;Create a new node
					If stacklevel > 0 Then parent = nodestack[stacklevel - 1] Else parent = 0
					node = xmlNodeAdd(parent)
					If stacklevel = 0 Then rootnode = node
					
					;Get the name and attributes from the tag
					For i = 0 To attr:attribute[i] = "":value[i] = "":Next:attr = 0:opened = False:name$ = ""
					length = Len(tag)
					For i = 1 To length
						ch$ = Mid(tag, i, 1)
						If attr = 0 And ch = " " Then attr = attr + 1
						If ch = "=" Then attr = -attr
						If ch = Chr(34) Then
							If attr > 0 Then xml_AddError("Expecting equals symbol", FilePos(file))
							opened = 1 - opened
							If opened = False Then attr = Abs(attr):attr = attr + 1
						End If
						If ch <> Chr(34) And attr < 0 And opened Then value[-attr] = value[-attr] + ch
						If attr = 0 Then
							name = name + ch
						Else
							If attr > 0 And ch <> Chr(34) And ch<>" " Then attribute[attr] = attribute[attr] + ch
						End If
					Next
					For i = 1 To attr-1
						xmlNodeAttributeValueSet(node, attribute[i], value[i])
					Next
					xmlNodeNameSet(node, name)
					nodestack[stacklevel] = node
					
					If Right(tag,1) = "/" Then
						;Stand-alone tag
					Else
						;Opening tag
						stacklevel = stacklevel + 1
					End If
				End If
			End If
		End If
	Wend
	
	CloseFile file
	
	endtime = MilliSecs()
	parsetime# = (endtime - begintime) / 1000.0
	If xmlErrorCount > 0 Then DebugLog "Parse failed" Else DebugLog "Parse completed in "+parsetime+" seconds."
	
	If xmlErrorCount > 0 Then Return 0 Else Return rootnode
End Function

;This function returns the number of errors and warnings from the last
;file parse performed.
Function xmlErrorCount()
	Return xml_ErrorCount
End Function

;This returns the position of the specified error (in characters from
;the beginning of the file
Function xmlErrorPosition(ErrorNumber)
	If ErrorNumber > xml_ErrorCount Then Return 0
	Return xml_ErrorPos[ErrorNumber]
End Function

;This returns the description of the requested error.
Function xmlError$(ErrorNumber)
	If ErrorNumber > xml_ErrorCount Then Return ""
	Return xml_Error[ErrorNumber]
End Function



;**** Internal Functions ================================================
;Internal functions should not be called from ANYWHERE but from other
;BlitzXML functions. These functions are undocumented, and you should
;NOT use them.

Global xml_ItemType
Function xml_NextItem$(file)
	Local tag$
	While Eof(file) = False
		ch = ReadByte(file)
		If txt$ <> "" And (ch = 60 Or ch = 13) Then xml_ItemType = 2:SeekFile file,FilePos(file)-1:Return txt
		If ch <> 13 And ch <> 15 And ch <> 10 Then txt$ = txt$ + Chr(ch)
		If ch = 13 And txt <> "" Then txt = txt + " "
		
		If ch = 60 Then ;<
			If opened = True Then xml_AddError("Expecting closing bracket (>)", FilePos(file))
			opened = True
		End If
		If ch = 62 Then ;>
			txt = ""
			If opened = False Then xml_AddError("Expecting opening bracket (<)", FilePos(file))
			opened = False
			If Left(tag,4) = "<!--" Or Left(tag,2) = "<?" Then
				If Left(tag,4) = "<!--" And Right(tag,2) <> "--" Then xml_AddError("Expecting correct comment closure (-->)", FilePos(file))
				If Left(tag,4) = "<?" And Right(tag,2) <> "?" Then xml_AddError("Expecting correct header closure (?>)", FilePos(file))
				tag = ""
			Else
				xml_ItemType = 1
				Return Right(tag,Len(tag)-1)
			End If
		End If
		If opened Then tag = tag + Chr(ch)
	Wend
End Function

Function xml_RegisterChild(Node.xmlNode, Child.xmlNode)
	;Incriment the child count
	Node\ChildCount = Node\ChildCount + 1
	
	;Allocate memory for the data
	If Node\ChildBank = False Then
		Node\ChildBank = CreateBank(4)
	Else
		ResizeBank Node\ChildBank, Node\ChildCount * 4
	End If
	
	;Write the data
	Value = Handle(Child)
	PokeInt Node\ChildBank, (Node\ChildCount - 1) * 4, Value
End Function

Function xml_GetChild.xmlNode(Node.xmlNode, ChildIndex)
	;Check if the ChildIndex is valid
	If ChildIndex > Node\ChildCount Then Return Null
	
	;Get the child xmlNode object and return it
	Value = PeekInt(Node\ChildBank, (ChildIndex - 1) * 4)
	this.xmlNode = Object.xmlNode(Value)
	Return this
End Function

Function xml_UnregisterChild(Node.xmlNode, ChildIndex)
	;Check if the ChildIndex is valid
	If ChildIndex > Node\ChildCount Then Return False

	;"Swap" the child-to-be-deleted with the last child on the list, so the last child on the list is now the child to be deleted
	;(actually, it doesn't swap - to optimize it a little, the child-to-be-deleted doesn't get copied anywhere because it's not gonna be used)
	Value = PeekInt(Node\ChildBank, (Node\ChildCount - 1) * 4)
	PokeInt Node\ChildBank, (ChildIndex - 1) * 4, Value
	
	;Downsize the bank, erasing the last child on the list which would be the child-to-be-deleted
	ResizeBank Node\ChildBank, (Node\ChildCount - 1) * 4
	Node\ChildCount = Node\ChildCount - 1
	
	Return True
End Function

Function xml_ClearErrors()
	xml_ErrorCount = 0
End Function

Function xml_AddError(Description$, pos)
	xml_ErrorCount = xml_ErrorCound + 1
	xml_ErrorPos[xml_ErrorCount] = pos
	xml_Error[xml_ErrorCount] = Description
	
	DebugLog "Error at char #"+pos+":  "+Description
End Function

Warner

(Posted 2010) [#5]

I think that the reason is, that when using windowmode 0 with Graphics, in debug mode, the program will be ran in a window mode, and in release mode, the program will be ran fullscreen.
Windowmodes are usually not a problem, but not all fullscreen resolutions/bitdepths are available in DirectX. You should test if a mode exists with GFXModeExists().
I believe that when using Graphics3D twice, any graphics could be destroyed: Images become invalid, and I believe entities/textures as well.

Jaydubeww

(Posted 2010) [#6]

Well, that shouldn't be the problem because I created a small app which creates the ini file based on the users choice. The choices are generated with GFXModeExists().

puki	(Posted 2010) [#7]

You should use EndGraphics before using a new Graphics command.

Not sure if it is the answer to your problem - but it is the law.

Robert Cummings

(Posted 2010) [#8]

I think Graphics already calls EndGraphics first though as a retard check, but Puki is right.

John Wesley, can you ensure that your xml is actually giving you good data? print out the values before calling graphics.

Jaydubeww

(Posted 2010) [#9]

Yep, it has "good" data.

To recap:
- Calling graphics3d multiple times is fine, as long as EndGraphics is called before switching.
Question: Warner mentioned any graphics and entities and textures will become invalid, is this true?

- I get "unable to set graphics mode" if i compile it, but it runs fine when i debug compile it.

puki	(Posted 2010) [#10]

Blitz3D will lose all the handles when calling Graphics - basically, Blitz3D becomes blind to what you have loaded.

You either reassign everything manually by basically hacking Blitz3D on-the-fly, or you store the handles and hope that you can still re-address them after a new Graphics - but don't bank on it.

EDIT:
Actually, I don't know for sure what gets lost, if anything, with Graphics3D - basically, I have never bothered calling it more than once.

Jaydubeww

(Posted 2010) [#11]

Gah, I just switched some code around forcing myself to only have one graphics3d at the moment. It now works. I'm not sure if that was the error (I'm not convinced it was..). All that matters to me is that it runs fine now.

Thanks for the help.

Jaydubeww

(Posted 2010) [#12]

haha, alright, well Im just going to put it in once to avoid all the troublesome errors..